Строка WM_COPYDATA не отображается в целевом приложении

Я думаю, это хорошая привычка добавить

  copyDataStruct.dwData := Handle; 

в procedure TMF.SendString; - если у вас нет пользовательского идентификатора, установка исходного значения HWND поможет отладке на месте назначения (вы можете проверить это значение на другой стороне и, следовательно, избежать неправильного понимания широковещательного WMCOPY_DATA например - да, не должно быть быть, но я видел некоторые!).

И

    procedure WMCopyData(var Msg : TWMCopyData); message WM_COPYDATA;

в TMF определении клиентского класса, верно?

После вложенного вызова SendData должно быть отсутствующее exit или else:

procedure TMF.SendData(copyDataStruct: TCopyDataStruct);
  (...)
      Sleep(3000);
      SendData(copyDataStruct);
   end else
     SendMessage(rh, WM_COPYDATA, NativeInt(Handle), NativeInt(@copyDataStruct));
end;

Но это мало что изменит.

Проверьте возвращенный дескриптор rh := FindWindow(): это дескриптор клиентской формы TMF или Application.Handle?

Есть несколько проблем с вашим кодом.

Во-первых, вы не присваиваете сообщению уникальный идентификатор. VCL и различные сторонние компоненты также используют WM_COPYDATA, поэтому вы должны убедиться, что вы действительно обрабатываете ВАШЕ сообщение, а не ЧТО-ТО ДРУГОЕ сообщение.

Во-вторых, вы можете не дождаться запуска второго приложения достаточно долго. Вместо Sleep() используйте ShellExecuteEx() с флагом SEE_MASK_WAITFORINPUTIDLE (или используйте CreateProcess() и WaitForInputIdle()).

В-третьих, при запуске второго приложения ваша рекурсивная логика пытается отправить сообщение во второй раз. Если это не сработает, вы запустите третье приложение и так далее. Вы должны полностью убрать рекурсию, она вам не нужна.

Попробуй это:

var
  GetPhoneMsg: DWORD = 0;

procedure TMF.SendString;
var
  copyDataStruct: TCopyDataStruct;
  s: AnsiString;
begin
  if GetPhoneMsg = 0 then Exit;
  s := ebFirm.Text;
  copyDataStruct.dwData := GetPhoneMsg;
  copyDataStruct.cbData := Length(s);
  copyDataStruct.lpData := PAnsiChar(s);
  SendData(copyDataStruct);
end;

procedure TMF.SendData(copyDataStruct: TCopyDataStruct);
var
  rh: HWND;
  si: TShellExecuteInfo;
  res: Integer;
begin
  rh := FindWindow(PChar('TMF'), PChar('Get Phone'));
  if rh = 0 then
  begin
    // Launch the target application and give time to start
    ZeroMemory(@si, SizeOf(si));
    si.cbSize := SizeOf(si);
    si.fMask := SEE_MASK_WAITFORINPUTIDLE;
    si.hwnd := Handle;
    si.lpVerb := 'open';
    si.lpFile := GetPhone;
    si.nShow := SW_SHOWNORMAL;
    if not ShellExecuteEx(@si) then Exit;
    rh := FindWindow(PChar('TMF'), PChar('Get Phone'));
    if rh = 0 then Exit;
  end;
  SendMessage(rh, WM_COPYDATA, WParam(Handle), LParam(@copyDataStruct));
end;

initialization
  GetPhoneMsg := RegisterWindowMessage('TMF_GetPhone');

Получить заявку

var
  GetPhoneMsg: DWORD = 0;

procedure TMF.WMCopyData(var Msg: TWMCopyData);
var
  s : AnsiString;
begin
  if (GetPhoneMsg <> 0) and (Msg.CopyDataStruct.dwData = GetPhoneMsg) then
  begin
    SetString(s, PAnsiChar(Msg.CopyDataStruct.lpData), Msg.CopyDataStruct.cbData);
    jobstatus.Panels[1].Text := s;
  end else
    inherited;
end;

initialization
  GetPhoneMsg := RegisterWindowMessage('TMF_GetPhone');

Он больше не работает, если вы используете Windows 7. Если вы используете его, посетите эту страницу, чтобы узнать, как добавить исключение: http://msdn.microsoft.com/en-us/library

Я думал, что была проблема с дескриптором (rh), равным 0, когда вы его вызываете, если приложение нужно запустить. Но теперь я вижу, что SendData вызывает себя рекурсивно. Я добавил комментарий в коде для этого, так как это было неочевидно. Но теперь есть другая проблема. Второй экземпляр SendData будет иметь правильный дескриптор. Но затем вы выскочите из этого, вернетесь к первому экземпляру, где дескриптор все еще равен 0, а затем вы снова вызовете SendMessage, на этот раз с дескриптором 0. Это, вероятно, не является причиной вашей проблемы, но это непреднамеренно, ненужно и в целом плохо. ИМО, это случай, когда все усложняется, пытаясь быть слишком умным.