Как создавать формы ввода TI-BASIC (TI-84+)?

На языке программирования TI-BASIC (в частности, TI-84+), как вы создаете формы ввода, такие как те, которые включены в приложения по умолчанию на TI-84+.

Есть много способов запросить ввод в вашей программе:

• Подсказка: запрашивает ввод и сохраняет его в переменной. Например, Prompt A. Самый простой способ запросить ввод, но не очень визуально привлекательный.

• Ввод: аналогично команде "Подсказка", за исключением того, что теперь вы можете включать текст в поле ввода. Например, Input "What is your name?",A.

• Меню (): ввод нескольких вариантов, и каждый вариант связан с маркером Lbl в другом месте скрипта. Многое как экран ошибки с вариантами выхода/перехода, которые вы, вероятно, видели.Например, Menu("Are you a boy or a girl?","Boy",B,"Girl",G).

• getKey: проверяет, нажата ли определенная клавиша, и выводит True (1), если эта клавиша нажата. Например, getKey 105. См. здесь, каким числам соответствует каждый ключ.

На приведенном здесь изображении показан пример того, что я пытаюсь создать: меню, которое вы можете прокручивать и свободно вводить несколько переменных перед выполнением функции http://imgur.com/ulthDRV

Боюсь, это невозможно в программах. Вы можете либо ввести несколько входных данных, либо вам может быть интересно заняться созданием приложений.

Кроме того, возможно ли сделать это меню динамически обновляемым при вводе переменных?

Если вы говорите о тексте поверх скриншота, да, вы можете; просто поместите команду Disp или что-то в этом роде после каждой строки ввода, чтобы он постоянно перезаписывал текст выше новым текстом после ввода переменной.

Вы поставили перед TI-Basic довольно высокий заказ. user3932000 правильный; нет встроенной функции для создания формы ввода запрашиваемого типа.

Однако ничто не мешает вам создать интерактивный интерфейс самостоятельно. Создание его с нуля займет много времени и потребует значительного объема памяти на вашем калькуляторе. Нет стандартного кода, в который вы вставляете свои переменные, чтобы получить желаемые результаты, но вам может повезти смоделировать его после написанного мной квадратичного решателя.

ClrHome
a+bi
Output(1,1,"    QUADRATIC
Output(2,1,"    AX²+BX+C
Output(3,1,"ZEROS:
Output(6,1,"A=
Output(7,1,"B=
Output(8,1,"C=

DelVar YDelVar D
"             →Str1

While Y≠105
getKey→Y

If Ans
Then
Output(X,4,Str1
Output(3,7,Str1+Str1+Str1+"   
End

X+(Ans=34)-(Ans=25
If Ans<6:8
If Ans>8:6
Ans→X

Output(Ans,16,"◄

D(Y≠45→D

If Y=25 or Y=34
sum({A,B,C}(X={6,7,8→D

If Y=104:⁻D→D

10not(Y)+Y(102≠Y)-13int(Y/13(2>abs(5-abs(5-abs(Y-83
If Ans≤9
D10+Ans-2Ans(D<0→D

If X=6:D→A
If X=7:D→B
If X=8:D→C

If A
Then
2ˉ¹Aˉ¹(⁻B+{1,⁻1}√(B²-4AC
Else
If B
Then
⁻C/B
Else
If C
Then
"No Zeros
Else
"All Numbers
End
End
End

Output(3,7,Ans
Output(6,3,A
Output(7,3,B
Output(8,3,C
End
ClrHome
Ans

Вот GIF того, что он делает для вас.

Еще немного работы. Этот код можно использовать на экране графика вместо главного экрана, что дает больше возможностей для компоновки и дизайна.