Динамическое добавление свойства или метода к объекту в groovy

Можно ли динамически добавить свойство или метод к объекту в Groovy? Это то, что я пробовал до сих пор:

class Greet {
  def name
  Greet(who) { name = who[0].toUpperCase() + [1..-1] }
  def salute() { println "Hello $name!" }
}

g = new Greet('world')  // create object
g.salute()              // Output "Hello World!"

g.bye = { println "Goodbye, $name" }
g.bye()

Но я получаю следующее исключение:

Hello World!
Caught: groovy.lang.MissingPropertyException: No such property: bye for class: Greet
Possible solutions: name
    at test.run(greet.groovy:11)

groovy monkeypatching
person Alex Spurling    schedule 24.01.2011    source источник

Ответы (1)


arrow_upward
64
arrow_downward

Если вы просто хотите добавить метод bye() к одному экземпляру g класса Greet, вам нужно сделать:

g.metaClass.bye = { println "Goodbye, $name" }
g.bye()

В противном случае, чтобы добавить bye() ко всем экземплярам Greet (с этого момента), вызовите

Greet.metaClass.bye = { println "Goodbye, $name" }

Но вам нужно сделать это до того, как вы создадите экземпляр класса Greet.

Вот страница метакласса для каждого экземпляра

А вот и страница о метаклассах в целом

Кроме того, в вашем конструкторе есть ошибка. Вам не хватает who перед вашим [1..-1], и если конструктору передается String длиной менее 2 символов, он вызовет исключение

Лучшей версией может быть:

Greet( String who ) { 
  name = who.inject( '' ) { String s, String c ->
    s += s ? c.toLowerCase() : c.toUpperCase()
  }
}

Как упоминалось в комментариях,

Greet( String who ) { 
  name = who.capitalize()
}

это правильный путь

person tim_yates    schedule 24.01.2011
comment
Я бы предложил использовать name = who.capitalize() в конструкторе. - person ataylor; 24.01.2011
comment
@ataylor Я знал, что есть лучший способ, чем этот inject! Ваше здоровье :-) - person tim_yates; 24.01.2011
comment
@tim_yates, если внедрять функцию класса, такую ​​как Greet.metaClass.bye = { ... }, следует ли это делать в BootStrap.groovy для приложения Grails? - person raffian; 27.01.2014
comment
Чтобы добавить свойство к экземпляру, мы можем добавить геттер в метакласс, то есть: g.metaClass.getPlanet() = { return 'World' } Затем мы можем использовать g.planet - person Meam; 17.10.2017
comment
Ссылки на помощь мертвы - person Lee Meador; 29.11.2018