читать CSV файл в Cplex

Надеюсь, я правильно понял ваше объяснение. Предположим, у вас есть файл weight.csv такого вида:

1,2,
3,7,
4,9,

Здесь первый элемент в каждой строке - это индекс точки спроса, второй элемент - это его вес. Затем вы можете проанализировать это, как и раньше, используя этот блок сценария:

tuple demandpoint {
    int index;
    int weight;
}

{demandpoint} demand={};

execute {
  var f = new IloOplInputFile("weight.csv");
  while (!f.eof) {
   var data = f.readline().split(",");
   if (data.length == 3)
     demand.add(Opl.intValue(data[0]), Opl.intValue(data[1]));
  }
  writeln(demand);
}

Затем вы можете создать набор, содержащий индексы всех точек спроса:

{int} demandpoints = { d.index | d in demand };

Предположим, файл test1.csv выглядит так

1,1,0,
1,2,5,
1,3,6,
1,4,7,
3,1,1,
3,2,1.5,
3,3,0,
3,4,3.5,
4,1,1,
4,2,1.5,
4,3,1.7,
4,4,0,

Здесь первый элемент - это индекс точки спроса, второй элемент - индекс заведения, а третий элемент - это расстояние между первым и вторым элементом. Обратите внимание, что нет строк, начинающихся с 2, поскольку нет точки спроса с индексом 2 в weight.csv. Также обратите внимание, что я предполагаю здесь только 4 возможности (чтобы файл был коротким). Вы можете прочитать расстояние между точками спроса и предприятиями следующим образом:

range facilities = 1..4;
float d[demandpoints][facilities];

execute {
  var f = new IloOplInputFile("test1.csv");
  while (!f.eof) {
    var data = f.readline().split(",");
    if (data.length == 4)
      d[Opl.intValue(data[0])][Opl.intValue(data[1])] = Opl.floatValue(data[2]);
  }
  writeln(d);
}

Полный сценарий (включая фиктивную цель и ограничения для запуска) выглядит так:

tuple demandpoint {
    int index;
    int weight;
}

{demandpoint} demand={};

execute {
  var f = new IloOplInputFile("weight.csv");
  while (!f.eof) {
   var data = f.readline().split(",");
   if (data.length == 3)
     demand.add(Opl.intValue(data[0]), Opl.intValue(data[1]));
  }
  writeln(demand);
}

// Create a set that contains all the indeces of demand points
// as read from weight.csv
{int} demandpoints = { d.index | d in demand };

range facilities = 1..4;
float d[demandpoints][facilities];

execute {
  var f = new IloOplInputFile("test1.csv");
  while (!f.eof) {
    var data = f.readline().split(",");
    if (data.length == 4)
      d[Opl.intValue(data[0])][Opl.intValue(data[1])] = Opl.floatValue(data[2]);
  }
  writeln(d);
}

minimize 0;
subject to {}

Он печатает

 {<1 2> <3 7> <4 9>}
 [[0 5 6 7]
  [1 1.5 0 3.5]
  [1 1.5 1.7 0]]

Будьте осторожны с тем, сколько запятых у вас в CSV! В приведенном выше коде предполагается, что каждая строка заканчивается запятой. То есть в каждой строке столько запятых, сколько полей. Если последнее поле не заканчивается запятой, вам необходимо адаптировать синтаксический анализатор.

Если у вас есть test1.csv расстояние между всеми узлами, тогда имеет смысл сначала прочитать данные в массив float distance[facilities][facilities];, а затем определить массив d на основе этого как

float d[i in demandpoints][j in facilities] = distance[i][j];

Обновите для более подробной спецификации, которую вы указали в комментариях: чтобы обработать test1.csv, который вы объяснили в комментариях, вы можете определить новый кортеж:

tuple Distance {
   int demandpoint;
   int facility;
   float distance;
}
{Distance} distances = {};

и прочтите / проанализируйте его точно так же, как вы проанализировали файл weight.csv (конечно, с одним дополнительным полем). Затем вы можете создать матрицу расстояний следующим образом:

float d[i in I][j in J] = sum (dist in distances : dist.demandpoint == i && dist.facility == j) dist.distance;

Здесь I и J - это наборы или диапазоны точек спроса и средств обслуживания соответственно. См. Выше, как получить набор всех точек спроса, определенных в наборе кортежей. Созданная матрица будет содержать запись для каждой пары точка спроса / расстояние. Уловка в определении d состоит в том, что есть два случая:

1. Если пара (i, j) определена в test1.csv, тогда сумма будет соответствовать ровно одному элементу в distances: тому, который определяет расстояние между двумя точками.
2. Если пара (i, j) не определена в test1.csv, тогда сумма не будет ни с чем совпадать, и соответствующая запись в матрице расстояний, таким образом, будет равна 0.