Использование fn: random-number-generator для получения случайных чисел более одного раза

Ваш вопрос инкапсулирует проблему:

Я пытаюсь написать простую функцию, которая будет выдавать мне случайную букву каждый раз, когда я ее вызываю.

Но функция, которая дает разные результаты при разных вызовах (с одними и теми же аргументами), не является истинной («чистой») функцией.

Один из выходов - использовать тот факт, что XSLT уже имеет своего рода «нечистые» функции: функция, которая создает новый узел, каждый раз возвращает другой узел, и вы можете раскрыть это, используя generate-id (). Чтобы вы могли написать

<xsl:function name="my:random" as="xs:double">
  <xsl:variable name="dummy"><a/></xsl:variable>
  <xsl:sequence select="fn:random-number-generator(generate-id($dummy))?permute(1 to 10)"/>
</xsl:function>

Единственная проблема заключается в том, что вы находитесь на грани того, что четко определено в спецификации, и оптимизатор может не позволить вам уйти от таких уловок. Гораздо лучше, если вы можете, найти способ передачи различных аргументов функции каждый раз, когда она вызывается: например, порядковый номер или generate-id (), применяемый к входному узлу, который вы в настоящее время обрабатываете.

В контексте XSLT 3 я думаю, что один из способов создать «новый» random-number-generator для каждого нужного вам узла - это определить аккумулятор:

<xsl:accumulator name="rng" as="map(xs:string, item())" initial-value="random-number-generator(current-dateTime())">
    <xsl:accumulator-rule match="foo[@type]" select="$value?next()"/>
</xsl:accumulator>

Таким образом, вы можете реализовать свою функцию как

<xsl:function name="gdpr:randomLetter" as="item()*">
    <xsl:param name="type" as="xs:string"/>
    <xsl:param name="rng" as="map(xs:string, item())"/>
    <xsl:choose>
        <xsl:when test="$type = 'A'">
            <xsl:variable name="randomNumber" select="$rng?permute(1 to 7)[1]"/>
            <xsl:variable name="letters" select="('A','O','U','E','I','Y','Q')"/>
            <xsl:sequence select="$letters[$randomNumber]"/>
        </xsl:when>
        <xsl:when test="$type = 'a'">
            <xsl:variable name="randomNumber" select="$rng?permute(1 to 7)[1]"/>
            <xsl:variable name="letters" select="('a','o','u','e','i','y','q')"/>
            <xsl:sequence select="$letters[$randomNumber]"/>
        </xsl:when>
        <xsl:when test="$type = 'B'">
            <xsl:variable name="randomNumber" select="$rng?permute(1 to 19)[1]"/>
            <xsl:variable name="letters" select="('W','R','T','P','S','D','F','G','H','J','K','L','M','N','B','V','C','X','Z')"/>
            <xsl:sequence select="$letters[$randomNumber]"/>
        </xsl:when>
        <xsl:when test="$type = 'b'">
            <xsl:variable name="randomNumber" select="$rng?permute(1 to 19)[1]"/>
            <xsl:variable name="letters" select="('w','r','t','p','s','d','f','g','h','j','k','l','m','n','b','v','c','x','z')"/>
            <xsl:sequence select="$letters[$randomNumber]"/>
        </xsl:when>
        <xsl:otherwise>
            <xsl:variable name="randomNumber" select="$rng?permute(1 to 52)[1]"/>
            <xsl:variable name="letters" select="('A','O','U','E','I','Y','Q','a','o','u','e','i','y','q','w','r','t','p','s','d','f','g','h','j','k','l','m','n','b','v','c','x','z','W','R','T','P','S','D','F','G','H','J','K','L','M','N','B','V','C','X','Z')"/>
            <xsl:sequence select="$letters[$randomNumber]"/>
        </xsl:otherwise>
    </xsl:choose>        
</xsl:function>

а затем назовите его, например,

<xsl:template match="foo[@type]">
    <xsl:copy>
        <xsl:value-of select="gdpr:randomLetter(@type, accumulator-before('rng'))"/>   
    </xsl:copy>
</xsl:template>

и убедитесь, что вы используете

<xsl:mode on-no-match="shallow-copy" use-accumulators="rng"/>

Проблема в том, что fn:random-number-generator function является детерминированный. В самой спецификации объясняется, что:

Обе формы функции являются · детерминированными ·: двойной вызов функции с одними и теми же аргументами в пределах одной · области выполнения · дает одинаковые результаты.

Вам необходимо правильно использовать функцию под ключом next, содержащуюся в результирующей карте, после вызова функции random-number-generator. Как сказано в спецификации:

Запись с ключом «next» - это функция нулевой арности, которую можно вызвать для возврата другого генератора случайных чисел.

Для полноты картины я предложил это решение, но оно работает только для небольших фрагментов текста из-за глубины рекурсии.

Кстати, я понял, что мое решение было пустой тратой времени, поскольку я использую exists-db, который не включает генератор случайных чисел в своей реализации XSLT.

<xsl:function name="gdpr:rngRecurseStart">
     <xsl:param name="text"></xsl:param>
     <xsl:variable name="chars" select="functx:chars($text)"/>

     <xsl:copy-of select="gdpr:rngRecurse($chars,random-number-generator(current-dateTime()),'')"></xsl:copy-of>
 </xsl:function>

 <xsl:function name="gdpr:rngRecurse">
     <xsl:param name="chars"></xsl:param>
     <xsl:param name="rngGenerator"></xsl:param>
     <xsl:param name="newText"></xsl:param>
     <xsl:variable name="curentchar" select="$chars[1]"></xsl:variable>
     <xsl:variable name="newRngGenerator" select="$rngGenerator?next()"/>
     <xsl:choose>
         <xsl:when test="count($chars) >1">
             <xsl:variable name="transformedChar" select="gdpr:randomLetter2($newRngGenerator,$curentchar)"/>
             <xsl:variable name="resultText" select="concat($newText, $transformedChar)"/>
             <xsl:copy-of select="gdpr:rngRecurse(subsequence($chars,2),$newRngGenerator,$resultText)"></xsl:copy-of>
         </xsl:when>
         <xsl:when test="count($chars) =1">
             <xsl:variable name="transformedChar" select="gdpr:randomLetter2($newRngGenerator,$curentchar)"/>
             <xsl:variable name="resultText" select="concat($newText, $transformedChar)"/>
             <xsl:copy-of select="$resultText"></xsl:copy-of>
         </xsl:when>
         <xsl:otherwise><xsl:copy-of select="$newText"></xsl:copy-of></xsl:otherwise>
     </xsl:choose>

 </xsl:function>