Как я могу отсоединить процесс от CGI, чтобы я мог хранить и читать файлы из памяти?

Скажем, у вас есть простой resource.cgi:

#! /usr/bin/perl

use warnings;
use strict;

use Reader;
use CGI qw/ :standard /;

print header("text/plain"),
      "Contents:\n",
      Reader::data,
      "-" x 40, "\n";

Его вывод

Content-Type: text/plain; charset=ISO-8859-1

Contents:
This is a data file
with some very interesting
bits.
----------------------------------------

Самое интересное в Reader.pm, которое начинается со знакомого шаблонного кода:

package Reader;

use warnings;
use strict;

use Fcntl qw/ :DEFAULT :flock :seek /;
use POSIX qw/ setsid /;    

Затем он определил точки встречи:

my $PIDFILE = "/tmp/reader.pid";
my $DATA    = "/tmp/file.dat";
my $PIPE    = "/tmp/reader.pipe";

Подпрограмма import вызывается как часть use Module. Если демон уже запущен, то делать нечего. В противном случае мы разветвляем демона и записываем его идентификатор процесса в $PIDFILE.

sub import {
  return unless my $fh = take_lock();

  my $child = fork;
  die "$0: fork: $!" unless defined $child;

  if ($child) {
    print $fh  "$child\n" or die "$0: write $PIDFILE: $!";
    close $fh             or die "$0: close $PIDFILE: $!";
    return;
  }

  # daemonize
  close $fh;
  chdir "/";
  open STDIN,  "<", "/dev/null";
  open STDOUT, ">", "/dev/null";
  open STDERR, ">", "/dev/null";
  setsid;

  open $fh, "<", $DATA or die;
  undef $/;
  my $data = <$fh>;
  close $fh;

  while (1) {
    open my $fh, ">", $PIPE or die;
    print $fh $data         or die;
    close $fh;
  }
}

Каждый клиент должен дождаться своей очереди, чтобы получить блокировку $PIDFILE. Получив блокировку, мы проверяем, что идентифицированный процесс все еще работает, и при необходимости создаем именованный канал.

sub take_lock {
  sysopen my $fh, $PIDFILE, O_RDWR | O_CREAT or die "$0: open $PIDFILE: $!";
  flock $fh => LOCK_EX                       or die "$0: flock $PIDFILE: $!";

  my $pid = <$fh>;

  if (defined $pid) {
    chomp $pid;

    if (kill 0 => $pid) {
      close $fh;
      return;
    }
  }
  else {
    die "$0: readline $PIDFILE: $!" if $!;
  }

  sysseek  $fh, 0, SEEK_SET or die "$0: sysseek $PIDFILE: $!";
  truncate $fh, 0           or die "$0: truncate $PIDFILE: $!";

  unless (-p $PIPE) {
    system("mknod", $PIPE, "p") == 0
                            or die "$0: mknod exited " . ($? >> 8);
  }

  $fh;
}

Наконец, чтение канала тривиально:

sub data {
  open my $fh, "<", $DATA or die "$0: open $DATA: $!";
  local $/;
  scalar <$fh>;
}

Не забудьте вернуть истинное значение из модуля:

1;

Вы заметите, что операции в демоне могут завершиться неудачно. Для вашего здравомыслия вы захотите как-то регистрировать события, а не молча задыхаться.

Что касается того, будут ли хосты разрешать длительные процессы, это зависит от поставщика к поставщику, но даже если ваш демон время от времени отключается, приведенный выше код перезапустит его по требованию.

Если вы абсолютно хотите, чтобы содержимое файлов присутствовало в памяти, гораздо более простым решением было бы создать RAM-диск и хранить их там. Тогда вам не придется делать ничего особенного с cgi-скриптами.

почему ты хочешь сделать это? Какую проблему ты пытаешься решить? Будет ли работать что-то вроде File::Map? Это файлы mmap, поэтому файлы не находятся в памяти, но ведут себя как есть. Я немного написал об этом в файлах карт памяти вместо того, чтобы глотать их.