XSL - встроенная таблица поиска - значение поиска переменной

- изменено в ответ на изменения в вопросе -

Рассмотрим 4 варианта, представленные в вашей таблице стилей:

1. Это работает как ожидалось:

   <xsl:value-of select='document("")//lookup:table/row[@raw = $value_to_lookup]/@corrected'/>
   

2. Это не может работать, потому что raw является атрибутом row, а row отсутствует в пути:

   <xsl:value-of select='document("")//lookup:table[@raw = $value_to_lookup]/@corrected'/>
   

3. Это работает как ожидалось:

   <xsl:value-of select='$lookup_table[@raw = $value_to_lookup]/@corrected'/>
   

4. Это не работает, потому что в XSLT 1.0 ключи работают только в контексте текущего документа:

   <xsl:value-of select="key('lookup_table',$value_to_lookup)/@corrected"/>
   

   Чтобы заставить его работать, вы должны сделать:

   <xsl:for-each select="document('')">
       <xsl:value-of select="key('lookup_table',$value_to_lookup)/@corrected"/>
   </xsl:for-each>
   

- добавлено в ответ на следующие пояснения в комментариях -

Таблица стилей XSL является частью приложения. Когда я хочу создать новый итоговый документ или внести изменения в существующий, я просматриваю меню приложения на основе Java. В конце концов я попал на экран с небольшим меню сбоку и большим окном для ввода текста посередине. В этом окне ввода текста набирается кодировка XSL.

что вы получите в результате <xsl:value-of select="count(document(''))"/>?

Результат - «0».

Очевидно, ваша среда обработки не поддерживает использование функции document() для ссылки на саму таблицу стилей. Это означает, что вам нужно будет использовать другой метод для выполнения внутреннего поиска, а именно определить переменную и преобразовать ее в набор узлов, как уже было предложено в ответе MiMo.

Обратите внимание, что это не имеет ничего общего с Java. Практически все процессоры XSLT 1.0 поддерживают функцию расширения EXSLT node-set(), но некоторые процессоры Microsoft распознают ее только в своем собственном пространстве имен.

Для завершения вот как вы могли бы использовать ключ для поиска значения в переменной:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:param name="value_to_lookup" select="'raw1'"/>

<xsl:key name="lookup" match="row" use="@raw"/>

<xsl:variable name="lookup">
    <row raw="raw1" corrected="Raw One"/>
    <row raw="raw2" corrected="Raw Two"/>
    <row raw="raw3" corrected="Raw Three"/>
    <row raw="raw4" corrected="Raw Four"/>
    <row raw="raw5" corrected="Raw Five"/>
</xsl:variable>
<xsl:variable name="lookup-set" select="exsl:node-set($lookup)" />

<xsl:template match="/">
    <!-- change context to the lookup "document" -->
    <xsl:for-each select="$lookup-set">
        <xsl:value-of select="key('lookup', $value_to_lookup)/@corrected"/>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

Проблема в том, что <xsl:variable name="value_to_lookup" select='raw1'/> устанавливает value_to_lookup в значение (несуществующего) элемента raw1 - поэтому он пуст.

Вам нужно <xsl:variable name="value_to_lookup" select="'raw1'"/>, а затем <xsl:value-of select='document("")//lookup:table/row[@raw = $value_to_lookup]/@corrected'/> работает. Полный XSLT:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
            xmlns:lookup="lookup" exclude-result-prefixes="lookup">

<lookup:table>
    <row raw="raw1" corrected="Raw One"/>
    <row raw="raw2" corrected="Raw Two"/>
    <row raw="raw3" corrected="Raw Three"/>
    <row raw="raw4" corrected="Raw Four"/>
    <row raw="raw5" corrected="Raw Five"/>
</lookup:table>

<xsl:template match="/">
    <xsl:variable name="value_to_lookup" select="'raw1'"/>
    <xsl:value-of select='document("")//lookup:table/row[@raw = $value_to_lookup]/@corrected'/>
</xsl:template>

You can define the lookup table without using document() doing something like this:

<xsl:variable name="lookup_table_fragment">
    <row raw="raw1" corrected="Raw One"/>
    <row raw="raw2" corrected="Raw Two"/>
    <row raw="raw3" corrected="Raw Three"/>
    <row raw="raw4" corrected="Raw Four"/>
    <row raw="raw5" corrected="Raw Five"/>
</xsl:variable>
<xsl:variable name="lookup_table" select="msxsl:node-set($lookup_table_fragment)" />

а потом:

<xsl:value-of select='$lookup_table/row[@raw = $value_to_lookup]/@corrected'/>

(msxsl:node-set специфично для Microsoft, но у всех процессоров есть функция для преобразования фрагмента в набор узлов)

Эта последняя версия, адаптированная для процессора Java XSLT, гласит:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
        xmlns:lookup="lookup" xmlns:exsl="http://exslt.org/common" exclude-result-prefixes="lookup exsl">

    <xsl:variable name="lookup_table_fragment">
        <row raw="raw1" corrected="Raw One"/>
        <row raw="raw2" corrected="Raw Two"/>
        <row raw="raw3" corrected="Raw Three"/>
        <row raw="raw4" corrected="Raw Four"/>
        <row raw="raw5" corrected="Raw Five"/>
    </xsl:variable>
    <xsl:variable name="lookup_table" select="exsl:node-set($lookup_table_fragment)" />

    <xsl:template match="/">
        <xsl:variable name="value_to_lookup" select="'raw1'"/>
        <xsl:value-of select='$lookup_table/row[@raw = $value_to_lookup]/@corrected'/>
   </xsl:template>

</xsl:stylesheet>

и его можно протестировать на странице http://www.utilities-online.info/xsltransformation