Реализация Eiffel Iterable на MAP?

Как только MAP [KEY, VAL] наследует ITERABLE [KEY], общий параметр ITERATION_CURSOR привязывается к KEY. Однако {ITERATION_CURSOR}.item — это просто обычная функция, которая подлежит повторному объявлению, переименованию и т. д. Поэтому несколько подходов могут соответствовать вашим потребностям:

1. Объявите MAP_ITERATOR_CURSOR иметь два формальных дженерика и объявите {MAP}.new_cursor следующим образом:

   class MAP [KEY, VAL] inherit ITERABLE [KEY] feature
       new_cursor: MAP_ITERATOR_CURSOR [KEY, VAL]
           do
               create Result.make (Current)
           end
   end
   
   class MAP_ITERATOR_CURSOR [KEY, VAL] inherit ITERATION_CURSOR [KEY]
   create make
   feature
       make (t: like target)
           do
               target := t
           end
       target: MAP [KEY, VAL]
       item: KEY ...
       value: VAL
           do
               Result := target.item (item)
           end
   end
   

   Тогда клиентский код может выглядеть как

   across map as c loop
       -- Use `c.item` of type KEY.
       -- Use `c.value` of type VAL.
   end
   

2. Если требуется, чтобы {MAP_ITERATOR_CURSOR}.item имел тип VAL, первый способ — использовать точно такой же код, что и выше, но переименовать функцию item, полученную из ITERABLE:

   class MAP_ITERATOR_CURSOR [KEY, VAL] inherit
       ITERATION_CURSOR [KEY] rename item as key end
   ...
       key: KEY ...
       item: VAL
           do
               Result := target.item (key)
           end
   end
   

   Тогда клиентский код может выглядеть как

   across map as c loop
       -- Use `c.item` of type VAL.
       -- Use `c.key` of type KEY.
   end
   

3. Итерацию можно выполнять по элементам типа VAL с самого начала. В этом случае фактический универсальный ITERABLE должен быть VAL:

   class MAP [KEY, VAL] inherit ITERABLE [VAL] feature
       new_cursor: MAP_ITERATOR_CURSOR [KEY, VAL]
           do
               create Result.make (Current)
           end
   end
   
   class MAP_ITERATOR_CURSOR [KEY, VAL] inherit ITERATION_CURSOR [VAL]
   create make
   feature
       make (t: like target)
           do
               target := t
           end
       target: MAP [KEY, VAL]
       item: VAL
           do
               Result := target.item (key)
           end
       key: KEY
               -- This feature can be not exported, or even not present
               -- as soon as `item` can be implemented.
   end
   

   Код клиента аналогичен случаю 2, но key может быть недоступен:

   across map as c loop
       -- Use `c.item` of type VAL.
   end
   

4. В 3 формальное общее KEY в MAP_ITERATION_CURSOR сохранено для удобства. Его можно удалить при условии, что есть какой-то способ доступа к элементам MAP, но это может вызвать некоторые другие проблемы, связанные с доступом к MAP, соответствием и CAT-вызовами. Поэтому, хотя это потенциально осуществимо, я бы не пошел на это.

Почему бы не использовать TABLE_ITERABLE [G, K]?

cf https://svn.eiffel.com/eiffelstudio/trunk/Src/library/base/elks/kernel/table_iterable.e