Несколько интерфейсов, функция Supports() и подсчет ссылок

Общий совет — никогда не смешивайте ссылки на объекты со ссылками на интерфейсы. Это означает, что если вам нужно создать экземпляр класса и использовать любой из его интерфейсов, лучше не ссылаться на него через объектно-ссылочный тип. Вы нарушили этот совет, изменив свои переменные на тип TMyClass вместо типа интерфейса. Вместо этого объявите их как переменные интерфейса; Я бы использовал IUnknown.

Причина этого совета в том, что ссылки на объекты не обрабатываются так же, как ссылки на интерфейсы. Компилятор всегда вставляет код подсчета ссылок для переменных интерфейса, и этот код не обращает внимания на любые ссылки на объекты где-либо еще в вашей программе. Из-за подсчета ссылок переменная ссылки на объект может стать недействительной после изменения какой-либо переменной интерфейса, и это легко упустить из виду при написании программ. Если у вас никогда не было переменной ссылки на объект, вам не нужно беспокоиться об этой возможности; ссылка на интерфейс должна всегда быть действительной.

Если MyClass1 является ссылкой на объект, то вы не должны не вызывать для него Free после того, как вы присвоили его переменной интерфейса. Вот часть вашего кода, аннотированная счетчиком ссылок на объект:

MyClass1 := TMyClass.Create;  // initialized to 0

bSupports := Supports(MyClass1,IFirstInterface,i1); // incremented to 1
if bSupports then 
begin
    Memo1.Lines.Add('MyClass1 supports IFirstInterface');
    DoSomethingWith(i1);
end
else
    Memo1.Lines.Add('MyClass1 does not support IFirstInterface');

bSupports := Supports(MyClass1,ISecondInterface,i2); // incremented to 2
if bSupports then 
begin
    Memo1.Lines.Add('MyClass1 supports ISecondInterface');
    DoSomethingElseWith(i2);
end
else
    Memo1.Lines.Add('MyClass1 does not support ISecondInterface');

MyClass1 := nil; // still 2
i1 := nil; // decremented to 1
i2 := nil; // decremented to 0; the object gets destroyed

Если бы вы в любой момент вызвали MyClass1.Free, ваша программа рухнула бы. Самостоятельное освобождение объекта не изменит значения в i1 или i2, поэтому автоматически вставленный компилятором код подсчета ссылок все равно будет выполняться. Он попытается уменьшить количество ссылок на уже освобожденный объект, что явно нехорошо.

Но предположим, что вы дождались после очистки i1 и i2, как в этом коде:

i1 := nil;
i2 := nil;
MyClass1.Free;

Это все еще неправильно. Очистка переменных устанавливает счетчик ссылок на 0, поэтому объект уничтожается при присвоении i2; значение в MyClass1 недопустимо, поэтому вы также не должны вызывать Free для него.

Самое безопасное, что можно сделать после того, как вы присвоили ссылку на объект ссылке на интерфейс, — это немедленно очистить ссылку на объект. Тогда у вас не будет соблазна его использовать.

Обычно нет необходимости очищать переменную интерфейса. Он автоматически очищается в конце своего срока службы (что для локальных переменных происходит, когда они выходят за пределы области действия в конце функции). Кроме того, если вы вызовете Supports и передадите уже назначенную ссылку на интерфейс, он либо получит ссылку на интерфейс для нового объекта, либо будет очищен; он не будет продолжать удерживать свое предыдущее значение.

То есть, когда вы вызываете Supports(MyClass2,IFirstInterface,i1);, нет необходимости сначала очищать i1. Вызов Supports либо заполнит i1 ссылкой на IFirstInterface для объекта, на который ссылается MyClass2, либо сохранит nil в i1.

В принципе... Я согласен со всем, что все говорят о смешивании интерфейсной и объектной моделей, и не смешивайте их...

Это простой способ навлечь на себя неприятности и заниматься ночным отслеживанием странных GPF...

Но... (всегда есть но)...

Вы можете сделать это ... если вы понимаете Gotcha's ...

• Если вы создадите TInterfacedObject и передадите его в ссылку на переменную. Нужно ли вам освобождать его или нет, зависит от того, получите ли вы от него интерфейс.
• Как только вы получаете от него интерфейс... начинается подсчет ссылок... и вы больше не отвечаете за его освобождение. Это верно для любого объекта, происходящего от TInterfacedObject.
• «Как» увеличивает счетчик ссылок вашего интерфейса до тех пор, пока «как» находится в области действия. Это означает, что если у вас нет другой ссылки на интерфейс... ваш объект уходит до свидания, как только "как" выходит из области видимости.

Оформить заказ Button4Click и Button5Click...Button4Click делает это с помощью интерфейса...Button5Click делает это с помощью обоих.

  IReqBase = Interface(IInterface)
  ['{B71BD1C3-CE4C-438A-8090-DA6AACF0B3C4}']
    procedure FillWithTemplateData;
  end;

  IReqLogIn = Interface(IInterface)
  ['{133D2DFF-670C-4942-A81C-D18CBE825A93}']
    procedure SetupPassword(aUserName, aPassword: string);
  end;

  type
   TWebAct = (ttlogin,
              ttsignin);

  TForm59 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    CheckBox1: TCheckBox;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    Button5: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
procedure Button5Click(Sender: TObject);
  private
    { Private declarations }
    FReqList: Array of IReqBase;
    procedure CreateBaseList;
    procedure ClearBaseList;
  public
    { Public declarations }
  end;

  TJSONStructure = class(TInterfacedObject);

  TReqBaseClass = class of TReqBase;

  TReqBase = class(TJSONStructure, IReqBase)
  private
     token: Int64;
  protected
    class function ReqClass: TReqBaseClass; virtual; abstract;
  public
     Constructor Create; virtual;
     procedure FillWithTemplateData; virtual;
     class function ReqBase: IReqBase;
  end;

  TReqLogin = class(TReqBase, IReqLogIn)
  private
    Fusername,
    Fpassword: String;
    Fmodule  : Integer;
  protected
    class function ReqClass: TReqBaseClass; override;
  public
     Constructor Create; override;
     Destructor Destroy; override;
     procedure SetupPassword(aUserName, aPassword: string);
     procedure FillWithTemplateData; override;
  end;

  TReqSignIn = class(TReqBase)
  private
    Fusername,
    Fpassword: String;
    Fmodule  : Integer;
  protected
    class function ReqClass: TReqBaseClass; override;
  public
     Constructor Create; override;
     Destructor Destroy; override;
     procedure FillWithTemplateData; override;
  end;


var
  Form59: TForm59;

implementation

{$R *.dfm}

procedure TForm59.Button1Click(Sender: TObject);
begin
  Memo1.Lines.Clear;

  IReqBase(FReqList[integer(CheckBox1.Checked)]).FillWithTemplateData;
end;

procedure TForm59.Button2Click(Sender: TObject);
begin
  CreateBaseList;
end;

procedure TForm59.Button3Click(Sender: TObject);
begin
  if CheckBox1.Checked then
    TReqSignIn.ReqBase.FillWithTemplateData
  else
    TReqLogin.ReqBase.FillWithTemplateData;
end;

procedure TForm59.Button4Click(Sender: TObject);
var
  a_IReqBase1: IReqBase;
  a_IReqBase2: IReqBase;
  a_IReqLogIn: IReqLogIn;
begin
  a_IReqBase1 := TReqSignIn.Create;
  a_IReqBase2 := TReqLogin.Create;

  a_IReqLogIn :=  a_IReqBase2 as IReqLogIn;
  a_IReqLogIn.SetupPassword('houseofdexter', 'dexter');

  a_IReqBase1.FillWithTemplateData;
  a_IReqBase2.FillWithTemplateData;
  a_IReqLogIn :=  a_IReqBase2 as IReqLogIn;
  a_IReqLogIn.SetupPassword('houseofdexter', 'dexter');
end;

procedure TForm59.Button5Click(Sender: TObject);
var
  a_ReqBase1: TReqSignIn;
  a_ReqBase2: TReqLogin;
  a_IReqBase1: IReqBase;
  a_IReqBase2: IReqBase;
  a_IReqLogIn: IReqLogIn;
begin
  a_ReqBase1 := TReqSignIn.Create;
  a_ReqBase2 := TReqLogin.Create;

  a_IReqBase1 :=  a_ReqBase1;
  a_IReqBase2 :=  a_ReqBase2;

  a_IReqLogIn :=  a_IReqBase2 as IReqLogIn;
  //note we are working with the object...
  a_ReqBase2.SetupPassword('houseofdexter', 'dexter');

  a_IReqBase1.FillWithTemplateData;
  a_IReqBase2.FillWithTemplateData;
  a_IReqLogIn :=  a_IReqBase2 as IReqLogIn;
  a_IReqLogIn.SetupPassword('houseofdexter', 'dexter');
end;

procedure TForm59.ClearBaseList;
begin
  SetLength(FReqList, 0);
end;

procedure TForm59.CreateBaseList;
begin
  if High(FReqList) = Ord(High(TWebAct)) +1 then
    ClearBaseList;

  SetLength(FReqList, Ord(High(TWebAct)) + 1 );
  FReqList[ord(ttlogin)] := TReqLogin.ReqBase;
  FReqList[ord(ttsignin)] := TReqSignIn.ReqBase;
end;

procedure TForm59.FormCreate(Sender: TObject);
begin
  CreateBaseList;
end;

procedure TForm59.FormDestroy(Sender: TObject);
begin
  ClearBaseList;
end;

{ TReqLogin }

constructor TReqLogin.Create;
begin
  inherited;
  FUserName := 'Rick';
  FPassword := 'Test';
  Fmodule := 100;
end;


destructor TReqLogin.Destroy;
begin
  Form59.Memo1.Lines.Add('Destroyed: ' +ClassName);
  Form59.Memo1.Lines.Add('RefCount: ' + IntToStr(TInterfacedObject(Self).RefCount));
end;

procedure TReqLogin.FillWithTemplateData;
begin
  inherited;
  Form59.Memo1.Lines.Add(Fusername);
  Form59.Memo1.Lines.Add(FPassword);
  Form59.Memo1.Lines.Add(IntToStr(FModule));
end;

class function TReqLogin.ReqClass: TReqBaseClass;
begin
  Result := TReqLogin;
end;

procedure TReqLogin.SetupPassword(aUserName, aPassword: string);
begin
  Fusername := aUserName;
  Fpassword := aPassword;
end;

{ TReqBase }

constructor TReqBase.Create;
begin
  inherited;
  Form59.Memo1.Lines.Add('Created: ' +ClassName);
  Token := -1;
end;

procedure TReqBase.FillWithTemplateData;
begin
  Form59.Memo1.Lines.Add(Self.ClassName);
  Form59.Memo1.Lines.Add('RefCount: ' + IntToStr(TInterfacedObject(Self).RefCount));
  Form59.Memo1.Lines.Add(IntToStr(Token));
end;

class function TReqBase.ReqBase: IReqBase;
begin
  Result := ReqClass.Create;
end;

{ TReqSignIn }

constructor TReqSignIn.Create;
begin
  inherited;
  Form59.Memo1.Lines.Add('RefCount: ' + IntToStr(TInterfacedObject(Self).RefCount));
  FUserName := 'Peterson';
  FPassword := 'TestPW';
  Fmodule := 101;
end;

destructor TReqSignIn.Destroy;
begin
  Form59.Memo1.Lines.Add('Destroyed: ' +ClassName);
  Form59.Memo1.Lines.Add('RefCount: ' + IntToStr(TInterfacedObject(Self).RefCount));
  inherited;
end;

procedure TReqSignIn.FillWithTemplateData;
begin
  inherited;
  Form59.Memo1.Lines.Add(Fusername);
  Form59.Memo1.Lines.Add(FPassword);
  Form59.Memo1.Lines.Add(IntToStr(FModule));
end;

class function TReqSignIn.ReqClass: TReqBaseClass;
begin
  Result := TReqSignIn;
end;

end.