Как нарисовать полупрозрачное изображение на форме?

Я нашел решение, которое позволит вам нарисовать изображение BMP с альфа-каналом в форме, используя только Windows API:

const
  AC_SRC_OVER = 0;
  AC_SRC_ALPHA = 1;

type
  BLENDFUNCTION = packed record
    BlendOp,
    BlendFlags,
    SourceConstantAlpha,
    AlphaFormat: byte;
  end;

function WinAlphaBlend(hdcDest: HDC; xoriginDest, yoriginDest, wDest, hDest: integer;
  hdcSrc: HDC; xoriginSrc, yoriginSrc, wSrc, hSrc: integer; ftn: BLENDFUNCTION): LongBool;
  stdcall; external 'Msimg32.dll' name 'AlphaBlend';

procedure TForm4.FormClick(Sender: TObject);
var
  hbm: HBITMAP;
  bm: BITMAP;
  bf: BLENDFUNCTION;
  dc: HDC;
begin
  hbm := LoadImage(0,
    'C:\Users\Andreas Rejbrand\Skrivbord\RatingCtrl.bmp',
    IMAGE_BITMAP,
    0,
    0,
    LR_LOADFROMFILE);
  if hbm = 0 then
    RaiseLastOSError;
  try
    if GetObject(hbm, sizeof(bm), @bm) = 0 then RaiseLastOSError;
    dc := CreateCompatibleDC(0);
    if dc = 0 then RaiseLastOSError;
    try
      if SelectObject(dc, hbm) = 0 then RaiseLastOSError;
      bf.BlendOp := AC_SRC_OVER;
      bf.BlendFlags := 0;
      bf.SourceConstantAlpha := 255;
      bf.AlphaFormat := AC_SRC_ALPHA;
      if not WinAlphaBlend(Canvas.Handle,
        10,
        10,
        bm.bmWidth,
        bm.bmHeight,
        dc,
        0,
        0,
        bm.bmWidth,
        bm.bmHeight,
        bf) then RaiseLastOSError;
    finally
      DeleteDC(dc);
    end;
  finally
    DeleteObject(hbm);
  end;
end;

Используя GIMP, я преобразовал изображение PNG.

нашел здесь 32-битное растровое изображение RGBA, нашел здесь, и результат очень хороший:

Почему бы не попробовать нарисовать свой png на новом изображении с помощью обычного BMP. Нарисуйте то, что вы хотите, на изображении 2 и перерисуйте / или назначьте / все на изображение 1, когда закончите. Должен работать ...

Подход TransparentColorValue не может работать, потому что он работает только с изображениями, в которых один цвет представляет полную прозрачность. [Кроме того, вы играете с прозрачным цветом формы вместо прозрачного цвета изображения!] Предполагается, что указанное выше изображение PNG имеет альфа-канал , поэтому не все пиксели отображаются или прозрачны - вместо этого каждый пиксель имеет непрозрачность от 0 до 1 (например, 0,37). То есть, в дополнение к компонентам R, G и B каждого пикселя существует альфа-компонент A.