Goto был неожиданным в это время пакетом для Windows 7 Starter

Вы должны заключить это в кавычки:

if "%accept%"=="yes" goto combat
if "%accept%"=="no" goto begin

Или, скорее, если вы не хотите делать его чувствительным к регистру:

if /i "%accept%"=="yes" goto combat
if /i "%accept%"=="no" goto begin

Ваша проблема в том, что эта строка:

set /p accept=Yes/No?

НЕ использует то же имя переменной, что и эти:

If %acccept%==Yes goto Combat
If %acccept%==No goto Begin

Вышеуказанные переменные имеют «ccc», но первая просто «cc».

ИЗМЕНИТЬ

Привет, user1205760; У меня есть время потратить, поэтому я взял вашу программу и уменьшил ее. Это моя версия:

@echo off

Setlocal EnableDelayedExpansion
Set Actions=Attack Capture Item Run
Set Attacks=Tackle Growl Ember Scratch Cancel
Set i=0
For %%a in (%Attacks%) do set /A i+=1 & set Attack[!i!]=%%a

Set H1=20
Set A1=8
Set D1=6
Set S1=5
Set H2=14
Set A2=5
Set D2=4
Set S2=8

:Begin
:Cancel
CLS
Echo Bulbasur
Echo %H2%/14      /\       
Echo           (__) ___  
Echo           l __lo.ol 
Echo           l_\ l_\"  
Echo.        
Echo     _ 
Echo *  / \ 
Echo \\l  )
Echo  \\__l   Charmander
Echo             %H1%/20
Echo -Attack -Capture
Echo -Item   -Run 
Set /p Move=Action? 
For %%a in (%Actions%) do if /I %move%==%%a goto %move%
Echo I'm sorry, Charmander can't do that. 
Pause
goto Begin

:Attack
Cls
Echo Attacks
For %%a in (1 2 3 4) do echo %%a)!Attack[%%a]!
Set /p attack=Which one? 
for %%a in (1 2 3 4) do if %attack%==%%a set attack=!Attack[%%a]!
for %%a in (%Attacks%) do if /I %attack%==%%a goto %attack%
Echo I didn't get that
Pause
Goto Attack

:Tackle
call :Confirm Tackle Hits The opponent where it hurts. EVERYWHERE.
If %accept%==Yes goto Combat
goto Begin

:Growl
call :Confirm Growl lowers the opponents attack.
If %accept%==Yes goto Status
goto Begin

:Ember
call :Confirm Ember hits the opponent with a small fire.
If %accept%==Yes goto Combat
goto Begin

:Scratch
call :Confirm Scratch hits the foe with a claw.
If %accept%==Yes goto Combat
goto Begin

:Status
Set /A A1-=1
:Combat
If /I NOT %attack%==Growl set /A H2=H2-(A1^2/D2)
set /A H1=H1-(A2^2/D1)
goto Begin

:Confirm 
Cls
Echo %*
Echo Do you want to?
set /p accept=Yes/No? 
For %%a in (Yes No) do if /I %accept%==%%a exit /B
Echo I didn't get that.
Pause
goto Confirm

Если пользователь ничего не вводит, ваши If строки, вероятно, оцениваются примерно так:

…
If ==Yes goto Combat
If ==No goto Begin
…

что синтаксически неверно. Я бы предложил инициализировать accept перед командой set /p с некоторым значением по умолчанию:

…
set accept=default
set /p accept=Yes/No?
if …

Таким образом, если пользователь просто нажмет Enter, переменная accept сохранит значение default, и последующий if не приведет к ошибке.

Извините,
Это просто вопрос к отрицательным голосам.
Люди, которые спрашивают, просто НЕ УВЕРЕНЫ, должна ли проблема быть в ЭТОЙ ЧАСТИ.

e.g.

set a=
if %a%==1 echo yes

Если я просто опубликую эту строку:

if %a%==1 echo yes

Тогда ВСЕ ЗНАЮТ В ЧЕМ ПРОБЛЕМА?

Помните, что для переменной, такой как% abc%, лучше использовать ее с ", [или {, чтобы предотвратить сообщение об ошибке.

e.g.

set /p abc=

и пользователь ничего не вводит.
Тогда следующая строка должна быть:

if %abc%==1 echo Hi

Но стало:

if ==1 echo Hi

, как "% abc%" == ""
Но с "" он станет

if ""=="1" echo Hi

И "" не равно "1".
Понятно?

РЕДАКТИРОВАТЬ---

Если вы используете Windows 7 (или другие версии), вы также можете попробовать следующее:

choice /c YN /n /m "Confirm? [Y^|N]

^ просто выходит из "трубы" (|).

Надеюсь, это будет вам полезно!