Как правильно использовать pkg-config из cmake?

Если вы обычно используете cmake и pkg-config, это решение работает.

Если, однако, у вас есть библиотека, которая существует в каком-либо каталоге разработки (например, / home / me / hack / lib), то использование других методов, представленных здесь, не может настроить пути компоновщика. Библиотеки, которые не находятся в типичных местах установки, могут привести к ошибкам компоновщика, например /usr/bin/ld: cannot find -lmy-hacking-library-1.0. Это решение исправляет ошибку компоновщика в этом случае.

Другая проблема может заключаться в том, что файлы pkg-config не установлены в обычном месте, и пути pkg-config для проекта должны быть добавлены с использованием переменной среды PKG_CONFIG_PATH во время работы cmake (см. Другие вопросы о переполнении стека по этому поводу). Если у вас настроен правильный путь pkg-config, это решение также устраняет эту проблему.

Использование IMPORTED_TARGETs решает эту проблему. Это решение является улучшением этого более раннего ответа и сводится к этой окончательной версии рабочего файла CMakeLists.txt:

cmake_minimum_required(VERSION 3.14)
project(ya-project C)

# the `pkg_check_modules` function is created with this call
find_package(PkgConfig REQUIRED) 

# these calls create special `PkgConfig::<MODULE>` variables
pkg_check_modules(MY_PKG REQUIRED IMPORTED_TARGET any-package)
pkg_check_modules(YOUR_PKG REQUIRED IMPORTED_TARGET ya-package)

add_executable(program-name file.c ya.c)

target_link_libraries(program-name PUBLIC
        PkgConfig::MY_PKG
        PkgConfig::YOUR_PKG)

Обратите внимание, что target_link_libraries делает больше, чем просто изменяет команды компоновщика. Он также распространяет другие PUBLIC свойства указанных целей, такие как: флаги компилятора, определения компилятора, пути включения и т. Д.

Во-первых, звонок:

include(FindPkgConfig)

следует заменить на:

find_package(PkgConfig)

Вызов find_package() более гибкий и позволяет использовать такие параметры, как REQUIRED, которые автоматически выполняют действия, которые можно было бы делать вручную с помощью include().

Во-вторых, по возможности следует избегать ручного вызова pkg-config. CMake поставляется с богатым набором определений пакетов, которые можно найти в Linux в разделе /usr/share/cmake-3.0/Modules/Find*cmake. Они предоставляют пользователю больше возможностей и выбора, чем простой вызов pkg_search_module().

Что касается упомянутой гипотетической команды target_use(), в CMake уже есть встроенная функция PUBLIC | PRIVATE | INTERFACE. Вызов типа target_include_directories(mytarget PUBLIC ...) вызовет автоматическое использование подключаемых каталогов в каждой цели, которая использует mytarget, например target_link_libraries(myapp mytarget). Однако этот механизм, похоже, предназначен только для библиотек, созданных в файле CMakeLists.txt, и не работает для библиотек, полученных с помощью pkg_search_module(). Для этого можно использовать вызов add_library(bar SHARED IMPORTED), но я еще не рассматривал это.

Что касается главного вопроса, то здесь это работает в большинстве случаев:

find_package(PkgConfig REQUIRED)
pkg_check_modules(SDL2 REQUIRED sdl2)
...
target_link_libraries(testapp ${SDL2_LIBRARIES})
target_include_directories(testapp PUBLIC ${SDL2_INCLUDE_DIRS})
target_compile_options(testapp PUBLIC ${SDL2_CFLAGS_OTHER})

SDL2_CFLAGS_OTHER содержит определения и другие флаги, необходимые для успешной компиляции. Флаги SDL2_LIBRARY_DIRS и SDL2_LDFLAGS_OTHER по-прежнему игнорируются, не знаю, как часто это может стать проблемой.

Дополнительная документация здесь http://www.cmake.org/cmake/help/v3.0/module/FindPkgConfig.html

Редко бывает нужно связать только с SDL2. В популярном в настоящее время ответе используется pkg_search_module(), который проверяет заданные модули и использует первый рабочий.

Более вероятно, что вы захотите связать с SDL2 и SDL2_Mixer, SDL2_TTF и т. Д. pkg_check_modules() проверяет наличие всех данных модулей.

# sdl2 linking variables
find_package(PkgConfig REQUIRED)
pkg_check_modules(SDL2 REQUIRED sdl2 SDL2_ttf SDL2_mixer SDL2_image)

# your app
file(GLOB SRC "my_app/*.c")
add_executable(my_app ${SRC})
target_link_libraries(my_app ${SDL2_LIBRARIES})
target_include_directories(my_app PUBLIC ${SDL2_INCLUDE_DIRS})
target_compile_options(my_app PUBLIC ${SDL2_CFLAGS_OTHER})

Отказ от ответственности: я бы просто прокомментировал собственный ответ Грумбеля, если бы у меня было достаточно уличных кредитов с stackoverflow.

В большинстве доступных ответов не удается настроить заголовки для библиотеки pkg-config. После размышлений над документацией для FindPkgConfig я пришел к решению, которое предоставляет также:

include(FindPkgConfig)
if(NOT PKG_CONFIG_FOUND)
  message(FATAL_ERROR "pkg-config not found!" )
endif()
 
pkg_check_modules(<some-lib> REQUIRED IMPORTED_TARGET <some-lib>)
 
target_link_libraries(<my-target> PkgConfig::<some-lib>)

(Замените свою цель вместо <my-target> и любую библиотеку вместо <some-lib> соответственно.)

Параметр IMPORTED_TARGET кажется ключевым и делает все доступным в пространстве имен PkgConfig::. Это было все, что требовалось, а также все, что должно требоваться.

1. Нет такой команды, как target_use. Но я знаю несколько проектов, которые написали такую ​​команду для внутреннего использования. Но каждый проект хочет передать дополнительные флаги или определения, поэтому нет смысла иметь их в CMake. Еще одна причина не использовать его - это шаблонные библиотеки C ++, такие как Eigen, библиотеки нет, но у вас есть только набор включаемых файлов.

2. Описанный способ часто бывает правильным. Для некоторых библиотек он может отличаться, тогда вам придется добавить _LDFLAGS или _CFLAGS. Еще одна причина отсутствия target_use. Если это не сработает, задайте новый вопрос, касающийся SDL2 или любой другой библиотеки, которую вы хотите использовать.

Если вы хотите добавить определения из библиотеки, для этого есть инструкция add_definitions. Документацию можно найти здесь, а также другие способы добавления флагов компилятора. .

В следующем фрагменте кода эта инструкция используется для добавления GTKGL в проект:

pkg_check_modules(GTKGL REQUIRED gtkglext-1.0)
include_directories(${GTKGL_INCLUDE_DIRS})
link_directories(${GTKGL_LIBRARY_DIRS})
add_definitions(${GTKGL_CFLAGS_OTHER})
set(LIBS ${LIBS} ${GTKGL_LIBRARIES})

target_link_libraries([insert name of program] ${LIBS})