Заставить GDB сохранить список точек останова

Начиная с GDB 7.2 (23.08.2011) теперь вы можете использовать сохранить точки останова.

save breakpoints <filename>
  Save all current breakpoint definitions to a file suitable for use
  in a later debugging session.  To read the saved breakpoint
  definitions, use the `source' command.

Используйте source <filename> для восстановления сохраненных точек останова из файла.

Этот ответ устарел. GDB теперь поддерживает сохранение напрямую. См. этот ответ.

Вы можете использовать ведение журнала:

(gdb) b main
Breakpoint 1 at 0x8049329
(gdb) info break
Num     Type           Disp Enb Address    What
1       breakpoint     keep y   0x08049329 <main+16>
(gdb) set logging file breaks.txt
(gdb) set logging on
Copying output to breaks.txt.
(gdb) info break
Num     Type           Disp Enb Address    What
1       breakpoint     keep y   0x08049329 <main+16>
(gdb) q

Теперь файл breaks.txt содержит:

Num     Type           Disp Enb Address    What
1       breakpoint     keep y   0x08049329 <main+16>

Написать сценарий AWK, преобразующий его в формат, полезный для .gdbinit или --command файла, легко. Или вы даже можете заставить скрипт выдавать отдельные --eval-command в командную строку GDB ...

Добавление этого небольшого макроса в .gdbinit поможет вам в этом:

# Call with dump_breaks file.txt
define dump_breaks
    set logging file $arg0
    set logging redirect on
    set logging on
    info breakpoints
    set logging off
    set logging redirect off
end

Поместите свои команды GDB и точки останова в файл .gdbinit, как вы может ввести их в приглашении gdb>, и GDB автоматически загрузит и запустит их при запуске. Это файл для каждого каталога, поэтому у вас могут быть разные файлы для разных проектов.

Расширение анонимного расширения до Ответ Йоханнеса:

.gdbinit:

define bsave
    shell rm -f brestore.txt
    set logging file brestore.txt
    set logging on
    info break
    set logging off
    # Reformat on-the-fly to a valid GDB command file
    shell perl -n -e 'print "break $1\n" if /^\d+.+?(\S+)$/g' brestore.txt > brestore.gdb
end
document bsave
  store actual breakpoints
end

define brestore
  source brestore.gdb
end
document brestore
  restore breakpoints saved by bsave
end

Затем с помощью brestore вы можете восстановить точки останова, сохраненные с помощью bsave.

Расширение ответ Йоханнеса: вы может автоматически переформатировать вывод info break в допустимый командный файл GDB:

.gdbinit:

define bsave
   shell rm -f brestore.txt
   set logging file brestore.txt
   set logging on
   info break
   set logging off
   # Reformat on-the-fly to a valid gdb command file
   shell perl -n -e 'print "break $1\n" if /^\d+.+?(\S+)$/g' brestore.txt > brestore.gdb
end
document bsave
  store actual breakpoints
end

После этого у вас будет действующий командный файл в brestore.gdb.

У меня это сработало, когда приложение скомпилировано с -g.

Я также успешно протестировал его с GDB v6.8 на Ubuntu 9.10 (Кармическая коала).

Возможно это:

save breakpoints [filename]

Поместите следующее в ~ / .gdbinit, чтобы определить bsave и brestore как команды GDB для сохранения и восстановления точек останова.

define bsave
    save breakpoints ~/.breakpoints
end

define brestore
   source ~/.breakpoints
end

предупреждение: текущий протокол вывода не поддерживает перенаправление

Я также получаю эту ошибку / предупреждение в GDB при попытке включить ведение журнала в TUI режим. Однако ведение журнала, похоже, работает в режиме "без TUI". Поэтому я выхожу из режима TUI всякий раз, когда хочу что-то записать. (Переключайтесь назад и вперед в режим TUI с помощью Ctrl + X, Ctrl + A ).

Вот как я работаю:

1. запустить GDB (в нормальном режиме)
2. включить логирование: set logging on - теперь жаловаться не должно.
3. переключаться назад / вперед в режим TUI и делать вещи GDB
4. всякий раз, когда я хочу что-то записать (например, огромный дамп обратной трассировки) - переключитесь в нормальный режим

Я нашел следующее дополнение к предыдущему ответу полезным для сохранения / загрузки точек останова в конкретный файл.

• Сохраните точки останова: bsave {filename}
• Загрузить точки останова: bload {filename}

Как и в предыдущем ответе, добавьте следующий код в файл ~ / .gdbinit

# Save breakpoints to a file
define bsave
    if $argc != 1
        help bsave
    else
    save breakpoints $arg0
    end
end
document bsave
Saves all current defined breakpoints to the defined file in the PWD
Usage: bsave <filename>
end

# Loads breakpoints from a file
define bload
    if $argc != 1
        help bload
    else
        source $arg0
    end
end
document bload
Loads all breakpoints from the defined file in the PWD
Usage: bload <filename>
end

Проблема в том, что установка точки останова зависит от контекста. Что делать, если у вас есть две статические функции с именем foo?

Если вы уже отлаживаете один из модулей, определяющих foo, то GDB предположит, что вы имели в виду именно этот. Но если вы просто скопируете "break foo" в файл, а затем прочитаете этот файл при запуске, не будет ясно, какую функцию foo вы имеете в виду.

Есть другие идеи? у меня есть

warning: Current output protocol does not support redirection

после

set logging on

РЕДАКТИРОВАТЬ:

Я знаю, что вопрос в том, «как сохранить список точек останова», однако я только что обнаружил, что с помощью GDB мы можем просто установить точки останова «сохраненные в файле» с помощью

gdb> source breakpoints.txt

где breakpoints.txt - это такой файл:

break main.cpp:25
break engine.cpp:465
break wheel.cpp:57