Как я могу сохранить массивы с плавающей запятой в многомерном массиве в IDL?

Вы проделали большую работу, ответив на свой очень красиво сформулированный вопрос. :-) Могу добавить еще несколько вариантов.

В случае, когда ваши подмассивы имеют одинаковый размер (128x128), общий подход в IDL заключается в использовании массива большей размерности для содержания нескольких из них. В этом случае, когда вам нужен массив (5x3) подмассивов, вы можете создать:

multidim_array = FltArr(128, 128, 5, 3)

Чтобы получить доступ к одному подмассиву 128x128, используйте, например:

current_float_array = multidim_array[*, *, 0, 0]
help, current_float_array
CURRENT_FLOAT_ARRAY               FLOAT     = Array[128, 128]

Обратите внимание, что IDL отбрасывает конечные измерения, если они имеют длину 1, поэтому мы получаем Array[128, 128], а не Array[128, 128, 1, 1].

Одно замечание для эффективности: когда вы загружаете данные в этот массив, а не адресуете подмассив 128x128, если вы указываете только начальный элемент, IDL выполнит назначение гораздо быстрее. Итак, используйте:

multidim_array[0, 0, 0, 0] = float_array

скорее, чем:

multidim_array[*, *, 0, 0] = float_array

(Общее правило заключается в том, что за кулисами IDL берет любые элементы «*» и расширяет их до набора индексов, которые используются для перемещения каждого элемента данных один за другим. Если вы просто задаете начальный элемент, весь массив может копировать как блок.)

Обратите внимание, что это именно то, что вы непреднамеренно сделали в своем первом тесте выше (multiple_array[0, 0] = float_array), что было не тем, что вы хотели в то время.

Подход multidim_array и ваш подход PtrArr будут иметь свои плюсы и минусы, когда массивы очень большие, где размер памяти и время обработки могут иметь компромиссы, но в небольших приложениях разумен любой подход.

Еще один способ сделать это (по крайней мере, начиная с IDL 8.1) — использовать тип данных LIST, который позволил бы подмассивам иметь разные размеры. На самом деле элемент списка может быть чем угодно (например, ваши подмассивы), и вы можете получить доступ к этим записям (и даже индексировать подмассивы) с помощью простого синтаксиса индексации массива. Вот пример того, что вы можете сделать, создав a как список списков:

IDL> a=list(list(indgen(2,3),indgen(3,4)), list(indgen(2,4)))
IDL> a
[
    [
        [[0, 1], [2, 3], [4, 5]],
        [[0, 1, 2], [3, 4, 5], [6, 7, 8], [9, 10, 11]]
    ],
    [
        [[0, 1], [2, 3], [4, 5], [6, 7]]
    ]
]
IDL> a[0]
[
    [[0, 1], [2, 3], [4, 5]],
    [[0, 1, 2], [3, 4, 5], [6, 7, 8], [9, 10, 11]]
]
IDL> a[0,1]
       0       1       2
       3       4       5
       6       7       8
       9      10      11

Вы загрузите свои данные в список списков, подобных этому, в цикле (извините, не проверено, но считается правильным):

multiple_list = List()
FOR rowI = 0, 3 DO BEGIN
   row_list = List
   FOR columnI = 0, 5 DO $
      row_list.Add, GetYourFloatArrayHerePossiblyUsing(columnI, rowI)
   multiple_list.Add, row_list
ENDFOR ; rowI over all rows

и вы можете получить доступ к первому массиву как:

multiple_list[0, 0]

а также:

multiple_list[0, 0, 0, 0]     ; first element of first array
multiple_list[2, 4, 127, 127] ; last element of last array

Я надеюсь, что это полезно!

Я просто нашел ответ как-то сам. На самом деле это очень легко. Я также надеюсь, что это поможет другим людям.

Вот что вам нужно сделать:

Вместо установки /FLOAT просто установите /PTR в функции MAKE_ARRAY:

multiple_array = MAKE_ARRAY(5, 3, /PTR)
> multiple_array
<NullPointer><NullPointer><NullPointer><NullPointer><NullPointer>
<NullPointer><NullPointer><NullPointer><NullPointer><NullPointer>
<NullPointer><NullPointer><NullPointer><NullPointer><NullPointer>

Определите свой float_array как всегда:

float_array = FLTARR(3, 3)
;skipped setting some simple values

> float_array
   1.0000000       2.0000000       3.0000000
   4.0000000       5.0000000       6.0000000
   7.0000000       8.0000000       9.0000000

Самая важная часть:

Определите свой массив с плавающей запятой как PTR_NEW, чтобы вы могли сохранить свой массив с плавающей запятой в первом индексе.

multiple_array[0,0] = PTR_NEW(float_array)
> multiple_array
<PtrHeapVar1><NullPointer><NullPointer><NullPointer><NullPointer>
<NullPointer><NullPointer><NullPointer><NullPointer><NullPointer>
<NullPointer><NullPointer><NullPointer><NullPointer><NullPointer>

> multiple_array[0,0]
<PtrHeapVar1>

Поместив * перед вашим массивом, вы распечатаете содержимое вашего массива с плавающей запятой.

> *multiple_array[0,0]
   1.0000000       2.0000000       3.0000000
   4.0000000       5.0000000       6.0000000
   7.0000000       8.0000000       9.0000000