Applescripting Reminder как действие добавления папки

Я новичок в applescript, но я хочу настроить действие папки, которое:

1. Recognises when a file is added to a folder
2. Tags said folder red
3. Adds a Reminder to the "Downloads" reminder list that has the name of the newly-added file as the body text of the reminder

Используя функцию записи Google и Applescript, я до сих пор писал это вместе.

property dialog_timeout : 30 -- set the amount of time before dialogs auto-answer.

on adding folder items to this_folder after receiving added_items



try
    tell application "Finder"
        set FILEname to name of (added_items)
        set label index of folder "untitled folder" of folder "Desktop" of folder "heyjeremyoates" of folder "Users" of startup disk to 2
    end tell

    tell application "Reminders"
        set mylist to list "Downloads"
        tell mylist
            make new reminder with properties {name:"D/L Complete", body:FILEname, due date:(current date)}
        end tell
    end tell
end try

end adding folder items to

Черт побери, не получится. Бесит. Я протестировал его как действие папки с «тестом» в качестве имени и тела напоминания, и оно сработало нормально. Я почти уверен, что где-то ошибся, установив FILEname в качестве имени вновь скопированного элемента, потому что скрипт в его нынешнем виде больше не окрашивает папку в красный цвет.

Идея этого заключается в том, чтобы я мог видеть с моего iPhone / iPad, сколько больших / запланированных загрузок на мой домашний Mac (как торренты, так и большие рабочие файлы - у меня будет отдельное действие папки и список напоминаний для каждой папки загрузки) есть те, которыми еще предстоит управлять.

Казалось, что настраивать комбинацию Growl/Prowl было расточительно, если iCloud/Reminders и дюжина строк кода все равно могли дать то, что я хотел. В идеале я напишу второй яблочный скрипт, который будет удалять напоминание, когда я переименовываю или перемещаю связанный файл, и хотя я даже не думал о том, как это будет работать, если у кого-нибудь есть какие-либо предложения по этому поводу, я был бы очень благодарен

Жаль, что вы не можете (изначально) отправлять уведомления OSX на устройство iOS, связанное с той же учетной записью iCloud (с соответствующей детализацией)

Но я отвлекся - может кто-нибудь увидеть, что я здесь напортачил?

Заранее спасибо даже за то, что дочитали до этого места


macos download finder applescript reminders
person user2853816    schedule 07.10.2013    source источник

Ответы (1)


arrow_upward
1
arrow_downward

added_items — это список псевдонимов, а name of (added_items) привело к ошибке.

on adding folder items to this_folder after receiving added_items
    tell application "Finder"
        set label index of this_folder to 2
        repeat with f in added_items
            set n to name of f
            tell application "Reminders" to tell list "Downloads"
                make new reminder with properties {name:"D/L Complete", body:n, due date:(current date)}
            end tell
        end repeat
    end tell
end adding folder items to

(Сохраните сценарий в ~/Library/Workflows/Applications/Folder Actions/ и включите действие с папкой в ​​настройках действий с папкой.)

person Lri    schedule 07.10.2013
comment
Спасибо за ответ, Лаури, в итоге я получил помощь по этой проблеме от DJ Bazzie Wazzie на форуме macscripter.net. Окончательный код — это сообщение № 6 по адресу macscripter.net/viewtopic.php?pid=167407#. p167407 но решение почти идентично вашему :D - person user2853816; 07.10.2013