Использование атомов из объявленных структур в elixir работает на repl, но не в приложении

Это происходит потому, что Elixir по умолчанию лениво загружает модули из скомпилированных файлов .beam при их первом использовании. (Ваш код будет работать, если start_permanent установлено в true в mix.exs, для которого по умолчанию установлено значение true в среде :prod, потому что тогда Elixir жадно загружает все модули пакета.)

В приведенном ниже коде атом :my_crazy_atom будет присутствовать в коде модуля Blah, но его нет в Foo. Если вы запустите сеанс REPL и запустите Foo.to_existing_atom, модуль Blah не будет загружен, что приведет к сбою String.to_existing_atom("my_crazy_atom").

# Credits: @mudasobwa
defmodule Blah do
  defstruct my_crazy_atom: nil
end

defmodule Foo do
  def to_existing_atom, do: String.to_existing_atom("my_crazy_atom")
end

Как вы заметили, если вы однажды создадите структуру вручную, все последующие вызовы String.to_existing_atom("my_crazy_atom") вернут правильный атом. Это связано с тем, что когда вы создаете структуру, Elixir загрузит файл .beam этого модуля, который также загрузит все атомы, используемые этим модулем.

Лучший способ загрузить модуль (по сравнению с созданием структуры) — использовать Code.ensure_loaded/1 для загрузки модуля:

{:module, _} = Code.ensure_loaded(Blah)

Разница между REPL и вашим приложением заключается в том, что в REPL процесс компиляции происходит немедленно. Тем не менее, ВМ, как она видит

iex(1)> defmodule MyModule do
...(1)>   defstruct my_crazy_atom: nil
...(1)> end

он сразу скомпилирован. На этапе компиляции создается атом и все работает.

В вашем приложении OTOH процесс компиляции выполняется заранее путем другого вызова виртуальной машины. Следовательно, если структура не используется явно, атом не будет создан.

Можно подумать об этом как об объявлении класса по сравнению с созданием экземпляра в ООП: существование определения класса не гарантирует наличие экземпляров этого класса.

Чтобы увидеть, что и когда на самом деле происходит, попробуйте поместить IO.puts "I AM HERE" в объявление модуля непосредственно перед defstruct. В REPL вы сразу же увидите эту строку. В вашем приложении вы увидите его во время компиляции и не увидите при обычном запуске приложения.

Действия по воспроизведению:

$ mix new blah && cd blah
$ cat lib/blah.ex
defmodule Blah do
  defstruct my_crazy_atom: nil
end

defmodule Foo do
  def to_existing_atom, do: String.to_existing_atom("my_crazy_atom")
end
$ mix compile
$ iex -S mix
iex|1 ▶ Foo.to_existing_atom
** (ArgumentError) argument error
    :erlang.binary_to_existing_atom("my_crazy_atom", :utf8)
    (blah) lib/blah.ex:6: Foo.to_existing_atom/0
iex|1 ▶ %Blah{}
%Blah{my_crazy_atom: nil}
iex|2 ▶ Foo.to_existing_atom
:my_crazy_atom

Я помещу его здесь для полноты (взято из этот блестящий ответ):

defmodule AtomLookUp do
  defp atom_by_number(n),
    do: :erlang.binary_to_term(<<131, 75, n::24>>)

  def atoms(n \\ 0) do
    try do
      [atom_by_number(n) | atoms(n + 1)]
    rescue
      _ -> []
    end
  end
  def atom?(value) when is_binary(value) do
    result = atoms()
             |> Enum.map(&Atom.to_string/1)
             |> Enum.find(& &1 == value)
    if result, do: String.to_existing_atom(result)
  end
end

iex|1 ▶ AtomLookUp.atom? "my_crazy_atom"
nil
iex|2 ▶ %Blah{}
%Blah{my_crazy_atom: nil}
iex|3 ▶ AtomLookUp.atom? "my_crazy_atom"
:my_crazy_atom