XSLT группировка и суммирование

Я новичок в XSLT, и мне нужно суммировать общую цену (Количество * Цена за единицу) товаров на основе идентификатора каждого заказа и печатать ее в конце каждой группы товаров, используя XSLT 1.0. Вот мой пример XML

<Orders>
<Order>
    <Reference>234</Reference>
    <Item>
        <ID>10</ID>
        <Quantity>1</Quantity>
        <UnitPrice>2</UnitPrice>
    </Item>
    <Item>
        <ID>10</ID>
        <Quantity>2</Quantity>
        <UnitPrice>3</UnitPrice>
    </Item>
    <Item>
        <ID>10</ID>
        <Quantity>2</Quantity>
        <UnitPrice>2</UnitPrice>
    </Item>
    <Item>
        <ID>20</ID>
        <Quantity>2</Quantity>
        <UnitPrice>4</UnitPrice>
    </Item>
</Order>
<Order>
    <Reference>456</Reference>
    <Item>
        <ID>10</ID>
        <Quantity>2</Quantity>
        <UnitPrice>2</UnitPrice>
    </Item>
    <Item>
        <ID>20</ID>
        <Quantity>2</Quantity>
        <UnitPrice>2</UnitPrice>
    </Item>
</Order>
</Orders>

Желаемый выходной XML приведен ниже

<SAPOrders>
<Order>
    <Reference>234</Reference>
    <Item>
        <Quantity>1</Quantity>
        <UnitPrice>2</UnitPrice>
    </Item>
    <Item>
        <Quantity>2</Quantity>
        <UnitPrice>3</UnitPrice>
    </Item>
    <Item>
        <Quantity>2</Quantity>
        <UnitPrice>2</UnitPrice>
        <Total>12</Notes>
    </Item>
    <Item>
        <Quantity>2</Quantity>
        <UnitPrice>4</UnitPrice>
        <Total>8</Notes>
    </Item>
</Order>
<Order>
    <Reference>456</Reference>
    <Item>
        <Quantity>2</Quantity>
        <UnitPrice>2</UnitPrice>
        <Total>4</Notes>
    </Item>
    <Item>
        <Quantity>2</Quantity>
        <UnitPrice>2</UnitPrice>
        <Total>4</Total>
    </Item>
</Order>
</SAPOrders>

xml xslt xslt-grouping
person tojira    schedule 09.01.2017    source источник
comment
См. stackoverflow.com/questions/37205574/ который является почти дубликатом   -  person Michael Kay    schedule 09.01.2017
comment
@MichaelKay Вы указываете на решение XSLT 2.0.   -  person michael.hor257k    schedule 09.01.2017
comment
@tojira Почему в выводе нет идентификаторов предметов?   -  person michael.hor257k    schedule 09.01.2017
comment
@ michael.hor257k есть логика для вывода xml, а не просто копирование.   -  person tojira    schedule 10.01.2017
comment
Я не могу сказать, что понимаю ваш ответ, но если вы так хотите...   -  person michael.hor257k    schedule 10.01.2017

Ответы (1)


arrow_upward
0
arrow_downward

Здесь есть две проблемы: (1) сгруппировать элементы по порядку и по идентификатору элемента и (2) вычислить промежуточный итог для каждой такой группы.

Первая проблема относительно проста и может быть решена с помощью метода группировки по Мюнху. Вторая проблема сложнее, так как XSLT 1.0 не позволяет суммировать результат вычисления.

Следующая таблица стилей начинается с предварительного расчета расширенной цены каждого элемента и сохранения результатов в переменной. Затем он работает с переменной, группируя элементы и подсчитывая промежуточные итоги по каждой группе.

XSLT 1.0

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:key name="item" match="Item" use="@key" />

<xsl:template match="/Orders">
    <!-- first pass -->
    <xsl:variable name="first-pass">
        <xsl:for-each select="Order">
            <Order>
                <xsl:copy-of select="Reference"/>
                <xsl:for-each select="Item">
                    <Item key="{concat(../Reference, '|', ID)}" extPrice="{Quantity * UnitPrice}">
                        <xsl:copy-of select="*"/>
                    </Item>
                </xsl:for-each>
            </Order>
        </xsl:for-each>
    </xsl:variable>
    <!-- output -->
    <SAPOrders>
        <xsl:for-each select="exsl:node-set($first-pass)/Order">
            <xsl:copy>
                <xsl:copy-of select="Reference"/>
                <!-- for each unique item in this order -->
                <xsl:for-each select="Item[count(. | key('item', @key)[1]) = 1]">
                    <!-- list the items in this group -->
                    <xsl:for-each select="key('item', @key)">
                        <Item>
                            <xsl:copy-of select="Quantity | UnitPrice"/>
                            <!-- add the subtotal of this group -->
                            <xsl:if test="position()=last()">
                                <Total>
                                    <xsl:value-of select="sum(key('item', @key)/@extPrice)" />
                                </Total>
                            </xsl:if>
                        </Item>
                    </xsl:for-each>
                </xsl:for-each>
            </xsl:copy>
        </xsl:for-each> 
    </SAPOrders>
</xsl:template>

</xsl:stylesheet>

Демонстрация: http://xsltransform.net/jz1PuPz

person michael.hor257k    schedule 10.01.2017