Flash ActionScript 3 - рисование статического трехмерного куба

Вот самый быстрый и, вероятно, наиболее рекомендуемый способ добиться желаемого:

• Загрузите библиотеку Papervision3D для AS3.

Как только вы это сделаете, создайте класс документа и вставьте в него этот код, который я создал для вас, чтобы вы начали:

package
{
    import org.papervision3d.view.BasicView;
    import org.papervision3d.objects.primitives.Cube;
    import org.papervision3d.materials.utils.MaterialsList;
    import org.papervision3d.materials.ColorMaterial;


    /**
     * Document class.
     * @author Marty Wallace.
     */
    public class Base extends BasicView
    {

        /**
         * Constructor.
         */
        public function Base()
        {

            // Create an array of faces for your cube.
            var faces:Array = [
                "front",
                "back",
                "left",
                "right",
                "top",
                "bottom"
            ];

            // Create a list of materials, which contains a material for each face of the cube.
            var list:MaterialsList = new MaterialsList();


            // Create a new material for each face.
            for each(var i:String in faces)
            {
                // Define the material.
                var material:ColorMaterial = new ColorMaterial(Math.random()*0xFFFFFF);

                // Add your material to the face represented by i.
                list.addMaterial(material, i);
            }


            // Create the Cube.
            var cube:Cube = new Cube(list, 250, 250, 250);


            // Rotate the cube to however required.
            cube.rotationX = Math.random()*360;
            cube.rotationY = Math.random()*360;
            cube.rotationZ = Math.random()*360;


            // Add the cube to the scene.
            scene.addChild(cube);


            // Render the cube.
            startRendering();

        }

    }
}

Большая часть кода говорит сама за себя, и для этого конкретного фреймворка есть uint.MAX_VALUE учебные пособия.

Наслаждаться!