Perl анализирует данные с несколькими символами-разделителями

Если ваши столбцы разделены несколькими пробелами, Text::CSV бесполезен. Ваш код содержит много повторяющегося кода, пытающегося обойти ограничения Text::CSV.

Кроме того, ваш код имеет плохой стиль, содержит множество синтаксических ошибок и опечаток, а также запутанные имена переменных.

Итак, вы хотите разобрать заголовок.

Нам нужно определение строки заголовка для нашего кода. Возьмем «первую строку комментария, содержащую не пробельные символы». Ему не могут предшествовать строки без комментариев.

use strict; use warnings; use autodie;

open my $fh, '<:encoding(UTF-8)', "filename.tsv";  # error handling by autodie

my @headers;
while (<$fh>) {
  # no need to copy to a $line variable, the $_ is just fine.
  chomp;                                     # remove line ending
  s/\A#\s*// or die "No header line found";  # remove comment char, or die
  /\S/ or next;                              # skip if there is nothing here
  @headers = split;                          # split the header names.
                                             # The `split` defaults to `split /\s+/, $_`
  last;                                      # break out of the loop: the header was found
}

Класс символов \s соответствует символам пробела (пробелы, табуляции, новые строки и т. д.). \S является инверсией и соответствует всем непробельным символам.

Остальные

Теперь у нас есть имена заголовков, и мы можем перейти к обычному разбору:

my @records;
while (<$fh>) {
  chomp;
  next if /\A#/;              # skip comments
  my @fields = split;
  my %hash;
  @hash{@headers} = @fields;  # use hash slice to assign fields to headers
  push @records, \%hash;      # add this hashref to our records
}

Вуаля.

Результат

Этот код создает следующую структуру данных из данных вашего примера:

@records = (
  {
    address => "0x1234fde0",
    name    => "test.data.one",
    scale   => 32768,
    type    => "float",
  },
  {
    address => "0x1234fde4",
    name    => "test.data.two",
    scale   => 32768,
    type    => "float",
  },
  {
    address => "0x1234fde8",
    name    => "test.data.the",
    scale   => 32768,
    type    => "float",
  },
  {
    address => "0x1234fdec",
    name    => "test.data.for",
    scale   => 32768,
    type    => "float",
  },
  {
    address => "0x1234fdf0",
    name    => "test.data.fiv",
    scale   => 32768,
    type    => "float",
  },
);

Эту структуру данных можно использовать как

for my $record (@records) {
  say $record->{name};
}

or

for my $i (0 .. $#records) {
  say "$i: $records[$i]{name}";
}

Критика вашего кода

• Вы объявляете все свои переменные в верхней части скрипта, фактически делая их глобальными переменными. Не надо. Создавайте свои переменные в наименьшей возможной области. В моем коде во внешней области видимости используются только три переменные: $fh, @headers и @records.

• Эта строка my $csv=Text::CSV({sep_char = ","}) не работает должным образом.

  • Text::CSV is not a function; it is the name of a module. You meant Text::CSV->new(...).
  • Параметры должны быть хэш-ссылкой, но sep_char = "," пытается назначить что-то для sep_char, к сожалению, это может быть правильный синтаксис. Но на самом деле вы хотели указать отношение ключ-значение. Вместо этого используйте оператор => (называемый толстая запятая или решетка).

• И это не работает: or die "Text::CSV error: " Text::CSV=error_diag.

  • To concatenate strings, use the . concatenation operator. What you wrote is a syntax error: A literal string is always followed by an operator.
  • Вы действительно любите задания? Text::CSV=error_diag не работает. Вы намеревались вызвать метод error_diag для класса Text::CSV. Поэтому используйте правильный оператор ->: Text::CSV->error_diag.

• Замена s/t+/,/g заменяет все последовательности t запятыми. Чтобы заменить вкладки, используйте класс символов \t.

• %arrayofhashes — это не массив хэшей: это хэш (о чем свидетельствует сигила %), но вы используете целые числа в качестве ключей. Массивы имеют сигил @.

• Чтобы добавить что-то в конец массива, я бы не стал хранить индекс последнего элемента в дополнительной переменной. Вместо этого используйте функцию push, чтобы добавить элемент в конец. Это уменьшает объем бухгалтерского кода.

• если вы обнаружите, что пишете цикл, подобный my $i = 0; while (condition) { do stuff; $i++}, то обычно вам нужен цикл for в стиле C:

  for (my $i = 0; condition; $i++) {
    do stuff;
  }
  

  Это также помогает с правильной областью видимости переменных.