Получите случайный файл из папки и добавьте его в список воспроизведения iTunes.

Вот сценарий, который вы ищете. Я оставляю первый ответ, потому что он также может быть полезен для других.

property RList : "my random list" -- name of the random list
property ListGenres : {"Rock", "Pop", "Soundtrack", "Jazz"} -- your list of genres
property NumPerGenre : {3, 2, 5, 4} -- the number of songs per genre

tell application "iTunes"
if exists user playlist RList then -- check if the playlsit exists or not
    delete tracks of user playlist RList -- delete all current tracks of the play list
    repeat while (number of tracks of playlist RList) > 0
        delay 0.1 -- wait for the library to clear out, because iTunes is asynchronous !
    end repeat
else -- creation of the play list
    set MyPlayList to make new user playlist with properties {name:RList}
end if

repeat with I from 1 to (count of ListGenres) -- loop per genre
    set ListTracks to (tracks whose genre is (item I of ListGenres))
    repeat with J from 1 to (item I of NumPerGenre) -- loop to add x tracks per genre
        set TheTrack to item (random number from 1 to (count of ListTracks)) of ListTracks
        duplicate TheTrack to playlist RList
    end repeat -- loop for all tracks per genre
end repeat -- loop by Genre
play playlist RList -- start to play !  
end tell

Я написал много комментариев, чтобы было понятно (надеюсь). В этом примере у меня 4 жанра, и я получу 3 песни первого жанра, 2 песни второго жанра, ...и так далее. вы можете изменить эти свойства, если в списке жанров содержится то же количество элементов, что и в списке numpergenre.

К сожалению, начиная с iTunes 11, атрибут случайного воспроизведения не может быть установлен с помощью скрипта, вы должны установить его вручную в iTunes для случайного воспроизведения списка (его можно установить один раз для всех)

чтобы воспроизвести треки, вы должны сначала импортировать их в iTunes, как сказал Вадиан. лучше импортировать их в список воспроизведения (легче потом удалить). сценарий ниже делает это:

set MyRatio to 0.2 -- the % of files randomly selected over the total file of the selected folder
set MyFolder to choose folder "select folder with your musics"
tell application "Finder" to set MyList to every file of MyFolder

-- build the random list
set SongList to {}
set MaxCount to (MyRatio * (count of MyList)) as integer
set MyCount to 0
repeat until MyCount = MaxCount
set MyItem to random number from 1 to (count of MyList)
set NewFile to (item MyItem of MyList) as string
if NewFile is not in SongList then
    copy NewFile to the end of SongList
    set MyCount to MyCount + 1
end if
end repeat

-- add the files to iTunes new playlist
tell application "iTunes"
set MyPlayList to make new user playlist with properties {name:"my Import"}
repeat with I from 1 to count of SongList
    add ((item I of SongList) as alias) to MyPlayList
end repeat
play MyPlayList -- start to play the play list
end tell