Как вывести список всех папок с размером через командный файл

Для каждой папки в списке используйте команду dir, чтобы получить размер файлов в папке.

@echo off
    setlocal disabledelayedexpansion

    set "folder=%~1"
    if not defined folder set "folder=%cd%"

    for /d %%a in ("%folder%\*") do (
        set "size=0"
        for /f "tokens=3,5" %%b in ('dir /-c /a /w /s "%%~fa\*" 2^>nul ^| findstr /b /c:"  "') do if "%%~c"=="" set "size=%%~b"
        setlocal enabledelayedexpansion
        echo(%%~nxa # !size!
        endlocal
    )

    endlocal

Он перебирает указанную папку (передается как параметр в пакетный файл или текущий каталог, если параметр отсутствует).

Для каждой папки внутри нее (for /d) рекурсивная команда dir выполняется внутри внутренней команды for, и из ее вывода анализируется итоговая строка в конце (извлекаемая findstr) (команда tokens в for) и общий размер будут получены все файлы в этой подпапке. Затем имя (и расширение, если оно есть) папки и размер элементов под ней выводятся на консоль.

Если необходимо создать файл, перенаправьте вывод пакета в файл.

getSizes.cmd "c:\temp" > C:\folderList.txt

Используя отличный код MC ND, я добавил преобразование в килобайты, мегабайты, гигабайты и т. д. На тот случай, если вы предпочитаете иметь его в этих форматах.

@echo off
setlocal disabledelayedexpansion

set "folder=%~1"
  if not defined folder set "folder=%cd%"

    for /d %%a in ("%folder%\*") do (
        set "size=0"
        for /f "tokens=3,5" %%b in ('dir /-c /a /w /s "%%~fa\*" 2^>nul ^| findstr /b /c:"  "') do if "%%~c"=="" set "size=%%~b"
        setlocal enabledelayedexpansion
        call :GetUnit !size! unit
        call :ConvertBytes !size! !unit! newsize
        echo(%%~nxa - !newsize! !unit!
        endlocal
    )

endlocal
exit /b

:ConvertBytes bytes unit ret
setlocal
if "%~2" EQU "KB" set val=/1024
if "%~2" EQU "MB" set val=/1024/1024
if "%~2" EQU "GB" set val=/1024/1024/1024
if "%~2" EQU "TB" set val=/1024/1024/1024/1024
> %temp%\tmp.vbs echo wsh.echo FormatNumber(eval(%~1%val%),1)
for /f "delims=" %%a in ( 
  'cscript //nologo %temp%\tmp.vbs' 
) do endlocal & set %~3=%%a
del %temp%\tmp.vbs
exit /b


:GetUnit bytes return
set byt=00000000000%1X
set TB=000000000001099511627776X
if %1 LEQ 1024 set "unit=Bytes"
if %1 GTR 1024   set "unit=KB"
if %1 GTR 1048576  set "unit=MB"
if %1 GTR 1073741824  set "unit=GB"
if %byt:~-14% GTR %TB:~-14% set "unit=TB"
endlocal & set %~2=%unit%
exit /b

Я взял код @Matt Williamsons и заставил его экспортировать каждую строку в файл .csv в каталоге запуска, folderSizes.csv. Он предоставляет полный размер байта в виде столбца, чтобы вы могли легко сортировать в Excel (или что-то еще).

@echo off
echo Getting folder sizes for you...storing to folderSizes.csv
setlocal disabledelayedexpansion
if EXIST folderSizes.csv del folderSizes.csv
echo Folder,Bytes Size,Short Size > folderSizes.csv

set "folder=%~1"
  if not defined folder set "folder=%cd%"

    for /d %%a in ("%folder%\*") do (
        set "size=0"
        for /f "tokens=3,5" %%b in ('dir /-c /a /w /s "%%~fa\*" 2^>nul ^| findstr /b /c:"  "') do if "%%~c"=="" set "size=%%~b"
        setlocal enabledelayedexpansion
        call :GetUnit !size! unit
        call :ConvertBytes !size! !unit! newsize
        echo(%%~nxa,!size!,!newsize!!unit! >> folderSizes.csv
        endlocal 
    )

endlocal
exit /b

:ConvertBytes bytes unit ret
setlocal
if "%~2" EQU "KB" set val=/1024
if "%~2" EQU "MB" set val=/1024/1024
if "%~2" EQU "GB" set val=/1024/1024/1024
if "%~2" EQU "TB" set val=/1024/1024/1024/1024
> %temp%\tmp.vbs echo wsh.echo FormatNumber(eval(%~1%val%),1)
for /f "delims=" %%a in ( 
  'cscript //nologo %temp%\tmp.vbs' 
) do endlocal & set %~3=%%a
del %temp%\tmp.vbs
exit /b


:GetUnit bytes return
set byt=00000000000%1X
set TB=000000000001099511627776X
if %1 LEQ 1024 set "unit=Bytes"
if %1 GTR 1024   set "unit=KB"
if %1 GTR 1048576  set "unit=MB"
if %1 GTR 1073741824  set "unit=GB"
if %byt:~-14% GTR %TB:~-14% set "unit=TB"
endlocal & set %~2=%unit%
exit /b

С помощью моей JREN.BAT папки с размерами. Это гибридный JScript/пакетный сценарий, который изначально запускается на любом компьютере с Windows, начиная с XP.

JREN удобно конвертировать в мегабайты (или любые другие единицы измерения) — он просто указывает размер в байтах. Но, безусловно, удобно (и сравнительно быстро) получить листинг:

jren "$" "' # '+size()" /d /j /list /p "d:\temp" >"C:\folderList.txt"

Вы можете сначала указать размер папки, пробел дополнить до фиксированной ширины, превышающей самую большую папку, а затем имя папки. Я нахожу этот формат намного легче для чтения, и его по-прежнему легко анализировать:

jren "^" "size('               ')+'  '" /d /j /list /p "d:\temp" >"C:\folderList.txt"

Вывод будет выглядеть примерно так

           1852  SomeFolderName
        1616869  Another folder name
         137764  yetAnother

Поскольку JREN — это пакетный файл, вы должны использовать CALL JREN, если вы помещаете команду в другой пакетный сценарий.

попробуйте sed для Windows:

dir /-c /a /w /s|sed -nr "/:$/q;/:/h;/^\s+[0-9]/{s/.*[^0-9]([0-9]+.*)/\1/;H;g;s/\n/ /p}"

если вы используете Windows 7 или новую, используйте powershell и введите команду

ls-r >> log.txt

он перечислит все файлы в текущем каталоге вместе с размером файла в байтах для файла журнала.