Агрегирование за фактический год в SAS

Шаг 1. Убедитесь, что ваш набор данных отсортирован или проиндексирован по бренду и дате

proc sort data=want;
     by brand date;
run;

Шаг 2. Рассчитайте даты начала и окончания для каждого продукта

Идея кода ниже:

1. Мы знаем, что первое появление бренда в отсортированном наборе данных — это день, когда бренд был представлен. Мы назовем это Product_Year_Start.

2. Функцию intnx можно использовать для увеличения этой даты на 365 дней, а затем вычесть из нее 1. Назовем эту дату Product_Year_End.

3. Поскольку теперь мы знаем дату окончания года продукта, мы знаем, что если дата в любой строке превышает дату окончания года продукта, мы начали следующий год продукта. Мы просто возьмем рассчитанные Product_Year_End и Product_Year_Start для этого бренда и увеличим их на один год.

Все это достигается с помощью групповой обработки и оператора retain.

data Comparison_Dates;
    set have;
    by brand date;

    retain Product_Year_Start Product_Year_End;

    if(first.brand) then do;
        Product_Year_Start = date;
        Product_Year_End = intnx('year', date, 1, 'S') - 1;
    end;

    if(Date > Product_Year_End) then do;
        Product_Year_Start = intnx('year', Product_Year_Start, 1, 'S');
        Product_Year_End = intnx('year', Product_Year_End, 1, 'S');
    end;

    format Product_Year_Start Product_Year_End date9.;
run;

Шаг 3. Используя исходный код SQL, сгруппируйте по новым датам начала/окончания продукта

proc sql;
    create table want as
    select catt(year(Product_Year_Start), '-', year(Product_Year_End) ) as Product_Year
         , Brand
         , sum(Units_Sold) as Unit_per_Year
    from Comparison_Dates
    group by Brand, calculated Product_Year
    order by Brand, calculated Product_Year;
quit;

Следующий код делает то, что вы просите, в буквальном смысле: для самой ранней «даты» каждого «бренда» он начинает агрегировать «единицы продажи», когда достигает отметки 365 дней, он сбрасывает счетчик и запускает другой цикл.

data have;
    informat date ddmmyy10.;
    input date units_sold brand $ year;
    format date date9.;
    cards;
18/03/2010                5                   A         2010
12/04/2010                2                   A         2010
22/05/2010                1                   A         2010
25/05/2010                7                   A         2010
11/08/2011                5                   A         2011
12/07/2010                2                   B         2010
22/10/2010                1                   B         2010
05/05/2011                7                   B         2011
;

proc sort data=have;
    by brand date;
run;

data want;
    do until (last.brand);
        set have;
        by brand date;

        if first.brand then
            do;
                Sales_Over_365=0;
                _end=intnx('day',date,365);
            end;

        if date <= _end then
            Sales_Over_365+units_sold;
        else
            do;
                output;
                Sales_Over_365=units_sold;
                _end=intnx('day',date,365);
            end;
    end;

    output;
    drop _end;
run;

У вас должна быть дата начала для каждого бренда. Пока мы можем использовать первую дату продажи, но это может быть не то, что вам нужно. Затем вы можете классифицировать каждую дату продажи, по какому году она относится к этому бренду.

Давайте начнем с создания набора данных из ваших образцов данных. Переменная YEAR не нужна.

data have ;
  input Date Units_Sold Brand $ Year ;
  informat date ddmmyy10.;
  format date yymmdd10.;
cards;
18/03/2010 5 A 2010
12/04/2010 2 A 2010
22/05/2010 1 A 2010
25/05/2010 7 A 2010
11/08/2011 5 A 2011
12/07/2010 2 B 2010
22/10/2010 1 B 2010
05/05/2011 7 B 2011
;;;;

Теперь мы можем получить нужный вам ответ с помощью SQL-запроса.

proc sql ;
  create table want as
   select brand
        , start_date
        , 1+floor((date - start_date)/365) as sales_year
        , intnx('year',start_date,calculated sales_year -1,'same')
            as start_sales_year format=yymmdd10.
        , sum(units_sold) as total_units_sold
  from
  ( select brand
        , min(date) as start_date format=yymmdd10.
        , date
        , units_sold
    from have
    group by 1
   )
  group by 1,2,3,4
  ;
quit;

Это даст такой результат:

                                               total_
                       sales_      start_      units_
Brand    start_date     year     sales_year     sold
  A      2010-03-18       1      2010-03-18      15
  A      2010-03-18       2      2011-03-18       5
  B      2010-07-12       1      2010-07-12      10

Нет прямого способа сделать это. Вы можете сделать что-то вроде этого.

Чтобы проверить код, я сохранил вашу таблицу в текстовом файле.

Затем я создал класс под названием Sale.

public class Sale
{
    public DateTime Date { get; set; }
    public int UnitsSold { get; set; }
    public string Brand { get; set; }
    public int Year { get; set; }
}

Затем я заполнил List<Sale>, используя сохраненный текстовый файл.

var lines = File.ReadAllLines(@"C:\Users\kosala\Documents\data.text");
var validLines = lines.Where(l => !l.Contains("Date")).ToList();//remove the first line.

List<Sale> sales = validLines.Select(l => new Sale()
        {
            Date = DateTime.Parse(l.Substring(0,10)),
            UnitsSold = int.Parse(l.Substring(26,5)),
            Brand = l.Substring(46,1),
            Year = int.Parse(l.Substring(56,4)),
        }).ToList();

//All the above code is for testing purposes. The actual code starts from here.
var totalUnitsSold = sales.OrderBy(s => s.Date).GroupBy(s => s.Brand);

        foreach (var soldUnit in totalUnitsSold)
        {
            DateTime? minDate = null;
            DateTime? maxDate = null;
            int total = 0;
            string brand = "";

            foreach (var sale in soldUnit)
            {
                brand = sale.Brand;
                if (minDate == null)
                {
                    minDate = sale.Date;
                }
                if ((sale.Date - minDate).Value.Days <= 365)
                {
                    maxDate = sale.Date;
                    total += sale.UnitsSold;
                }
                else
                {
                    break;
                }
            }
            Console.WriteLine("Brand : {0} UnitsSold Between {1} - {2} is {3}",brand, minDate.Value, maxDate.Value, total);
   }