Snakemake заставляет контрольную точку и агрегатную функцию работать

Функция aggregate_input ожидает переменную wildcards.sample, но у вас нет подстановочных знаков, указанных в rule combine_fasta_file. Вы можете либо указать подстановочный знак в этом правиле, либо реорганизовать функцию для использования глобальной переменной, если это применимо.

Правило, которое собирает выходные данные контрольной точки (combine_fasta_file, в вашем случае), должно содержать подстановочные знаки, присутствующие в выходных данных правила контрольной точки (clustering, в вашем случае). Это связано с тем, что Snakemake смотрит на желаемый результат, а затем пытается вернуться через ваши правила к доступным входным файлам. Если подстановочные знаки в правиле сбора не включают подстановочные знаки правила контрольной точки, точная ссылка на контрольную точку может быть неоднозначной.

Чтобы уточнить комментарии к контрольной точке Snakemake docs пример Манавалана Гаджапати и многочисленные агрегации, необходимые для pabster212, я создал минимальный пример для выделения контрольных точек и множественного сбора.

Настройка входа:

mkdir -p input/sampleA_run{1,2,3}
mkdir -p input/sampleB_run{4,5}
touch input/sampleA_run1/{apple,banana,cucumber,beet,basil}.txt
touch input/sampleA_run2/{alpha,beta,gamma}.txt
touch input/sampleA_run3/{red,blue,green,brown}.txt
touch input/sampleB_run4/{alice,betty,beth,barbara,christy}.txt
touch input/sampleB_run5/{alex,brad,bart,bennett,clive}.txt

Snakefile, который проходит через контрольные точки и мультиагрегацию:

rule all:
    input:
        # Final
        expand("output/gathered_samples/{sample}.txt", sample = ["sampleA","sampleB"])

# My real-world analysis at this step (Nanopore guppy basecaller) 
# Takes as input a directory 
# With a inconsistent numbers of files and names for files (.fast5 in real analysis)
# Due to filtering, there are more inputs than outputs (.fastq in real analysis)
# And the output filenames are not predictably named or numbered
# Therefore I use a checkpoint to evaluate which output files have been created
# In this toy example, only files beginning with 'b' are maintained
checkpoint unpredictable_file_generator:
    input:
        "input/{sample}_{run_id}"
    output:
        directory("output/unpredictable_files/{sample}_{run_id}"),
    shell:
        """
        mkdir -p {output}

        for some_file in {input}/*
        do
            outfile=$(basename "$some_file")
            if [[ "$outfile" =~ ^b.* ]]
            then
                touch "{output}/$outfile"
            fi
        done
        """

# For my real-world analysis, this intermediate step 
# Represents generation of bams from fastqs
# No intermediate step is necessarily required following the checkpoint
# Just modify the input-gathering function below (gather_from_checkpoint) 
# To expand 'output/unpredictable_files' instead of 'output/intermediate_files'
rule intermediate_step:
    input:
        "output/unpredictable_files/{sample}_{run_id}/{file_id}.txt"
    output:
        "output/intermediate_files/{sample}_{run_id}/{file_id}.txt"
    shell:
        """
        cp {input} {output}
        """

# Function to gather all outputs from checkpoint rule
# The output of the rule referring back to the checkpoint (gather_one, below)
# Must contain the all wildcards in the checkpoint rule
# To gather further (e.g. gather by sample rather than by run_id)
# An additional gather rule is required
def gather_from_checkpoint(wildcards):
    checkpoint_output = checkpoints.unpredictable_file_generator.get(**wildcards).output[0]
    return expand("output/intermediate_files/{sample}_{run_id}/{file_id}.txt",
           sample=wildcards.sample,
           run_id=wildcards.run_id,
           file_id=glob_wildcards(os.path.join(checkpoint_output, "{file_id}.txt")).file_id)

# Gathers all files by run_id
# But each sample is still divided into runs
# For my real-world analysis, this could represent a 'samtools merge bam'
rule gather_one:
    input:
        gather_from_checkpoint
    output:
        "output/gathered_runs/{sample}_{run_id}.txt"
    shell:
        """
        # Generate a file for each run 
        # Containing the names of all files output by 'unknown_file_generator' 
        echo {input} | tr ' ' $'\\n' > {output}
        """

# Gathers all previously-run_id-gathered files by sample
# For my real-world analysis, this could represent a second 'samtools merge bam'
# After which point the first merge could potentially be removed if it were marked 'temporary'
############
# Note wildcard restriction was required 
# To prevent the {run_id} match from descending into diretories
# And generating 'ChildIOException' errors
rule gather_two:
    input:
        lambda wildcards: expand("output/gathered_runs/{sample}_{run_id}.txt",
            sample = wildcards.sample,
            run_id = glob_wildcards("input/" + wildcards.sample + "_{run_id,[^/]+}/").run_id)
    output:
        "output/gathered_samples/{sample}.txt"
    shell:
        """
        # This output should contain 6 filenames for each sample
        # Each beginning with 'b'
        cat {input} > {output}
        """