Преобразование между типами в дискриминируемых союзах

При немного другом дизайне можно использовать System.Convert.ChangeType и тот факт, что конструкторы размеченных объединений на самом деле являются функциями:

// statically typed wrapper for System.Convert.ChangeType
let conv a : 'T = System.Convert.ChangeType(a, typeof<'T>) :?> 'T

type MyCustomType() = class end

type ResultType = 
  | Boolean of bool
  | Integer of int
  | Decimal of decimal
  | Double of double
  | String of string
  | MyCustomType of MyCustomType
  with
    member this.ConvertTo (newType:'T->ResultType) =
      match this with
      | Boolean b -> newType( conv b )
      | Integer i -> newType( conv i )
      | Decimal d -> newType( conv d )
      | Double d -> newType( conv d )
      | String s -> newType( conv s )
      | MyCustomType m ->
         if typeof<'T> <> typeof<string> then
            raise (new System.InvalidCastException("MyCustomType can only be converted to String"))
         else
            String (m.ToString())

let i = Integer 42

let b = i.ConvertTo Boolean
printfn "%A" b

let d = i.ConvertTo Decimal
printfn "%A" d

let d2 = i.ConvertTo Double
printfn "%A" d2

let s = i.ConvertTo String
printfn "%A" s

//let mi = i.ConvertTo MyCustomType  // throws InvalidCastException

let m = MyCustomType (new MyCustomType())
let sm = m.ConvertTo String
printfn "%A" sm

//let im = m.ConvertTo Integer // throws InvalidCastException

РЕДАКТИРОВАТЬ: после того, как вы добавите больше настраиваемых типов, это не сильно поможет.

Может быть, вам стоит сделать так, чтобы ваши пользовательские типы реализовали IConvertible. Затем вы можете удалить код особого случая из ConvertTo и полностью полагаться на System.Convert.ChangeType.

Вам все равно придется расширять ToObject реализацию каждого настраиваемого типа всякий раз, когда вы добавляете новый настраиваемый тип. Спорный вопрос, действительно ли это лучше, чем центральная ConvertTo функция.

Почему вы хотите для начала выполнить преобразование типов? Дискриминационные союзы - хороший способ скрыть информацию о типе до тех пор, пока она вам не понадобится, и отвлечься от сложности. Обычно у вас есть оператор соответствия в функции, которая использует этот тип, а затем вы выполняете приведение только в случае необходимости.

Если вы пытаетесь создать какой-либо тип парсера или языкового движка, у вас нет другого выбора, кроме как определить все приведенные типы или, по крайней мере, их состояния ошибок. Если вы не против уточнить, почему и для чего вы бы это использовали, возможно, я мог бы предложить другой подход.

В стороне: F # и .NET в целом не поддерживают перегрузку возвращаемых типов.