Пакетный режим против полностью потокового XSLT

Если порядок свойств в JSON не имеет значения, вы можете напрямую создавать карты и массивы XSLT / XPath 3 с xsl:map/xsl:map-entry (или конструктором XPath 3.1 map) и специфическим для Saxon элементом расширения saxon:array (к сожалению, в языковом стандарте XSLT 3 отсутствует инструкция по созданию массива). Более того, большинство ваших итерационных параметров, кажется, легко реализовать в виде аккумуляторов:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:saxon="http://saxon.sf.net/"
    extension-element-prefixes="saxon"
    xpath-default-namespace="urn:com.workday.report/INT1109_CR_REV_Customer_Invoices_to_Connect"
    exclude-result-prefixes="#all"
    version="3.0">

    <xsl:output method="adaptive" indent="yes"/>

    <xsl:mode streamable="yes" use-accumulators="#all" on-no-match="shallow-skip"/>

    <xsl:accumulator name="header-count" as="xs:integer" initial-value="0" streamable="yes">
        <xsl:accumulator-rule match="Report_Entry" select="$value + 1"/>
    </xsl:accumulator>

    <xsl:accumulator name="lines-count" as="xs:integer" initial-value="0" streamable="yes">
        <xsl:accumulator-rule match="Report_Entry/total_lines/text()" select="$value + xs:integer(.)"/>
    </xsl:accumulator>

    <xsl:template match="Report_Data">
        <xsl:apply-templates/>
        <xsl:sequence
            select="map {
                     'Stats': map { 
                          'Total Header Count' : accumulator-after('header-count'),
                          'Total Lines Count' : accumulator-after('lines-count')
                        }
                    }"/>
    </xsl:template>

    <xsl:template match="Report_Entry">
        <xsl:map>
            <xsl:apply-templates/>
        </xsl:map>
    </xsl:template>

    <xsl:template match="Report_Entry/id | Report_Entry/revenue_stream | lines/sequence | lines/sales_item_id">
        <xsl:map-entry key="local-name()" select="string()"/>
    </xsl:template>

    <xsl:template match="Report_Entry/lines">
        <xsl:map-entry key="local-name()">
            <saxon:array>
                <xsl:apply-templates/>
            </saxon:array>
        </xsl:map-entry>
    </xsl:template>

</xsl:stylesheet>

В этом примере используется адаптивный метод вывода, поскольку ваш текущий образец не создает ни одного объекта JSON, и я просто попытался создать тот же вывод, что и ваш текущий код; для метода вывода JSON потребуется одна карта или массив в качестве результата основной последовательности.

Код работает с потоковой передачей и Saxon EE 9.9.1.1 в oXygen, к сожалению, 9.8 не считает код потоковым.

Что касается общих правил, существуют ограничения на то, чего вы можете достичь с помощью аккумуляторов и сопоставления шаблонов при потоковой передаче; как вы можете видеть, аккумулятор для суммирования значений из элементов total_lines должен соответствовать текстовому дочернему элементу, чтобы не потреблять элемент в аккумуляторе (однако у Saxon есть еще одно расширение для захвата аккумуляторов, чтобы облегчить такие задачи).

До сих пор я бы сказал, что более важно найти способ обойти анализ потоковой передачи и обеспечить, чтобы потоковый код возвращал правильный и тот же результат, что и непотоковый код; например, при экспериментировании с подходом к генерации JSON с потоковой передачей с использованием двух шагов преобразования, где некоторые образцы данных, подобные вашим, являются входными, представление XML для JSON является результатом первого преобразования, а JSON должен быть результатом использования xml-to-json в результате первого шага я столкнулся с саксонской ошибкой https://saxonica.plan.io/issues/4215.

Что касается потоковой передачи, кажется, что недостаточно тестового покрытия или зрелости реализации, чтобы иметь возможность надежно комбинировать функции сложным и масштабируемым образом, частично из-за сложной спецификации, частично из-за ограниченного использования этого материала XSLT-сообществом.

Поэтому, если вы найдете рабочий способ решения конкретной проблемы для использования потоковой передачи, чтобы снизить потребление памяти или управлять им по сравнению с обычной обработкой на основе дерева XSLT 2/3, вы, конечно, можете поэкспериментировать с изменениями для повышения производительности, но это легко сломать. .

Одно общее наблюдение заключается в том, что потоковая передача позволяет вам получить доступ ко всем атрибутам текущего обрабатываемого / согласованного элемента, но не к его дочерним элементам, поэтому может очень помочь вставка шагов обработки, которые преобразуют элементы в атрибуты, если у вас есть простая структура дочерних элементов. Таким образом, вы сможете избежать copy-of(). Но, конечно, вам нужен способ объединения двух таблиц стилей, который Saxon позволяет с его API, но для этого требуется написание кода Java или .NET.