Как увеличить std_logic_vector внутри типа массива с помощью индекса? VHDL

Это связано с самым длинным статическим префиксом, это не только проблема синтеза, но и отражение в моделировании.

Драйверы для my_signal в процессе определяются по самому длинному статическому префиксу my_signal.

Используя нестатическое значение для индекса в массиве, вы создали драйверы для my_signal(0), my_signal(1), my_signal(2) и my_signal(3) в своем непомеченном процессе.

Каждое из параллельных назначений сигналов имеет эквивалентный процесс, и они имеют самый длинный статический префикс, который включает числовые литералы, используемые в качестве индекса в вашем массиве my_signal.

Два общих драйвера между немаркированным процессом и каждым эквивалентным процессом для каждого параллельного оператора присваивания приводят к разрешенному значению сигнала, которое в моделировании будет давать значения «X» или «U» для конфликтующих значений элементов std_logic. Ваш синтез блокируется и сообщает, что вы замкнули драйверы вместе.

См. IEEE Std 1076-2008 8. Имена, 8.1 Общие положения (самый длинный статический префикс, параграф 8), 14.7 Исполнение модели, 14.7.2 Драйверы, параграф 1, 14.7.3 Распространение значений сигнала, 14.7.3.1 Общие положения, параграф 5.

Если бы вы использовали неразрешенный тип элемента (BIT, BIT_VECTOR), вы бы получили отчеты об одной или нескольких ошибках во время разработки для нескольких драйверов в сигнальной сети. Это эквивалент того, что сообщает ваш инструмент синтеза.

Ваша проблема связана с несколькими дисками. Это сообщение и его ответ могут помочь понять это. Поскольку вы используете разрешенные типы (std_logic), вы не получите ошибок или предупреждений при компиляции или моделировании. Используемый вами инструмент (ISE) представляет собой логический синтезатор. Он пытается сопоставить описанное вами поведение с существующими аппаратными ресурсами. Поскольку ваше аппаратное обеспечение не поддерживает несколько дисков, вы получаете ошибки. Мои советы:

• не используйте разрешенные типы, когда они не нужны,
• используйте соответствующие типы (как мудро предложил Брайан Драммонд).

Что-то вроде следующего кода должно быть лучше. Адаптируйте его к вашим конкретным потребностям. Обратите внимание, что тип unsigned для ieee.numeric_std, к сожалению, является разрешенным типом. Поэтому используйте его осторожно и избегайте ситуаций с несколькими дисками. Или, что еще лучше, если ваши инструменты поддерживают это, используйте unresolved_unsigned неразрешенную версию unsigned.

library ieee;
use ieee.std_logic_1164.all;
use ieee.numeric_std.all;

entity ui_top is
  Port(clk         : in  std_ulogic;
       buttons     : in  std_ulogic_vector (4 downto 0); -- centre, left, up, right, down
       switches    : in  std_ulogic_vector (7 downto 0);
       leds        : out std_ulogic_vector (7 downto 0);
       digit       : out std_ulogic_vector (3 downto 0);
       segments    : out std_ulogic_vector (7 downto 0);
       uart_tx     : out std_ulogic);
end ui_top;

architecture Behavioral of ui_top is

  constant n: positive := 4;
  type my_arr_type is array (0 to 3) of unsigned(n-1 downto 0);
  -- type my_arr_type is array (0 to 3) of unresolved_unsigned(n-1 downto 0);

  signal my_signal : my_arr_type;
  signal index : natural range 0 to n-1;

begin

  -- send indexed signal to leds
  leds(n-1 downto 0) <= std_ulogic_vector(my_signal(index));

  -- set other outputs arbitrarily
  leds(7 downto n) <= (others => '1');
  uart_tx <= '1';
  digit <= "1110";
  segments <= (others => '0');
  -- set index
  index <= 0;

  process(clk)
  begin
    if (rising_edge(clk)) then
      -- set non indexed values arbitrarily
      for i in 0 to n-1 loop
        if i = index then
          if switches(1) = '1' then -- up
            my_signal(i) <= my_signal(i) + 1;
          end if;
        else
          my_signal(i) <= (others => '0');
        end if;
      end loop;
    end if; -- rising clock edge
  end process;

end Behavioral;

Причина (вероятно) в том, что существует другой процесс или параллельное назначение, которое управляет (назначает) my_signal, поэтому просмотрите весь код или разместите его здесь для дальнейшего изучения.

Обратите внимание, что драйвер (назначить) может относиться к другому индексу; взгляните на этот ответ.

Кстати. вы можете удалить

else --remain the same
    my_signal(to_integer(unsigned(index))) 
    <= my_signal(to_integer(unsigned(index)));

поскольку my_signal будет сохранять текущее значение до тех пор, пока не будет задано новое.