Есть ли способ сделать ассоциативные массивы в REXX?

Вы можете использовать базовые переменные, не совсем такие, как массивы, но очень похожие

/* REXX */
NAME = PAX
ARRAY.NAME = "DIABLO"
NAME = BOB
ARRAY.NAME = "DYLAN"
NAME = 'PAX'
SAY "ARRAY.PAX " IS ARRAY.NAME
NAME = 'BOB'
SAY "ARRAY.BOB " IS ARRAY.NAME
NAME = 'SANDY'
SAY "ARRAY.SANDY " IS ARRAY.NAME
IF ARRAY.NAME = "ARRAY.SANDY" THEN SAY "ARRAY.SANDY IS EMPTY"

Вышеупомянутый Rexx будет печатать

ARRAY.PAX  IS DIABLO
ARRAY.BOB  IS DYLAN
ARRAY.SANDY  IS ARRAY.SANDY
ARRAY.SANDY IS EMPTY

Они также могут быть составными, например, a.b.c. Переменная основы, если она пуста, вернет себя. Невозможно выполнить итерацию стебля, который не использует последовательные числа в качестве индекса, о котором я знаю.

Руководство IBM со ссылкой на базовые переменные

Perl доступен как дополнительная бесплатная функция для ZOS IBM Ported Инструменты для z/OS

Я просто хочу добавить немного больше к ответу, данному Deuian. Я согласен, базовые переменные REXX - это ответ.

Простые переменные REXX по умолчанию имеют собственное имя. Например:

/* REXX */
SAY X

будет печатать «X», пока X не будет присвоено другое значение:

/* REXX */
X = 'A'
SAY X

напечатает «А».

Пока нет большого сюрприза. Стеблевые переменные немного отличаются. Головка стебля никогда не оценивается, оценивается только бит после начальной точки.

Проиллюстрировать:

/* REXX */                                                           
X. = 'empty'   /* all unassigned stem values take on this value */
A. = 'nil'
B = 'A'        /* simple variable B is assigned value A */                                                      
X = 'A'        /* simple variable X is assigned value A */                                                      
SAY X.A        /* prints: empty */                                 
X.A = 'hello'  /* Stem X. associates value of A with 'hello' */
SAY X.A        /* prints: hello */                                   
SAY X.B        /* prints: hello */                                   
SAY X.X        /* prints: hello */                                   

Обратите внимание, что имена стволов X и A не оцениваются, однако переменные X и A, стоящие после них, вычисляются. Некоторые люди находят это немного запутанным — подумайте об этом некоторое время, и это обретет смысл.

Версия REXX для Z/OS не предоставляет естественного способа перебора основной переменной. Самый простой способ сделать это — создать свой собственный индекс. Например:

/* REXX */
X. = ''
DO I = 1 TO 10
  J = RANDOM(100, 500) /* Random # 100..500 */
  X.INDEX = X.INDEX J  /* concatinate J's with 1 space between */
  X.J = 'was picked'   /* Associate 'was picked' with whatever J evalauates to */
  END

DO I = 1 TO WORDS(X.INDEX) /* Number of blank delimited 'words' */
  J = WORD(X.INDEX, I)     /* Extract 1 'word' at a time */
  SAY J X.J                /* Print 'word' and its associated value */
  END

Довольно тривиально, но иллюстрирует идею. Просто убедитесь, что INDEX (или любое другое имя, которое вы выберете) для хранения имен индексации никогда не всплывает как ассоциативное значение! Если это возможно, используйте другую переменную для хранения индекса.

Последняя точка. Обратите внимание, что каждый из моих примеров начинается с /* REXX */, возможно, вы обнаружите, что это должна быть первая строка ваших REXX-программ под Z/OS.