Преобразование png в bmp (с сохранением прозрачности)

Сначала вам нужно включить темы выполнения (Менеджер проектов), иначе у вас не будет прозрачности ваших изображений.

И это код для загрузки изображения PNG в ваш ImageList1

bmp := TBitmap.Create;
try
  // everything done before to bmp has no effect
  bmp.Assign( png );
  // if for some reason the loaded image is smaller
  // set the size to avoid the invalid image size error
  bmp.Width := ImageList1.Width;
  bmp.Height := ImageList1.Height;

  AdvGlowBtn.Images:= ImageList1;
  ...
  // now add the Bitmap to the ImageList
  AdvGlowBtn.ImageIndex := ImageList1.Add( bmp, nil );
finally
  bmp.Free;
end;

У меня есть старый проект в Delphi 5, и я до сих пор иногда его использую. Это мое решение с использованием объекта png.

procedure ImageList2Alpha(const ImageList: TImageList);
const
  Mask: array[Boolean] of Longint = (0, ILC_MASK);
var
  TempList: TImageList;
begin
  if Assigned(ImageList) then
  begin
    TempList := TImageList.Create(nil);
    try
      TempList.Assign(ImageList);
      with ImageList do
      begin
        Handle := ImageList_Create(Width, Height, ILC_COLOR32 or Mask[Masked], 0, AllocBy);
        if not HandleAllocated then
          raise EInvalidOperation.Create(SInvalidImageList);
      end;
      Imagelist.AddImages(TempList);
    finally
      FreeAndNil(TempList);
    end;
  end;
end;

procedure LoadPngToBmp(var Dest: TBitmap; AFilename: TFilename);
type 
  TRGB32 = packed record 
    B, G, R, A : Byte;
  end; 
  PRGBArray32 = ^TRGBArray32; 
  TRGBArray32 = array[0..0] of TRGB32;
type
  TRG24 = packed record
    rgbtBlue, rgbtGreen, rgbtRed : Byte;
  end;
  PRGBArray24 = ^TPRGBArray24;
  TPRGBArray24 = array[0..0] of TRG24;
type
  TByteArray = Array[Word] of Byte;
  PByteArray = ^TByteArray;
  TPByteArray = array[0..0] of TByteArray;
var
  BMP : TBitmap;
  PNG: TPNGObject;
  x, y: Integer; 
  BmpRow: PRGBArray32;
  PngRow : PRGBArray24;
  AlphaRow: PByteArray;
begin

  Bmp := TBitmap.Create;
  PNG := TPNGObject.Create;

  try

    if AFilename <> '' then
    begin

      PNG.LoadFromFile(AFilename);
      BMP.PixelFormat := pf32bit;
      BMP.Height := PNG.Height;
      BMP.Width := PNG.Width;

      if ( PNG.TransparencyMode = ptmPartial ) then
      begin

        for Y := 0 to BMP.Height-1 do
        begin

          BmpRow := PRGBArray32(BMP.ScanLine[Y]);
          PngRow := PRGBArray24(PNG.ScanLine[Y]);
          AlphaRow := PByteArray(PNG.AlphaScanline[Y]);

          for X := 0 to BMP.Width - 1 do
          begin
            with BmpRow[X] do
            begin
              with PngRow[X] do
              begin
                R := rgbtRed; G := rgbtGreen; B := rgbtBlue;
              end;
              A := Byte(AlphaRow[X]);
            end;
          end;

        end;

      end else
      begin

        for Y := 0 to BMP.Height-1 do
        begin

          BmpRow := PRGBArray32(BMP.ScanLine[Y]);
          PngRow := PRGBArray24(PNG.ScanLine[Y]);

          for X := 0 to BMP.Width - 1 do
          begin
            with BmpRow[X] do
            begin
              with PngRow[X] do
              begin
                R := rgbtRed; G := rgbtGreen; B := rgbtBlue;
              end;
              A := 255;
            end;
          end;

        end;

      end;

      Dest.Assign(BMP);

    end;

  finally
    Bmp.Free;
    PNG.Free;
  end;
end;

Вызовите ImageList2Alpha(YourImageList) в OnCreate формы (FormCreate), и ImageList будет готов хранить ваши Bitmap32, сохраняя прозрачность.

Вызовите процедуру LoadPngToBmp, чтобы преобразовать PNG в Bitmap32, а затем сохраните его в своем ImageList.

Класс TBitmap использует собственные библиотеки Windows для управления растровыми изображениями. В зависимости от вашей версии Windows, базовые библиотеки операционной системы не поддерживают 32-битные BMP, несмотря на то, что файлы заголовков библиотек объявляют структуру BITMAPQUAD.

Для более новых версий Windows (наверное, Vista и выше) поле BITMAPQUAD.reserved используется для хранения альфа-канала. Для более старых версий это поле должно оставаться нулевым (0x00).

Если вы используете «последнюю» версию Windows, единственное возможное объяснение, которое я вижу, это то, что класс TBitmap не был обновлен для поддержки альфа-канала.

Использование класса TPNGImage не должно быть проблемой вместо его преобразования в BMP перед использованием, если только у вас нет особых потребностей.

Используйте это так:

ABitmap.SetSize(png.Width, png.Height);
png.AssignTo(ABitmap);