Сбросить поток случайных чисел

Вы не можете сбросить потоки для функции RAND в SAS 9.4M4. Однако вы можете перематывать поток в SAS 9.4M5 (отправлено в сентябре 2017 г.), используя новый подпрограмма STREAMREWIND. Следующая программа демонстрирует синтаксис:

data want;
  call streaminit(123);  
  do i = 1 to 2;
    call streamrewind;
    ran1 = rand('uniform');      
    ran2 = rand('uniform');      
    ran3 = rand('uniform');      
    put _all_;
    output;
  end;
run;

Однако вы можете обойти это, используя сгенерированный код, с помощью CALL EXECUTE или, возможно, DOSUBL, например:

data _null_;
  do i = 1 to 2;
    rc=dosubl(cats("data want_",i,";
    call streaminit(123);  * <-- WANT THIS TO RESET THE STREAM;
    ran1 = rand('uniform');      
    ran2 = rand('uniform');      
    ran3 = rand('uniform');    
    i=",i,"; 
    put _all_;
    output;
    run;
    "));
  end;
  rc = dosubl("data want; set want_1 want_2; run;");
run;

Очевидно, проще/лучше написать макрос для выполнения этой части.

К сожалению, это ограничение «новой» процедуры RAND; со старым было намного легче работать в этом отношении (поскольку на самом деле у него было только одно семя). Начальные свойства нового более сложны, поэтому, хотя вы можете инициализировать его одним числом, это не так просто, отсюда и сложности.

Вы можете использовать call ranuni, чтобы использовать одно и то же начальное число для двух разных потоков случайных чисел.

Обратите внимание, что здесь используется другой, более низкий PRNG с гораздо более коротким циклом и худшими статистическими свойствами, чем функция rand().

Пример:

data x;
  seed1 = 123;
  seed2 = 123;
  do i =1 to 3;
    call ranuni(seed1, x); 
    call ranuni(seed2, y); 
    output;
  end;
run;

Выход:

i=1 x=0.7503960881 y=0.7503960881
i=2 x=0.3209120251 y=0.3209120251
i=3 x=0.178389649 y=0.178389649