Как перечислить ключи и значения записи в AppleScript

Я знаю, что это старый Q, но теперь есть возможности получить доступ к ключам и значениям (10.9+). В версии 10.9 вам нужно использовать библиотеки сценариев для выполнения этого запуска, в версии 10.10 вы можете использовать код прямо в редакторе сценариев:

use framework "Foundation"
set testRecord to {a:"aaa", b:"bbb", c:"ccc"}

set objCDictionary to current application's NSDictionary's dictionaryWithDictionary:testRecord
set allKeys to objCDictionary's allKeys()

repeat with theKey in allKeys
    log theKey as text
    log (objCDictionary's valueForKey:theKey) as text
end repeat

Это не взлом или обходной путь. Он просто использует «новую» возможность доступа к Objective-C-Objects из AppleScript. Нашла этот вопрос во время поиска по другим темам и не удержалась от ответа ;-)

Обновление для обеспечения функциональности JSON: Конечно, мы можем углубиться в классы Foundation и использовать объект NSJSONSerialization:

use framework "Foundation"
set testRecord to {a:"aaa", b:"bbb", c:"ccc"}

set objCDictionary to current application's NSDictionary's dictionaryWithDictionary:testRecord

set {jsonDictionary, anError} to current application's NSJSONSerialization's dataWithJSONObject:objCDictionary options:(current application's NSJSONWritingPrettyPrinted) |error|:(reference)

if jsonDictionary is missing value then
    log "An error occured: " & anError as text
else
    log (current application's NSString's alloc()'s initWithData:jsonDictionary encoding:(current application's NSUTF8StringEncoding)) as text
end if

Веселись, Майкл / Гамбург

Если вы просто хотите перебрать значения записи, вы можете сделать что-то вроде этого:

tell application "iPhoto"
    repeat with value in (properties of album 1) as list
        log value
    end repeat
end tell

Но мне не очень понятно, чего вы на самом деле хотите добиться.

По сути, то, что сказали AtomicToothbrush и foo. Записи AppleScript больше похожи на структуры C с известным списком меток, чем на ассоциативный массив с произвольными ключами, и нет (приличного) языкового способа проанализировать метки записи. (И даже если бы они были, у вас все равно возникла бы проблема с их применением для получения значений.)

В большинстве случаев ответ будет «использовать вместо этого библиотеку ассоциативных массивов». Однако вас особенно интересуют метки из значения properties, а это значит, что нам нужен хак. Обычный — вызвать ошибку с помощью записи, а затем проанализировать сообщение об ошибке, что-то вроде этого:

set x to {a:1, b:2}
try
    myRecord as string
on error message e
    -- e will be the string “Can’t make {a:1, b:2} into type string”
end

Разбор этого, и особенно разбор этого с учетом неанглоязычных локалей, остается читателю в качестве упражнения.

Ответ ShooTerKo невероятно полезен для меня.

Я подниму еще одну возможность, я удивлен, что я не видел, чтобы кто-то еще упомянул. Мне приходится часто переключаться между AppleScript и JSON в своих сценариях, и если вы можете установить программное обеспечение на компьютеры, на которых должен выполняться сценарий, то я настоятельно рекомендую JSONHelper, чтобы в основном решить всю проблему:

https://github.com/isair/JSONHelper