Свертывание, композиция функций, монады и лень, боже мой?

Я озадачен. Я могу написать это:

import Control.Monad

main = print $ head $ (foldr (.) id [f, g]) [3]
  where f = (1:)
        g = undefined

и выход 1. Это имеет смысл, потому что это сводится к:

main = print $ head $ ((1:) . undefined . id) [3]
main = print $ head $ (1:) ((undefined . id) [3])
main = print $ head $ 1 : ((undefined . id) [3])
main = print $ 1

Но если я использую смутно похожую монадическую технику, она не работает так же:

import Control.Monad

main = print $ (foldr (<=<) return [f, g]) 3
  where f = const Nothing
        g = undefined

Это попадает в prelude.Undefined. Что странно, потому что я ожидал бы, что он уменьшится:

main = print $ ((const Nothing) <=< undefined <=< return) 3
main = print $ return 3 >>= undefined >>= (\_ -> Nothing)
main = print $ Nothing -- nope! instead, undefined makes this blow up

Однако, изменив порядок композиции:

import Control.Monad

main = print $ (foldr (>=>) return [f, g]) 3
  where f = const Nothing
        g = undefined

выполняет ожидаемое короткое замыкание и выдает Nothing.

main = print $ (const Nothing >=> undefined >=> return) 3
main = print $ (const Nothing 3) >>= undefined >>= return
main = print $ Nothing >>= undefined >>= return
main = print $ Nothing

Я полагаю, что сравнение двух подходов могло бы сравнить яблоки и апельсины, но можете ли вы объяснить разницу? Я думал, что f <=< g был монадическим аналогом f . g, но они, по-видимому, не так аналогичны, как я думал. Можете ли вы объяснить, почему?


function-composition fold haskell monads
person Dan Burton    schedule 23.11.2011    source источник

Ответы (2)


arrow_upward
21
arrow_downward

Это зависит от того, с какой монадой вы работаете и как определен ее оператор (>>=).

В случае Maybe, (>>=) является строгим в своем первом аргументе, как объяснил Даниэль Фишер.

Вот некоторые результаты для нескольких других монад.

> :set -XNoMonomorphismRestriction
> let foo = (const (return 42) <=< undefined <=< return) 3
> :t foo
foo :: (Num t, Monad m) => m t

Идентификация: Ленивый.

> Control.Monad.Identity.runIdentity foo
42

IO: Строгий.

> foo :: IO Integer
*** Exception: Prelude.undefined

Читатель: Ленивый.

> Control.Monad.Reader.runReader foo "bar"
42

Писатель: имеет как ленивый, так и строгий вариант.

> Control.Monad.Writer.runWriter foo
(42,())
> Control.Monad.Writer.Strict.runWriter foo
*** Exception: Prelude.undefined

Состояние: также имеет как строгую, так и ленивую версию.

> Control.Monad.State.runState foo "bar"
(42,"*** Exception: Prelude.undefined
> Control.Monad.State.Strict.runState foo "bar"
*** Exception: Prelude.undefined

Прод.: Строг.

> Control.Monad.Cont.runCont foo id
*** Exception: Prelude.undefined
person hammar    schedule 23.11.2011

arrow_upward
19
arrow_downward

Привязка для Maybe является строгой в первом аргументе.

Just v >>= f = f v
Nothing >>= f = Nothing

Поэтому, когда вы пытаетесь

Just v >>= undefined >>= \_ -> Nothing

ты попал

undefined v >>= \_ -> Nothing

и реализация должна выяснить, является ли undefined v Nothing или Just something, чтобы увидеть, какое уравнение (>>=) использовать.

С другой стороны,

Nothing >>= undefined

определяет результат, не глядя на второй аргумент (>>=).

person Daniel Fischer    schedule 23.11.2011