Метод Ньютона в Perl

Добро пожаловать в Перл.

Я настоятельно рекомендую следующие изменения в вашем коде:

1. Всегда указывайте use strict; и use warnings; в КАЖДОМ Perl-скрипте.

2. Всегда chomp ваш ввод из STDIN, как вы его принимаете:

   chomp( my $input = <STDIN> );
   

3. Не создавайте без необходимости подпрограммы, особенно для таких одноразовых сценариев, как этот.

4. Вместо использования модификатора инструкции формы do, я бы рекомендовал использовать бесконечный while с операторами управления циклом для выхода:

   while (1) {
   
       last if COND;
   }
   

5. Наконец, поскольку все коэффициенты вашего полинома связаны с показателем степени для X, я бы рекомендовал использовать %hash для удобного сохранения этих значений.

Как показано:

#!usr/bin/env perl
use strict;
use warnings;

print "Build your Polynomial:\n";

my %coefficients;

# Request each Coefficient and Exponent of the Polynomial
while (1) {
    print "What is the coefficient (for each factor) of your function? (use a bare return when done)\n";
    chomp( my $coef = <STDIN> );

    last if $coef eq '';

    print "... times x to the (enter exponent, if no exponent, enter 1. if no x, enter 0)?\n";
    chomp( my $exp = <STDIN> );

    $coefficients{$exp} = $coef;
}

print "\nFirst guess? (this is x0)\n";
chomp( my $x = <> );

# Newton's Method Iteration
while (1) {
    my $fx  = 0;
    my $fpx = 0;

    while ( my ( $exp, $coef ) = each %coefficients ) {
        $fx += $coef * $x**$exp;
        $fpx += $coef * $exp * $x**( $exp - 1 ) if $exp != 0;
    }

    print "   f(x) = $fx\n";
    print "   f'(x) = $fpx\n";

    die "Slope of 0 found at $x\n" if $fpx == 0;

    my $new_x = $x - $fx / $fpx;

    print "Newton's Method gives new value for x at $new_x\n";

    if ( abs($x - $new_x) < .0001 ) {
        print "Accuracy reached\n";
        last;
    }

    $x = $new_x;
}

У меня возникли проблемы с определением того, что вы намеревались использовать в своем коде. Основная проблема, по-видимому, заключается в том, что у вас в голове не ясно, что делает каждая из ваших подпрограмм, поскольку fx и fprimex запрашивают данные, а также оценивают функцию (за исключением суммирования условий, которое, как ни странно, выполняется вне подпрограмма). Это совсем не то, что вам нужно, так как показатели степени и коэффициенты остаются постоянными на протяжении всей программы, которая должна много раз оценивать эти функции, и вы действительно не хотите каждый раз запрашивать значения снова.

Вот несколько советов, как заставить Perl-код работать в целом.

• Пишите программу небольшими порциями — по одной-две строки за раз — и проверяйте после каждого добавления, что программа компилируется, запускается и дает ожидаемые результаты. Написание всей программы еще до того, как вы попытаетесь ее запустить, — прямой путь к катастрофе.

• Всегда use strict и use warnings, и объявляйте каждую переменную с my как можно ближе к точке, где она впервые используется. У вас есть много необъявленных переменных, которые, следовательно, являются глобальными, и передача информации между разделами кода с использованием глобальных переменных — хороший способ потеряться в собственном коде. Для подпрограммы рекомендуется использовать только переданные ей параметры или объявленные в ней переменные.

• chomp переменные, как только они будут прочитаны либо из файла, либо из терминала. Полезная идиома для обрезки входных строк в источнике:

  chomp(my $input = <>)
  

  что гарантирует, что в ваших данных нет случайных новых строк

По крайней мере, это должно заставить вас начать.

Я сомневаюсь, стоит ли это показывать. Я надеюсь, что это поможет вам, но я действительно не хочу втягивать вас в те части Perl, с которыми вы не знакомы.

Это программа, которая использует метод Ньютона–Рафсона для нахождения корня многочлена. На данный момент я пропустил ввод терминала и жестко запрограммировал данные. В нынешнем виде он находит квадратный корень из 3000, находя положительный корень из x² - 3000.

Обратите внимание, что @f и @f_prime содержат коэффициенты функции и ее производной назад от обычного порядка, поэтому @f равно (-3000, 0, 1). Программа также вычисляет коэффициенты производной функции, так как это просто и гораздо предпочтительнее, чем запрашивать у пользователя другой набор значений.

Есть только одна подпрограмма polynomial, которая принимает значение для x и список коэффициентов. Это используется для вычисления значения как функции, так и ее производной для заданного значения x.

Шаг алгоритма находится в строке

my $new_x = $x - polynomial($x, @f) / polynomial($x, @f_prime);

который вычисляет x - f(x) / f'(x) и присваивает его $new_x. Каждая последующая оценка выводится в STDOUT до выхода из цикла.

Сравнение значений с плавающей запятой на равенство — плохая идея. Точность компьютерных значений с плавающей запятой, очевидно, ограничена, и последовательность, вероятно, никогда не сойдется к точке, в которой два последних значения последовательности равны. Лучшее, что можно сделать, это проверить, находится ли абсолютное значение разницы между двумя последними значениями ниже разумной дельты. Точность 10E12 приемлема для 32-битных чисел с плавающей запятой. Я обнаружил, что последовательность сходится в пределах 10E14 довольно надежно, но если вы обнаружите, что ваша программа зависает в бесконечном цикле, вам следует увеличить запас.

use strict;
use warnings;

my @f       = reverse (1, 0, -3000);
my @f_prime = map { $f[$_] * $_ } 1 .. $#f;

my $x = 0.5;
print $x, "\n";

while () {
  my $new_x = $x - polynomial($x, @f) / polynomial($x, @f_prime);
  last if abs($new_x - $x) < $x / 1e14;
  $x = $new_x;
  print $x, "\n";
}

sub polynomial {
  my ($x, @coeffs) = @_;

  my $total = 0;
  my $x_pow = 1;

  for my $coeff (@coeffs) {
    $total += $x_pow * $coeff;
    $x_pow *= $x;
  }

  $total;
}

вывод

0.5
3000.25
1500.62495833681
751.312062703027
377.652538627869
192.798174296885
104.179243809523
66.4878834504349
55.8044433107163
54.7818016853582
54.7722565822241
54.7722557505166