Как получить значение DateDiff в миллисекундах в VBA (Excel)?

Вы можете использовать метод, описанный здесь следующим образом: -

Создайте новый модуль класса с именем StopWatch. Поместите следующий код в модуль класса StopWatch:

Private mlngStart As Long
Private Declare Function GetTickCount Lib "kernel32" () As Long

Public Sub StartTimer()
    mlngStart = GetTickCount
End Sub

Public Function EndTimer() As Long
    EndTimer = (GetTickCount - mlngStart)
End Function

Вы используете код следующим образом:

Dim sw as StopWatch
Set sw = New StopWatch
sw.StartTimer

' Do whatever you want to time here

Debug.Print "That took: " & sw.EndTimer & "milliseconds"

Другие методы описывают использование функции таймера VBA, но они имеют точность только до одной сотой секунды (сантисекунды).

Если вам просто нужно время, прошедшее в сантисекундах, вам не нужен TickCount API. Вы можете просто использовать метод VBA.Timer, который присутствует во всех продуктах Office.

Public Sub TestHarness()
    Dim fTimeStart As Single
    Dim fTimeEnd As Single
    fTimeStart = Timer
    SomeProcedure
    fTimeEnd = Timer
    Debug.Print Format$((fTimeEnd - fTimeStart) * 100!, "0.00 "" Centiseconds Elapsed""")
End Sub

Public Sub SomeProcedure()
    Dim i As Long, r As Double
    For i = 0& To 10000000
        r = Rnd
    Next
End Sub

GetTickCount и счетчик производительности необходимы, если вы хотите использовать микросекунды. Для миллисекунд вы можете просто использовать что-то вроде этого.

'at the bigining of the module
Private Type SYSTEMTIME  
        wYear As Integer  
        wMonth As Integer  
        wDayOfWeek As Integer  
        wDay As Integer  
        wHour As Integer  
        wMinute As Integer  
        wSecond As Integer  
        wMilliseconds As Integer  
End Type  

Private Declare Sub GetLocalTime Lib "kernel32" (lpSystemTime As SYSTEMTIME)  


'In the Function where you need find diff
Dim sSysTime As SYSTEMTIME
Dim iStartSec As Long, iCurrentSec As Long    

GetLocalTime sSysTime
iStartSec = CLng(sSysTime.wSecond) * 1000 + sSysTime.wMilliseconds
'do your stuff spending few milliseconds
GetLocalTime sSysTime ' get the new time
iCurrentSec=CLng(sSysTime.wSecond) * 1000 + sSysTime.wMilliseconds
'Different between iStartSec and iCurrentSec will give you diff in MilliSecs

Вы также можете использовать формулу =NOW(), рассчитанную в ячейке:

Dim ws As Worksheet
Set ws = Sheet1

 ws.Range("a1").formula = "=now()"
 ws.Range("a1").numberFormat = "dd/mm/yyyy h:mm:ss.000"
 Application.Wait Now() + TimeSerial(0, 0, 1)
 ws.Range("a2").formula = "=now()"
 ws.Range("a2").numberFormat = "dd/mm/yyyy h:mm:ss.000"
 ws.Range("a3").formula = "=a2-a1"
 ws.Range("a3").numberFormat = "h:mm:ss.000"
 var diff as double
 diff = ws.Range("a3")

Извините, что разбудил этот старый пост, но я получил ответ:
Напишите функцию для Millisecond следующим образом:

Public Function TimeInMS() As String
TimeInMS = Strings.Format(Now, "HH:nn:ss") & "." & Strings.Right(Strings.Format(Timer, "#0.00"), 2) 
End Function    

Используйте эту функцию в своем подразделе:

Sub DisplayMS()
On Error Resume Next
Cancel = True
Cells(Rows.Count, 2).End(xlUp).Offset(1) = TimeInMS()
End Sub

Если точности Timer() достаточно, вы можете просто создать метку времени, объединив дату и время с миллисекундами:

Function Now2() As Date

    Now2 = Date + CDate(Timer / 86400)

End Function

Чтобы вычислить разницу между двумя метками времени в миллисекундах, вы можете вычесть их:

Sub test()

    Dim start As Date
    Dim finish As Date
    Dim i As Long

    start = Now2
    For i = 0 To 100000000
    Next
    finish = Now2
    Debug.Print (finish - start) & " days"
    Debug.Print (finish - start) * 86400 & " sec"
    Debug.Print (finish - start) * 86400 * 1000 & " msec"

End Sub

Фактическая точность этого метода для меня составляет около 8 мс (кстати, GetTickCount еще хуже - 16 мс).

Помимо метода, описанного AdamRalph (GetTickCount()), вы можете сделать это:

• Использование функций API QueryPerformanceCounter() и QueryPerformanceFrequency()
  Как вы тестируете время выполнения кода VBA?
• или, для сред без доступа к Win32 API (например, VBScript), это:
  http://ccrp.mvps.org/ (см. раздел загрузки для установки COM-объектов «High-Performance Timer». Они бесплатны.)