Clojure.spec: существование поля на основе другого поля в генераторе

Допустим, у нас есть API для сохранения в БД* атрибутов различных типов файлов: текст, изображения, аудио и видео файлы. Он должен иметь возможность получать следующие поля в зависимости от их типа:
базовые свойства для всех файлов:

{"file-type": "text",
"location": "/Documents",
"creation-time": "2020-03-02",
"name": "sometext.txt"}

дополнительные реквизиты, характерные только для некоторых типов:

text: only base props
video file: base props + {"duration(s)":123, "resolution":"4k"}
audio file: base props + {"duration(s)":123}
image: base props + {"resolution":"2048x1536"}

как мы видим, некоторые поля должны быть нулевыми в зависимости от "типа файла". Допустим, нам нужно проверить этот тип ввода, который может быть любым описанным типом. Итак, характеристики:

(s/def ::file-type (s/with-gen (s/and string? not-empty) #(s/gen #{"text" "image" "video" "audio"})))
(s/def ::location (s/with-gen (s/and string? not-empty) #(s/gen #{"/Documents"})))
(s/def ::creation-time (s/with-gen (s/and string? not-empty) #(s/gen #{"2020-03-02"}))) ;for simplicity
(s/def ::name (s/with-gen (s/and string? not-empty) #(s/gen #{"sometext.txt" "image.jpg" "video.mp4" "audio.mp3"}))) ;for simplicity
(s/def ::duration (s/and int? not-empty))                   ;for simplicity
(s/def ::resolution (s/with-gen (s/and string? not-empty) #(s/gen #{"4k" "2048x1536"}))) ;for simplicity
(s/def ::files-input (s/keys :req-un [::file-type ::location ::creation-time ::extension] :opt-un [::duration ::resolution]))

Предположим также, что существует программный валидатор, который проверяет, был ли передан правильный набор полей для каждого типа файла (например, у "видео" есть поле "длительность", а у "текста" нет).
Вопрос в том, как это сделать. генерировать полные готовые входные данные с этими зависимостями для модульных тестов (включая зависимые поля)?

*(оставим в стороне вопрос, подходит ли этот дизайн для API, так как этот пример не из реальной жизни, а только для демонстрации)


unit-testing clojure generator clojure.spec
person jsay    schedule 25.04.2020    source источник

Ответы (1)


arrow_upward
8
arrow_downward

На основе документа multi-spec мы должны добавить отдельный метод с собственным набором полей для каждого случая:

(s/def ::file-type (s/with-gen (s/and string? not-empty) #(s/gen #{"text" "image" "video" "audio"})))
(s/def ::location (s/with-gen (s/and string? not-empty) #(s/gen #{"/Documents"})))
(s/def ::creation-time (s/with-gen (s/and string? not-empty) #(s/gen #{"2020-03-02"}))) ;for simplicity
(s/def ::name (s/with-gen (s/and string? not-empty) #(s/gen #{"sometext.txt" "image.jpg" "video.mp4" "audio.mp3"}))) ;for simplicity
(s/def ::duration pos-int?)                                 ;for simplicity
(s/def ::resolution (s/with-gen (s/and string? not-empty) #(s/gen #{"4k" "2048x1536"}))) ;for simplicity
(s/def ::base-props (s/keys :req-un [::file-type ::location ::creation-time ::name]))
(s/def ::file-type-key (s/with-gen keyword? #(s/gen #{:text :image :video :audio})))

(defmulti file :file-type-key)
(defmethod file :text [_]
    (s/merge (s/keys :req-un [::file-type-key]) ::base-props))
(defmethod file :image [_]
    (s/merge (s/keys :req-un [::file-type-key ::resolution]) ::base-props))
(defmethod file :video [_]
    (s/merge (s/keys :req-un [::file-type-key ::duration ::resolution]) ::base-props))
(defmethod file :audio [_]
    (s/merge (s/keys :req-un [::file-type-key ::duration]) ::base-props))
(defmethod file :default [_]
    (s/merge (s/keys :req-un [::file-type-key]) ::base-props))

(s/def ::file-input (s/and (s/multi-spec file :file-type-key)
                           (fn [{:keys [file-type file-type-key]}]
                               (= file-type-key (keyword file-type)))))

даст сгенерированный ввод для модульного теста (проверяется stest/check):

(gen/sample (s/gen ::file-input) 2)
=>
({:file-type-key :text, :file-type "text", :location "/Documents", :creation-time "2020-03-02", :name "sometext.txt"}
 {:file-type-key :image,
  :resolution "4k",
  :file-type "image",
  :location "/Documents",
  :creation-time "2020-03-02",
  :name "sometext.txt"})

нам пришлось добавить еще одно поле ::file-type-key в качестве селектора (должно быть ключевым словом), но оно не влияет на тесты и может быть легко dissoced.

person jsay    schedule 25.04.2020