Советы и рекомендации Vim и Ctags

Ctrl + ] - перейти к определению
Ctrl + T - вернуться к определению.
Ctrl + W Ctrl + ] - открыть определение в горизонтальном разделении

Добавьте эти строки в vimrc
map <C-\> :tab split<CR>:exec("tag ".expand("<cword>"))<CR>
map <A-]> :vsp <CR>:exec("tag ".expand("<cword>"))<CR>

Ctrl + \ - открыть определение в новой вкладке
Alt + ] - открыть определение в вертикальный раскол

После создания тегов. Вы можете использовать следующие клавиши для включения и выключения функций:

Ctrl + Left MouseClick - перейти к определению
Ctrl + Right MouseClick - вернуться к определению

Одна строка, которая всегда идет в моем .vimrc:

set tags=./tags;/

Это будет искать в текущем каталоге «теги» и двигаться вверх по дереву к корню, пока не будет найден один. IOW, вы можете находиться где угодно в дереве исходных текстов, а не только в его корне.

Еще один полезный плагин для разработки на C - cscope. Так же, как Ctags позволяет переходить к определениям, Cscope переходит к вызов функций.

Если у вас есть cscope в вашем каталоге ~ / bin /, добавьте следующее в ваш .vimrc и используйте g ^] для перехода к вызывающей функции (см.: Help cscope).

if has("cscope")
    set csprg=~/bin/cscope
    set csto=0
    set cst
    set nocsverb
    " add any database in current directory
    if filereadable("cscope.out")
        cs add cscope.out
        " else add database pointed to by environment
    elseif $CSCOPE_DB != ""
        cs add $CSCOPE_DB
    endif
endif

Чуть не забыл ... Так же, как ctags - нужно генерировать (и периодически обновлять) базу данных. Я использую следующий скрипт

select_files > cscope.files
ctags -L cscope.files
ctags -e -L cscope.files
cscope -ub -i cscope.files

Где select_files - это еще один сценарий, который извлекает список файлов C и заголовочных файлов из Makefile. Таким образом я индексирую только те файлы, которые фактически используются в проекте.

Вы можете добавлять каталоги в поиск по ctags. Например, у меня есть индекс ctags, созданный для Qt4, и он есть в моем .vimrc:

set tags+=/usr/local/share/ctags/qt4

Все вышеперечисленное и ...

code_complete: завершение параметра функции, фрагменты кода и многое другое.

• http://www.vim.org/scripts/script.php?script_id=1764

taglist.vim: браузер исходного кода (поддерживает C / C ++, java, perl, python, tcl, sql, php и т. д.)

• http://www.vim.org/scripts/script.php?script_id=273

Я использую ALT-left и ALT-right, чтобы выталкивать / выталкивать из / в стек тегов.

" Alt-right/left to navigate forward/backward in the tags stack
map <M-Left> <C-T>
map <M-Right> <C-]>

Если вы используете hjkl для движения, вы можете вместо этого отобразить <M-h> и <M-l>.

Несколько определений одного и того же имени

<C-w>g<C-]> открыть определение в разделе, но также сделать :tjump, который либо переходит к определению, либо, если определений несколько, предоставляет вам список определений на выбор.

Чаще всего я использую команду C-], которая переходит к определению функции под курсором. Вы можете использовать его чаще, чтобы следить за большим количеством звонков. После этого C-o вернет вас на один уровень, C-i снова войдет глубже.

Я считаю, что подключаемый модуль taglist просто необходим. Он перечисляет все теги, о которых он знает (файлы, которые вы открыли), в отдельном окне и упрощает навигацию по большим файлам.

Я использую его в основном для разработки на Python, но он может быть лучше только для C / C ++.

Я инкапсулировал манипуляции с тегами в экспериментальном плагине мой.

Что касается разработки на C ++ в vim, я уже ответил там : Я использую свой собственный набор и несколько других плагинов.

Я адаптирую свои плагины vim в течение двух лет для поддержки достаточно большого проекта C ++. Вы можете взглянуть на них.

Они используют ctags и cscsope.

http://www.vim.org/scripts/script.php?script_id=1638
http://www.vim.org/scripts/script.php?script_id=2507

Я поместил следующее в свой файл .gvimrc, который ищет по дереву из любой точки файл тегов при запуске gvim:

function SetTags()
    let curdir = getcwd()

    while !filereadable("tags") && getcwd() != "/"
        cd ..
    endwhile

    if filereadable("tags")
        execute "set tags=" . getcwd() . "/tags"
    endif

    execute "cd " . curdir
endfunction

call SetTags()

Затем я периодически регенерирую файл тегов в верхней части моего исходного дерева с помощью сценария, который выглядит так:

#!/bin/bash

find . -regex ".*\.\(c\|h\|hpp\|cc\|cpp\)" -print | ctags --totals --recurse --extra="+qf" --fields="+i" -L -

Я использую vim в macos, и исходные теги ctags не работают, поэтому я загружаю самую новую и настраиваю make make install. Я устанавливаю ctgas в / usr / local / bin / ctags (чтобы сохранить исходный)

"taglist
let Tlist_Ctags_Cmd = "/usr/local/bin/ctags"
let Tlist_WinWidth = 50
map <leader>ta :TlistToggle<cr>
map <leader>bta :!/usr/local/bin/ctags -R .<CR>
set tags=tags;/
map <M-j> <C-]>
map <M-k> <C-T>

Я адаптировал указанную выше функцию поиска SetTags () (которую следует заменить на эквивалент set tags+=./tags;/) для работы с cscope. Кажется, работает!

"cscope file-searching alternative
function SetCscope()
    let curdir = getcwd()

    while !filereadable("cscope.out") && getcwd() != "/"
            cd ..
                endwhile

    if filereadable("cscope.out")
            execute "cs add " . getcwd() . "/cscope.out"
                endif

    execute "cd " . curdir
    endfunction

call SetCscope()

Еще одна итерация вышеупомянутой функции SetCscope (). Это устанавливает предварительный путь cscope для получения совпадений, не находясь в каталоге, где "cscope.out":

function s:FindFile(file)
    let curdir = getcwd()
    let found = curdir
    while !filereadable(a:file) && found != "/"
        cd ..
        let found = getcwd()
    endwhile
    execute "cd " . curdir
    return found
endfunction

if has('cscope')    
    let $CSCOPE_DIR=s:FindFile("cscope.out")
    let $CSCOPE_DB=$CSCOPE_DIR."/cscope.out"
    if filereadable($CSCOPE_DB)
        cscope add $CSCOPE_DB $CSCOPE_DIR
    endif

    command -nargs=0 Cscope !cscope -ub -R &
endif