Как проверить наличие пустого массива в макросе vba

Когда вы имеете дело со строковым массивом, рассматривали ли вы возможность соединения?

If Len(Join(FileNamesList)) > 0 Then

Сделайте тройной минус:

If (Not Not FileNamesList) <> 0 Then
    ' Array has been initialized, so you're good to go.
Else
    ' Array has NOT been initialized
End If

Или просто:

If (Not FileNamesList) = -1 Then
    ' Array has NOT been initialized
Else
    ' Array has been initialized, so you're good to go.
End If

В VB по какой-либо причине Not myArray возвращает указатель SafeArray. Для неинициализированных массивов возвращается -1. Вы можете Not выполнить XOR с -1, возвращая ноль, если хотите.

               (Not myArray)   (Not Not myArray)
Uninitialized       -1                 0
Initialized    -someBigNumber   someOtherBigNumber

Источник

Если вы протестируете функцию массива, она будет работать для всех границ:

Function IsVarArrayEmpty(anArray As Variant)

Dim i As Integer

On Error Resume Next
    i = UBound(anArray,1)
If Err.number = 0 Then
    IsVarArrayEmpty = False
Else
    IsVarArrayEmpty = True
End If

End Function

Я вижу здесь похожие ответы ... но не мои ...

Вот как я, к сожалению, собираюсь с этим справиться ... Мне нравится подход len (join (arr))> 0, но он не сработал бы, если бы массив был массивом пустых строк ...

Public Function arrayLength(arr As Variant) As Long
  On Error GoTo handler

  Dim lngLower As Long
  Dim lngUpper As Long

  lngLower = LBound(arr)
  lngUpper = UBound(arr)

  arrayLength = (lngUpper - lngLower) + 1
  Exit Function

handler:
  arrayLength = 0 'error occured.  must be zero length
End Function

Когда я пишу VBA, у меня в голове возникает такая фраза: «Могло бы быть так просто, но ...»

Вот для чего я его адаптировал:

Private Function IsArrayEmpty(arr As Variant)
  ' This function returns true if array is empty
  Dim l As Long

  On Error Resume Next
  l = Len(Join(arr))
  If l = 0 Then
    IsArrayEmpty = True
  Else
    IsArrayEmpty = False
  End If

  If Err.Number > 0 Then
      IsArrayEmpty = True
  End If

  On Error GoTo 0
End Function

Private Sub IsArrayEmptyTest()
  Dim a As Variant
  a = Array()
  Debug.Print "Array is Empty is " & IsArrayEmpty(a)
  If IsArrayEmpty(a) = False Then
    Debug.Print "  " & Join(a)
  End If
End Sub

Этот код не делает того, что вы ожидаете:

If Dir(SigString) <> "" Then
    Signature = GetBoiler(SigString) 
Else
    Signature = "" 
End If

Если вы передадите пустую строку ("") или vbNullString в Dir, он вернет имя первого файла в текущем пути к каталогу (путь, возвращенный CurDir$). Итак, если SigString пусто, ваше If условие будет оцениваться как True, потому что Dir вернет непустую строку (имя первого файла в текущем каталоге), и будет вызываться GetBoiler. И если SigString пусто, вызов fso.GetFile завершится ошибкой.

Вам следует либо изменить свое условие, чтобы проверить, что SigString не пусто, либо использовать метод FileSystemObject.FileExists вместо Dir для проверки существования файла. Dir сложно использовать именно потому, что он делает то, чего от него нельзя ожидать. Лично я бы использовал Scripting.FileSystemObject вместо Dir, потому что здесь нет забавных дел (FileExists возвращает True, если файл существует, и, ну, False, если нет). Более того, FileExists гораздо яснее выражает намерение вашего кода, чем Dir.

Метод 1. Сначала убедитесь, что SigString не пусто

If SigString <> "" And Dir(SigString) <> "" Then
    Signature = GetBoiler(SigString) 
Else
    Signature = "" 
End If

Метод 2. Используйте метод FileSystemObject.FileExists

Dim fso As Object
Set fso = CreateObject("Scripting.FileSystemObject")

If fso.FileExists(SigString) Then
    Signature = GetBoiler(SigString) 
Else
    Signature = "" 
End If

Я просто вставляю ниже код великого Чипа Пирсона. Это прекрасно работает.
Вот его страница о функциях массивов.

Надеюсь, это поможет.

Public Function IsArrayEmpty(Arr As Variant) As Boolean
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' IsArrayEmpty
' This function tests whether the array is empty (unallocated). Returns TRUE or FALSE.
'
' The VBA IsArray function indicates whether a variable is an array, but it does not
' distinguish between allocated and unallocated arrays. It will return TRUE for both
' allocated and unallocated arrays. This function tests whether the array has actually
' been allocated.
'
' This function is really the reverse of IsArrayAllocated.
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

    Dim LB As Long
    Dim UB As Long

    err.Clear
    On Error Resume Next
    If IsArray(Arr) = False Then
        ' we weren't passed an array, return True
        IsArrayEmpty = True
    End If

    ' Attempt to get the UBound of the array. If the array is
    ' unallocated, an error will occur.
    UB = UBound(Arr, 1)
    If (err.Number <> 0) Then
        IsArrayEmpty = True
    Else
        ''''''''''''''''''''''''''''''''''''''''''
        ' On rare occasion, under circumstances I
        ' cannot reliably replicate, Err.Number
        ' will be 0 for an unallocated, empty array.
        ' On these occasions, LBound is 0 and
        ' UBound is -1.
        ' To accommodate the weird behavior, test to
        ' see if LB > UB. If so, the array is not
        ' allocated.
        ''''''''''''''''''''''''''''''''''''''''''
        err.Clear
        LB = LBound(Arr)
        If LB > UB Then
            IsArrayEmpty = True
        Else
            IsArrayEmpty = False
        End If
    End If

End Function

Auth был ближе всего, но его ответ выдает ошибку несоответствия типа.

Что касается других ответов, вам следует избегать использования ошибки для проверки условия, если вы можете, потому что, по крайней мере, это усложняет отладку (что, если что-то еще вызывает эту ошибку).

Вот простое и полное решение:

option explicit
Function foo() As Variant

    Dim bar() As String

    If (Not Not bar) Then
        ReDim Preserve bar(0 To UBound(bar) + 1)
    Else
        ReDim Preserve bar(0 To 0)
    End If

    bar(UBound(bar)) = "it works!"

    foo = bar

End Function

Упрощенная проверка пустого массива:

Dim exampleArray() As Variant 'Any Type

If ((Not Not exampleArray) = 0) Then
      'Array is Empty
Else
      'Array is Not Empty
End If

Вот еще один способ сделать это. Я использовал его в некоторых случаях, и он работает.

Function IsArrayEmpty(arr As Variant) As Boolean

Dim index As Integer

index = -1
    On Error Resume Next
        index = UBound(arr)
    On Error GoTo 0

If (index = -1) Then IsArrayEmpty = True Else IsArrayEmpty = False

End Function

На основе ответа ahuth;

Function AryLen(ary() As Variant, Optional idx_dim As Long = 1) As Long
    If (Not ary) = -1 Then
        AryLen = 0
    Else
        AryLen = UBound(ary, idx_dim) - LBound(ary, idx_dim) + 1
    End If
End Function

Проверить наличие пустого массива; is_empty = AryLen(some_array)=0

Вы можете использовать приведенную ниже функцию, чтобы проверить, пуст ли вариант или строковый массив в vba.

Function IsArrayAllocated(Arr As Variant) As Boolean
        On Error Resume Next
        IsArrayAllocated = IsArray(Arr) And _
                           Not IsError(LBound(Arr, 1)) And _
                           LBound(Arr, 1) <= UBound(Arr, 1)
End Function

Пример использования

Public Function test()
Dim Arr(1) As String
Arr(0) = "d"
Dim x As Boolean
x = IsArrayAllocated(Arr)
End Function

Другой способ - сделать это раньше. Вы можете создать логическую переменную и установить для нее значение true после загрузки данных в массив. поэтому все, что вам действительно нужно, это простой оператор if, когда вы загружаете данные в массив.

Чтобы проверить, пуст ли массив байтов, самый простой способ - использовать функцию VBA StrPtr().

Если массив байтов пуст, StrPtr() возвращает 0; в противном случае он возвращает ненулевое значение (однако это не адрес первого элемента).

Dim ar() As Byte
Debug.Assert StrPtr(ar) = 0

ReDim ar(0 to 3) As Byte
Debug.Assert StrPtr(ar) <> 0

Однако он работает только с байтовым массивом.

Function IsVarArrayEmpty(anArray As Variant) as boolean
    On Error Resume Next
    IsVarArrayEmpty = true
    IsVarArrayEmpty = UBound(anArray) < LBound(anArray)
End Function

Может ubound вылетает и остается истинным, а если ubound < lbound, то пусто

Я обобщу проблему и вопрос, как задумано. Проверить задание на массив и отловить возможную ошибку

Function IsVarArrayEmpty(anArray as Variant)
Dim aVar as Variant

IsVarArrayEmpty=False
On error resume next
aVar=anArray(1)
If Err.number then '...still, it might not start at this index
    aVar=anArray(0)
    If Err.number then IsVarArrayEmpty=True ' neither 0 or 1 yields good assignment
EndIF
End Function

Конечно, он пропускает массивы со всеми отрицательными индексами или всеми> 1 ... это вероятно? в странной стране, да.

Лично я думаю, что один из приведенных выше ответов можно изменить, чтобы проверить, есть ли в массиве содержимое:

if UBound(ar) > LBound(ar) Then

Это обрабатывает ссылки с отрицательными числами и занимает меньше времени, чем некоторые другие варианты.

Вы можете проверить, пуст ли массив, получив общее количество элементов с помощью объекта JScript VBArray() (работает с массивами вариантного типа, одномерного или многомерного):

Sub Test()

    Dim a() As Variant
    Dim b As Variant
    Dim c As Long

    ' Uninitialized array of variant
    ' MsgBox UBound(a) ' gives 'Subscript out of range' error
    MsgBox GetElementsCount(a) ' 0

    ' Variant containing an empty array
    b = Array()
    MsgBox GetElementsCount(b) ' 0

    ' Any other types, eg Long or not Variant type arrays
    MsgBox GetElementsCount(c) ' -1

End Sub

Function GetElementsCount(aSample) As Long

    Static oHtmlfile As Object ' instantiate once

    If oHtmlfile Is Nothing Then
        Set oHtmlfile = CreateObject("htmlfile")
        oHtmlfile.parentWindow.execScript ("function arrlength(arr) {try {return (new VBArray(arr)).toArray().length} catch(e) {return -1}}"), "jscript"
    End If
    GetElementsCount = oHtmlfile.parentWindow.arrlength(aSample)

End Function

Для меня это занимает около 0,3 мкс для каждого элемента + инициализация 15 мс, поэтому массив из 10M элементов занимает около 3 секунд. Те же функции могут быть реализованы с помощью ScriptControl ActiveX (он недоступен в 64-разрядных версиях MS Office, поэтому вы можете использовать обходной путь, например this < / а>).

Вы можете проверить его количество.

Здесь cid - это массив.

if (jsonObject("result")("cid").Count) = 0 them
MsgBox "Empty Array"

Надеюсь, это поможет. Хорошего дня!

Другое решение для проверки пустого массива

if UBound(ar) < LBound(ar) then msgbox "Your array is empty!"

Или, если вы уже знаете, что LBound равен 0

if -1 = UBound(ar) then msgbox "Your array is empty!"

Это может быть быстрее, чем join (). (А с отрицательными показателями не проверял)

Вот мой образец для фильтрации двух строковых массивов, чтобы они не использовали одни и те же строки.

' Filtering ar2 out of strings that exists in ar1

For i = 0 To UBound(ar1)

    ' filter out any ar2.string that exists in ar1
    ar2 = Filter(ar2 , ar1(i), False)    

    If UBound(ar2) < LBound(ar2) Then
       MsgBox "All strings are the same.", vbExclamation, "Operation ignored":
       Exit Sub

    End If

Next

' At this point, we know that ar2 is not empty and it is filtered 
'