передача аргументов в кавычках из командного файла в `powershell start` - самоповышение по требованию

• Вы столкнулись с целой чередой двух адов цитирования (cmd и PowerShell), украшенных ошибка PowerShell (начиная с PowerShell Core 6.2.0).

• Чтобы обойти эту ошибку, пакетный файл нельзя повторно вызвать напрямую, вместо этого его необходимо повторно вызвать через cmd /c.

• Полезный ответ LotPings, который принимает это во внимание, обычно работает, но не в следующих пограничных случаях:

  • If the batch file's full path contains spaces (e.g., c:\path\to\my batch file.cmd)
  • Если аргументы содержат любой из следующих cmd метасимволов (даже внутри "..."): & | < > ^; например, one "two & three"
  • Если пакетный файл, повторно вызванный с правами администратора, полагается на выполнение в том же рабочем каталоге, из которого он был первоначально вызван.

Следующее решение касается всех этих крайних случаев. Хотя это далеко не тривиально, его можно использовать повторно как есть:

@echo off
setlocal

:: Test whether this invocation is elevated (`net session` only works with elevation).
:: If already running elevated (as admin), continue below.
net session >NUL 2>NUL && goto :elevated

:: If not, reinvoke with elevation.
set args=%*
if defined args set args=%args:^=^^%
if defined args set args=%args:<=^<%
if defined args set args=%args:>=^>%
if defined args set args=%args:&=^&%
if defined args set args=%args:|=^|%
if defined args set "args=%args:"=\"\"%"
powershell -NoProfile -ExecutionPolicy Bypass -Command ^
  " Start-Process -Wait -Verb RunAs -FilePath cmd -ArgumentList \"/c \"\" cd /d \"\"%CD%\"\" ^&^& \"\"%~f0\"\" %args% \"\" \" "
exit /b

:elevated
:: =====================================================
:: Now we are running elevated, in the same working dir., with args passed through.
:: YOUR CODE GOES HERE.

echo First argument is "%~1"
echo Second argument is "%~2"

pause

Это моя партия для этой цели:

::ElevateMe.cmd::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
@echo off & setlocal EnableExtensions DisableDelayedExpansion
Set "Args=%*"
net file 1>nul 2>&1 || (powershell -ex unrestricted -Command ^
  Start-Process -Verb RunAs -FilePath '%comspec%' -ArgumentList '/c %~f0 %Args:"=\""%'
  goto :eof)
:: Put code here that needs elevation
Echo:%*
Echo:%1
Echo:%2
Pause

Пример вывода:

one "two three"
one
"two three"
Drücken Sie eine beliebige Taste . . .

Если вы хотите, чтобы командная строка с повышенными правами оставалась открытой, используйте -ArgumentList '/k %~f0 %Args:"=\""%

Единственный одобренный способ повышения — использовать манифест. Это эмулирует SUDO.EXE Unix.

Чтобы запустить команду и оставаться на повышенных правах

RunAsAdminconsole <Command to run>

Чтобы поднять текущее окно cmd или создать новое окно с повышенными правами

RunAsAdminconsole 

Из https://pastebin.com/KYUgEKQv

REM Three files follow
REM RunAsAdminConsole.bat
REM This file compiles RunAsAdminconsole.vb to RunAsAdminconsole.exe using the system VB.NET compiler.
REM Runs a command elevated using a manifest
C:\Windows\Microsoft.NET\Framework\v4.0.30319\vbc "%~dp0\RunAsAdminconsole.vb" /win32manifest:"%~dp0\RunAsAdmin.manifest" /out:"%~dp0\RunAsAdminConsole.exe" /target:exe
REM To use
rem RunAsAdminconsole <Command to run>
pause

RunAsAdmin.manifest

<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<assembly xmlns="urn:schemas-microsoft-com:asm.v1" manifestVersion="1.0">
<assemblyIdentity
    version="1.0.0.0"
    processorArchitecture="*"
    name="Color Management"
    type="win32"
/>
<description>Serenity's Editor</description>
<trustInfo xmlns="urn:schemas-microsoft-com:asm.v2"> 
<security> 
    <requestedPrivileges> 
        <requestedExecutionLevel level="requireAdministrator" uiAccess="false"/> 
    </requestedPrivileges> 
</security> 
</trustInfo> 
</assembly>

'RunAsAdminConsole.vb
'Change cmd /k to cmd /c to elevate and run command then exit elevation
imports System.Runtime.InteropServices 
Public Module MyApplication  

    Public Sub Main ()
        Dim wshshell as object
        WshShell = CreateObject("WScript.Shell")
        Shell("cmd /k " & Command())
    End Sub 

End Module 


----------------------------------------