Как подавить / автоматически закрыть диалоговое окно ошибки в AppleScript

Я боролся с этой проблемой на своем медиа-сервере Mac Mini целую вечность и считаю, что наконец-то нашел решение.

Я разделил его на два скрипта:

первый работает в режиме ожидания (а не в цикле повторения) и вызывает второй скрипт каждые 10 секунд, который обрабатывает монтирование диска.

--------------------------------------------------------------------------------------
--"On Idle Launch Basic Drive Mounter.app"

on idle
    try
        --script loads on startup, so first we wait 5 seconds to ensure network
        delay 5
        --run the mounter script which is on the desktop
        run script file ":Users:localusername:Desktop:Basic Drive Mounter.app"

    on error errStr number errorNumber
        --listen for the apple quit command and quit
        if the errorNumber is equal to -128 then
            quit
            return 1
        --listen for the unknown error and ignore it
        else if the errorNumber is equal to -5014 then
            return 5
        else
            --all other errors are also ignored
            return 5
        end if
    end try
    --return with a wait of 5 seconds before next idle run
    return 5

end idle
--------------------------------------------------------------------------------------

второй скрипт выполняет проверку сети, а затем пытается смонтировать том с помощью монтирования оболочки. Первоначально я использовал средство поиска «монтирование тома», и эти коды также существуют в виде комментариев, но мне не понравилось, что диалоговое окно появляется при ошибках; хотя бы на секунду, поэтому я перешел к сценарию оболочки.

--------------------------------------------------------------------------------------
--"Basic Drive Mounter.app"
try
    set IP_address to "xxx.xxx.xxx.xxx"

    set IP_Valid to true

    try
        do shell script ("ping -c 2 " & IP_address)
    on error
        set IP_Valid to false
    end try

    if IP_Valid then
        tell application "Finder"
            if disk "work" exists then
            else
                -->>shell script version
                try
                    do shell script "mkdir /Volumes/work"
                end try
                do shell script "mount_afp afp://xxx.xxx.xxx.xxx/work /Volumes/work/"
                --<<shell script version
                -->>finder mount volume version
                --with timeout of 1 second
                --  mount volume "afp://xxx.xxx.xxx.xxx/work"
                --end timeout
                --<<finder mount volume version
            end if
        end tell
    end if
on error
    -->>finder mount volume version
    --on error finder returns an error dialog which needs to be closed to go back and  retry
    --tell application "System Events"
    --  keystroke return
    --end tell
    --<<finder mount volume version
    return 0
end try    
--------------------------------------------------------------------------------------

не все это мой собственный код, так что большое спасибо сообществу applescript и Google - не забудьте заплатить вперед

Извиняюсь за корявый ответ. Я думаю, что если вы попробуете что-то подобное, вас не будут беспокоить диалоги (но вы все равно можете заставить свой скрипт реагировать на ошибки).

(ниже приведена простая версия. Документация для mount_afp с именем пользователя и паролем находится здесь: http://developer.apple.com/library/mac/documentation/Darwin/Reference/Manpages/man8/mount_afp.8.html )

    try
        alias (POSIX file "/Volumes/yourMountedVolumeName")--hacky check for mount point
    on error
        --does not exist, so make dir
        do shell script "mkdir /Volumes/yourMountedVolumeName"
    end try

    --now use do shell to mount
    try
        do shell script "mount_afp 'afp://yourServer/yourMountedVolumeName/' /Volumes/yourMountedVolumeName"

    on error errText number errnum
        log {errText, errnum}
    end try

[недостаточный ответ ниже]

Что-то из этого может быть очевидным, но вам нужно

killall NetAuthAgent

do shell script "killall NetAuthAgent"

Конечно, вы должны быть осторожны, чтобы не убить его во время процесса аутентификации.

Чтобы смонтировать диски, создайте сценарий Apple следующим образом:

tell application "Finder"

    try

        mount volume "afp://192.168.0.0/test"

    end try

end tell

Затем, чтобы закрыть появившееся предупреждающее сообщение, используйте другой скрипт, подобный этому:

delay 2
tell application "System Events"
    click UI element "OK" of window 1 of application process "NetAuthAgent"
end tell

Задержка просто дает возможность появиться окну сообщения, но вам это может не понадобиться.

Если вы запустите этот последний скрипт из терминала, используя osacompile, а затем osascript, вам нужно будет предоставить доступ к терминалу.