Сортировка столбцов ListView со стрелками

HDF_SORTDOWN и HDF_SORTUP требуется comctl32 v6. Это указано в документации для HDITEM:

HDF_SORTDOWN Версия 6.00 и выше. Рисует стрелку вниз на этом элементе. Обычно это используется для указания того, что информация в текущем окне сортируется по этому столбцу в порядке убывания. Этот флаг нельзя комбинировать с HDF_IMAGE или HDF_BITMAP.

HDF_SORTUP версии 6.00 и выше. Рисует стрелку вверх на этом элементе. Обычно это используется для указания того, что информация в текущем окне сортируется по этому столбцу в порядке возрастания. Этот флаг нельзя комбинировать с HDF_IMAGE или HDF_BITMAP.

Как вы объяснили в своих комментариях, вы не включили манифест comctl32 v6. Это объясняет то, что вы наблюдаете.

Решения включают:

• Добавление манифеста comctl32 v6 или
• Пользовательские стрелки заголовка чертежа.

Вам не нужно менять исходный код VCL, чтобы следовать немецкому примеру, вы можете просто исправить среду выполнения кода.

DISCALMER Я хотел протестировать свой код на Delphi 6, но моя установка Delphi 6 не запустилась сегодня утром, поэтому она тестировалась только на Delphi XE!

Но я думаю, что это будет работать и на Delphi 6.

Сначала вам нужен класс для исправления среды выполнения метода:

unit PatchU;

interface

type
  pPatchEvent = ^TPatchEvent;

  // "Asm" opcode hack to patch an existing routine
  TPatchEvent = packed record
    Jump: Byte;
    Offset: Integer;
  end;

  TPatchMethod = class
  private
    PatchedMethod, OriginalMethod: TPatchEvent;
    PatchPositionMethod: pPatchEvent;
  public
    constructor Create(const aSource, aDestination: Pointer);
    destructor Destroy; override;
    procedure Restore;
    procedure Hook;
  end;

implementation

uses
  Windows, Sysutils;

{ TPatchMethod }

constructor TPatchMethod.Create(const aSource, aDestination: Pointer);
var
  OldProtect: Cardinal;
begin
  PatchPositionMethod := pPatchEvent(aSource);
  OriginalMethod := PatchPositionMethod^;
  PatchedMethod.Jump := $E9;
  PatchedMethod.Offset := PByte(aDestination) - PByte(PatchPositionMethod) - SizeOf(TPatchEvent);

  if not VirtualProtect(PatchPositionMethod, SizeOf(TPatchEvent), PAGE_EXECUTE_READWRITE, OldProtect) then
    RaiseLastOSError;

  Hook;
end;

destructor TPatchMethod.Destroy;
begin
  Restore;
  inherited;
end;

procedure TPatchMethod.Hook;
begin
  PatchPositionMethod^ := PatchedMethod;
end;

procedure TPatchMethod.Restore;
begin
  PatchPositionMethod^ := OriginalMethod;
end;

end.

Тогда нам нужно его использовать. Pau listview в форме, а затем этот код:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ComCtrls, PatchU;

type
  TListView = class(ComCtrls.TListView)
  protected
    procedure ColClick(Column: TListColumn); override;
  end;

  TForm1 = class(TForm)
    ListView1: TListView;
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

uses
  CommCtrl;

var
  ListView_UpdateColumn_Patch: TPatchMethod;

type
  THooked_ListView = class(TListView)
    procedure HookedUpdateColumn(AnIndex: Integer);
  end;

  { TListView }

procedure TListView.ColClick(Column: TListColumn);
var
  Header: HWND;
  Item: THDItem;
  NewFlag: DWORD;
begin
  Header := ListView_GetHeader(Handle);
  ZeroMemory(@Item, SizeOf(Item));
  Item.Mask := HDI_FORMAT;
  Header_GetItem(Header, Column.Index, Item);

  if Item.fmt and HDF_SORTDOWN <> 0 then
    NewFlag := HDF_SORTUP
  else
    NewFlag := HDF_SORTDOWN;

  Item.fmt := Item.fmt and not(HDF_SORTUP or HDF_SORTDOWN); // remove both flags
  Item.fmt := Item.fmt or NewFlag;
  Header_SetItem(Header, Column.Index, Item);

  inherited;
end;

{ THooked_ListView }

procedure THooked_ListView.HookedUpdateColumn(AnIndex: Integer);
begin
  ListView_UpdateColumn_Patch.Restore;
  try
    UpdateColumn(AnIndex);
  finally
    ListView_UpdateColumn_Patch.Hook;
  end;
end;

initialization

ListView_UpdateColumn_Patch := TPatchMethod.Create(@TListView.UpdateColumn, @THooked_ListView.HookedUpdateColumn);

finalization

ListView_UpdateColumn_Patch.Free;

end.

Как видите, мое демо сильно вдохновлено опубликованным вами кодом. Я только что удалил глобальные переменные. В моем примере я ничего не делаю, кроме как вызываю исходную процедуру, но вам, конечно, придется вызывать код из примера Geraman.

В общем, я просто хотел показать вам, как можно изменить VCL, не редактируя исходный код. Это должно вас заинтересовать.