Как передать несколько строк Fortran в C?

Чтобы передать строку Fortran в C, также передается скрытый параметр с размером переменной. Вот рабочее определение fortran и метод C (фактически C++/CLI):

  interface
     subroutine AppendExtension(
 +      Filename)
 +      bind(C, name="AppendExtension")
     character *1, intent(inout):: Filename
    end subroutine AppendExtension
  end interface

и вот вызываемый C++/CLI:

extern "C" {
  void __declspec(dllexport) __cdecl AppendExtension(
                                         char * name, 
                                         int buffersize)
{
  String^ clistr = gcnew String(name);
  clistr = System::IO::Path::ChangeExtension(clistr->Trim(), gcnew String("OUT"));
  IntPtr p = Marshal::StringToHGlobalAnsi(clistr);
  char *pNewCharStr = static_cast<char*>(p.ToPointer());
  int cstrlen = strlen(pNewCharStr);
  memcpy_s(name, buffersize, pNewCharStr, cstrlen);
  if (cstrlen < buffersize)
  {
    // backfill with spaces, since a Fortran string is spaces on the right.
    memset(&name[cstrlen], ' ', buffersize-cstrlen);
  }
  Marshal::FreeHGlobal(p);
}

Вышеупомянутое работает правильно (Intel Visual Fortran 2013 SP1).

Теперь я хочу передать две строки в функцию. Вот что я сделал:

   interface
     subroutine ParseSpec(
 +      Filename, Corename)
 +      bind(C, name="ParseSpec")
     character *1, intent(inout):: Filename
     character *1, intent(inout):: Corename
    end subroutine ParseSpec
   end interface

Вот призыв в действии:

      CHARACTER*80 FILE_SPEC
      CHARACTER*200 CORE_NAME
      CALL ParseSpec(FILE_SPEC, CORE_NAME)

и вот С++/CLI:

void __declspec(dllexport) __cdecl ParseSpec(char * name, char * corename, int namelen, int corelen)
{
  // namelen and corelen both contain the length of "name".
  ...

Есть две скрытые переменные. Я думаю, что они должны быть для размеров буфера для каждой из моих двух строк, одна для «Имя файла» и одна для «Имя ядра». Но оба содержат размер буфера первого буфера, а именно 80.

Где я ошибаюсь?


c c++-cli fortran intel-fortran fortran-iso-c-binding
person erict    schedule 16.01.2016    source источник

Ответы (1)


arrow_upward
4
arrow_downward

Соглашение о вызовах для процедур BIND(C) может сильно отличаться от соглашения о вызовах по умолчанию, которое компилятор Фортрана использует для вызовов Фортран-Фортран. Вы не должны полагаться на какие-либо скрытые аргументы длины CHARACTER (в общем случае вы также не должны ожидать, что скрытые аргументы имеют тип int). Я подозреваю, что вам просто повезло, учитывая то, как компилятор размещает в памяти переменную Fortran CHARACTER.

Компилятору не нужно передавать длину для процедуры BIND(C), потому что единственная длина переменной CHARACTER, совместимой с C, равна единице. Однако, если фиктивный аргумент представляет собой массив (это то, что вам нужно, если вы передаете строку, а не отдельный символ), SIZE этого массива может быть неотрицательным - правила ассоциации последовательности Fortran для KIND = C_CHAR символ означает, что вы можете связать скаляр с массивом.

Все вверх — измените объявление функции Fortran так, чтобы символьные аргументы были массивами, и добавьте аргументы для явной передачи длины этих массивов.

Используя источник произвольной формы и предполагая, что символ по умолчанию такой же, как вид C_CHAR:

interface
  subroutine ParseSpec(  &
        Name, Name_len,  &
        Corename, Corename_len )  &
      bind(C, name="ParseSpec")
    use, intrinsic :: iso_c_binding, only: c_int, c_char
    integer(c_int), value :: Name_len
    character(kind=c_char), intent(inout) :: Name(Name_len)
    integer(c_int), value :: Corename_len
    character(kind=c_char), intent(inout):: Corename(Corename_len)
  end subroutine ParseSpec
end interface

USE, INTRINSIC :: ISO_C_BINDING, ONLY: C_INT
CHARACTER*80 FILE_SPEC
CHARACTER*200 CORE_NAME
CALL ParseSpec(  &
    FILE_SPEC, LEN(FILE_SPEC, KIND=C_INT),  &
    CORE_NAME, LEN(CORE_NAME, KIND=C_INT) )

extern "C" void ParseSpec( 
    char* name, int name_len, 
    char* corename, int corelen );
// Operations on name[0] to name[name_len-1] and 
// corename[0] through corename[core_len-1]...
person IanH    schedule 16.01.2016