Регион Растет в DM

Возможно, это не то, что вы ищете, но ваша «цель» мне все еще не ясна на 100%. Из вашего вопроса до сих пор кажется, что вам только нужно двоичное изображение вашей маски, которое вы бы просто получили, сохранив все изображения с нулевым значением как ноль и установив для всех остальных значение 1. Можно сделать с трет или просто двойное "не":

image src := GetFrontImage()

image binMask = !!src
binMask.SetName( "Binary" )
binMask.ShowImage()

Однако я предполагаю, что ваша реальная цель состоит в том, чтобы получить эти бинарные маски для каждой отдельной частицы по отдельности, то есть получить 10 бинарных масок, показывающих только одну частицу, когда у вас есть 10 разных (пространственно разделенных) частиц. Это несколько другая задача.

В своем сообщении вы, кажется, говорите, что «Анализ частиц», вероятно, уже делает то, что вы хотите, поэтому одним из решений вашей проблемы может быть фактическое использование анализа частиц прямо сейчас!

К сожалению, эта часть программного обеспечения в настоящее время недоступна должным образом через скриптовый API. Тем не менее, обладая небольшим количеством нестандартного мышления и некоторыми навыками взлома, можно получить доступ к необходимой функциональности с помощью связанной с пользовательским интерфейсом команды ChooseMenuItem().

Ниже я публикую небольшой пример, который я только что собрал. Сначала он обрабатывает бинарное входное изображение, затем применяет анализ частиц по умолчанию, затем получает изображение результатов и использует содержащуюся информацию для вырезания частиц.

Извините за неаккуратное кодирование, но вы можете модифицировать этот скрипт под свои нужды.

number GetMeasurementsColumnIndex( image input, string colLabel )
{
    // Basic checks... return <0 if fail.
    if ( !input.ImageIsValid() ) return -1
    if ( input.GetName() != "Measurements" ) return -2
    if ( 0 == input.ImageCountImageDisplays() ) return -3

    imageDisplay disp = input.ImageGetImageDisplay( 0 ) 
    number sx = input.ImageGetDimensionSize( 0 )
    for( number c = 0; c<sx; c++ )
        if ( colLabel == disp.SpreadsheetImageDisplayGetColumnLabel(c) ) 
            return c

    return -4 // not found
}


// Main Script (Test)
number bOnNewWorkSpace = 1

// Pre-#1: Ensure relevant information is computed by particle Anlaysis
// The info is stored in the tags, but it seems it is only read from there
// on start-up... (needs checking)
GetPersistentTagGroup().TagGroupSetTagAsBoolean( "Private:Particles:Configuration:Length", 0 ) 
GetPersistentTagGroup().TagGroupSetTagAsBoolean( "Private:Particles:Configuration:Width", 1 ) 
GetPersistentTagGroup().TagGroupSetTagAsBoolean( "Private:Particles:Configuration:CenterX", 1 ) 
GetPersistentTagGroup().TagGroupSetTagAsBoolean( "Private:Particles:Configuration:CenterY", 1 ) 

// #1 Act on binary image mask based on front-image (temp)
image source := GetFrontImage()
image binSrc = !!source


// #2 Potentially work on "clean" workspace
if ( bOnNewWorkSpace )
{
    number wsID_src = WorkSpaceGetActive()
    number wsID_results = WorkSpaceAdd( WorkSpaceGetIndex(wsID_src) + 1 )
    WorkSpaceSetActive( wsID_results )
}

// #3 Treshold the mask by script. (Requires display)
binSrc.ShowImage()
imageDisplay disp = binSrc.ImageGetImageDisplay( 0 )
disp.RasterImageDisplaySetThresholdOn( 1 ) 
disp.RasterImageDisplaySetThresholdLimits( 0.1, 1 ) 

// #4 Perform Particle analysis, grab results, close temp. source
ChooseMenuItem( "Analysis", "Particles", "Analyze Particles" )
binSrc.DeleteImage()
image particleList := GetFrontImage()

// #5 Perfrom checks on results before proceeding. 
// (Particle Analysis may be configured by script by modifying persistent tags. See pre-step #1)
number pxIndex = GetMeasurementsColumnIndex( particleList, "CenterX" )
number pyIndex = GetMeasurementsColumnIndex( particleList, "CenterY" )
number pRIndex = GetMeasurementsColumnIndex( particleList, "MaxRadii" ) 

if ( pxIndex < 0 ) Throw( "Need to setup Analysis to create 'CenterX' output." )
if ( pyIndex < 0 ) Throw( "Need to setup Analysis to create 'CenterY' output." )
if ( pRIndex < 0 ) Throw( "Need to setup Analysis to create 'MaxRadii' output." )

// #6 Use results. Example Create Individual crops from source
//  ( This may still include intruding pixels from neighboring particles )
number nParticles = particleList.ImageGetDimensionSize( 1 )
nParticles = 5 // for testing...
for( number p = 0; p<nParticles; p++ )
{
    number px = particleList.GetPixel( pxIndex, p )
    number py = particleList.GetPixel( pyIndex, p )
    number pR = particleList.GetPixel( pRIndex, p )
    number y0 = py - pr
    number x0 = px - pr

    image crop := source.Slice2( x0,y0,0, 0,pR*2,1, 1,pR*2,1).ImageClone()
    crop.ShowImage()    
}

Возможно, вы захотите получить координаты пикселей для каждой частицы. Чтобы сохранить его, вы создаете taglist taglists. Начните с кратких кодов BeMyGuest, вы можете сделать это:

image source := GetFrontImage()
image binSrc = !!source
taggroup tgPartcleList=newTagList()
taggroup tgParticleIndividual=newTagList()
number val, x, y
while (1) {
   val=binSrc.max(x, y)
   if (val==0) break
   else {
      tgParticleIndividual=dfs(binSrc, x, y)
   }
   tgPartcleList.taggroupInsertTagAsTagGroup(infinity(), tgParticleIndividual)
   turnOffpixels(binSrc, tgParticleIndividual)
}

функция dfs - это "поиск в глубину". По сути, это один из видов «поиска связанных компонентов». Алгоритмов для этого много. Я использовал «сначала в глубину», который можно закодировать со структурой стека, смоделированной с помощью группы тегов. после каждого dfs вы вызываете функцию «turnOffpixels», чтобы затемнить эту частицу и вернуться к циклу.