Обработка файлов FASTQ на основе длины пары сопряжений

Как вы прочитали, ваша проблема связана с ложным push, который добавляет целочисленное значение в конец массива @fh. Я предполагаю, что вы стремились расширить массив, чтобы он был достаточно длинным, чтобы добавить новый дескриптор файла. Вы можете сделать это, назначив $#fh, поэтому вы должны написать $#fh = $len if $#fh < $len; однако в этом нет необходимости, потому что Perl будет автоматически расширять массивы для вас, когда вы просто присваиваете элемент за пределами конца массива.

У меня есть пара замечаний по вашей программе, которые, я надеюсь, будут вам полезны.

• Ненужно и расточительно раскошеливаться на команду awk. Perl вполне способен делать все то же, что и awk.

• Если вы обнаружите, что пишете split /\s+/, $_, то почти наверняка имеете в виду только split: поведение по умолчанию — split ' ', $_. Если вы используете /\s+/ в качестве шаблона и в строке, которую вы разбиваете, есть начальные пробелы, то split вернет пустую строку в качестве первого элемента в списке полей. Если вместо этого вы используете ' ' (буквальный одиночный пробел, а не шаблон / /), этого не произойдет. По сути, split ' ' эквивалентно /\S+/g.

• При интерполяции значений переменных в строке, как правило, лучше помещать идентификаторы в фигурные скобки, если есть следующий символ, который может быть частью идентификатора. Итак, "${file_name}_$len" вместо "$file_name\_$len"

Вот как я бы написал ваш код. Он накапливает входные записи в $line до тех пор, пока не будут добавлены четыре записи, а затем обрабатывает эту строку, как и раньше.

#!/usr/bin/perl

use strict;
use warnings;

my ($file_name, $infile) = @ARGV;

open my $in_fh, '<', $infile or die $!;
my $line;

my @fh;
while ( <$in_fh> ) {
  chomp;
  $line .= $_;

  if ( $. % 4 == 0 or eof ) {

    my @line = split ' ', $line;
    my $len  = length $line[1];
    next if $len < 100;

    open $fh[$len], '>', "${file_name}_$len" unless $fh[$len];
    print { $fh[$len] } "$_\n" for @line;

    $line = undef;
  }
}

Эта ошибка конкретно означает, что вы делаете что-то, что ожидает ссылку, но не получает ее.

Линия:

print {$fh[$len]} (join("\n",@line),"\n");

Явно печатает в дескриптор файла - из того, что выглядит как список дескрипторов файлов с именем @fh.

Эта строка:

push @fh, $len;

Будет вставлять числовое значение в этот список. (Предположительно $line[1] имеет длину 151 символ). Итак, вы на самом деле пытаетесь:

 print {151} (join("\n",@line),"\n");

Что, надеюсь, довольно очевидно - просто не сработает. Похоже, вы пытаетесь открыть дескриптор файла и вставить его в массив:

open $fh[$len], '>', "$file_name\_$len";

Могу ли я вместо этого предложить, что вам было бы гораздо лучше использовать для этого хэш? В противном случае у вас есть массив, полный пустых элементов, один из которых заполнен.

Где вы могли бы вместо этого:

#further up:
my %fh; 


#and then
open ( $fh{$len}, ">", "$file_name\_$len" ) or warn $!; 

Не забудьте закрыть дескрипторы файлов в конце:

foreach my $key ( keys %fh ) {
   close ( $fh{$key} );
}

Я бы также предложил, а не:

open( FH, "cat '$infile' | awk '{printf \"%s%s\",\$0,(NR%4?FS:RS)}' | " );

Вам, вероятно, лучше обрабатывать это в perl, поскольку все, что вы делаете, это анализируете файл с помощью внешнего двоичного файла. (И используйте лексические дескрипторы файлов: `open ( $input, "-|,"cat '$infile' | awk '{printf \"%s%s\",\$0,(NR%4?FS:RS)}' " ) или предупредить $!; )