XSLT 1.0 не может переводить апостроф

Ваша первая проблема заключается в том, что кажется, что ваш контент был "двойным экранированием". Сущность для апострофа — ', а не '.

Ваша попытка заменить символы на translate() не дала результата. работу, потому что она работает не так, как вы ожидаете. Это не метод поиска/замены. Вы указываете список символов во втором аргументе, а затем соответствующий символ для перевода каждого из них в третий параметр. Если в списке символов третьего параметра нет соответствующего символа, то он будет удален.

Вам нужно будет использовать рекурсивный шаблон для выполнения замены символов.

Например:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:template match="/">
        <xsl:call-template name="replace-string">
            <xsl:with-param name="text" select="MyElement"/>
            <xsl:with-param name="replace" select="'&amp;apos;'"/>
            <xsl:with-param name="with" select='"&apos;"'/>
        </xsl:call-template>
    </xsl:template>

    <xsl:template name="replace-string">
        <xsl:param name="text"/>
        <xsl:param name="replace"/>
        <xsl:param name="with"/>
        <xsl:choose>
            <xsl:when test="contains($text,$replace)">
                <xsl:value-of select="substring-before($text,$replace)"/>
                <xsl:value-of select="$with"/>
                <xsl:call-template name="replace-string">
                    <xsl:with-param name="text"
                        select="substring-after($text,$replace)"/>
                    <xsl:with-param name="replace" select="$replace"/>
                    <xsl:with-param name="with" select="$with"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$text"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

Конечно, с XSLT 2.0 вы можете просто использовать replace()< /strong> функция:

<xsl:sequence select='replace(MyElement, "&amp;apos;", "&apos;")'/>