BusyIndicator не отображается

Это можно сделать с помощью сигнала QQuickWindow afterSynchronizing:

import QtQuick 2.4
import QtQuick.Controls 1.3

ApplicationWindow {
    width: 400
    height: 400
    visible: true

    Component.onCompleted: print(Qt.formatDateTime(new Date(), "mm:ss:zzz"), "QML loaded")

    onAfterSynchronizing: {
        print(Qt.formatDateTime(new Date(), "mm:ss:zzz"), "Window content rendered")
        if (!loader.item) {
            loader.active = true
        }
    }

    Item {
        anchors.fill: parent

        BusyIndicator {
            running: !loader.item
            anchors.centerIn: parent
        }

        Loader {
            id: loader
            active: false
            anchors.fill: parent
            sourceComponent: Text {
                wrapMode: Text.Wrap

                Component.onCompleted: {
                    for (var i = 0; i < 500; ++i) {
                        text += "Hello, ";
                    }
                }
            }
        }
    }
}

Идея состоит в том, чтобы использовать Loader, чтобы иметь контроль над тем, когда происходит дорогостоящая операция. Вы также можете использовать динамически загружаемый компонент через Qt.createQmlObject() или Qt.createComponent() для динамической загрузки компонента в отдельный файл.

Если вы запустите пример, вы увидите, что вы получите следующий вывод:

qml: 58:12:356 QML загружен
qml: 58:12:608 Отображено содержимое окна

Мы используем сигнал QQuickWindow afterSynchronizing, чтобы узнать, когда содержимое окна было отображается и действует только в первый раз (через if (!loader.item)).

Когда сигнал исходит изначально, мы можем быть уверены, что BusyIndicator начал свою анимацию, поэтому пользователь действительно увидит вращающуюся иконку.

Как только Loader завершит загрузку текста, его свойство item станет ненулевым, а BusyIndicator исчезнет.

Вы не можете просмотреть свой BusyIndicator только потому, что долгая работа в обработчике onClicked блокирует графический интерфейс приложения и индикатор не обновляется. Вы должны запустить такую ​​операцию в другом потоке, чтобы избежать зависания графического интерфейса. Простой пример:

QML

Window {
    id: win
    width: 300
    height: 300

    property bool run : false

    Rectangle {
        anchors.fill: parent
        BusyIndicator {
            id: busy
            anchors.centerIn: parent
            running: win.run
        }

        MouseArea {
            anchors.fill: parent
            onClicked: {
                win.run = true
                thread.sendMessage({run : true});
            }
        }

        WorkerScript {
            id: thread
            source: "handler.js"
            onMessage: {
                win.run = messageObject.run;
            }
        }
    }
}

handle.js

WorkerScript.onMessage = function(message) {
    if(message.run === true) {
        for(var a=0;a<1000000;a++) { console.log(a) }
    }
    WorkerScript.sendMessage({run : false});
}

Сегодня столкнулся с той же проблемой! Я предполагаю, что вы управляете своим BusyIndicator из свойства C++, называемого busy. И вы устанавливаете busy на true непосредственно перед расчетами и на false сразу после. Это решило это для меня. Это не очень элегантное решение, но оно работает:

QML

BusyIndicator {
    running: CPPModule.busy
}

Цена за тысячу показов

void CPPModule::setBusy(const bool &busy)
{
    m_busy = busy;
    emit busyChanged();
}
void CPPModule::InsertIntoDB()
{
    setBusy(true);
    QThread::msleep(50);
    QCoreApplication::processEvents();
    /*
    very Long Operation
    */
    setBusy(false);
}