Почему весь мой пакетный сценарий работает как команда SETLOCAL?

Если ваш скрипт НЕ запускается командой @ECHO OFF, то вы увидите на экране полное содержимое скрипта, когда он запустится.

Я хочу использовать этот пост с пользой, поэтому я изменил ваш скрипт, чтобы сделать создание файла temp.vbs намного чище, хотя этот момент не имеет прямого отношения к вашей проблеме. Однако, когда я протестировал приведенный ниже пакетный файл с командой GOTO :EOF, вставленной после создания файла temp.vbs, он работает правильно, без ошибки «setlocal»!

EDIT: я понял, что исходный скрипт использует переменную loggedinuser для жесткого кодирования ее значения при создании программы temp.vbs, по этой причине файл создается и удаляется каждый раз. Мой оригинальный перевод не учитывает эту деталь.

Я изменил приведенный ниже пакетный файл, чтобы передать значение loggedinuser из пакета в раздел VBS в параметре. Таким образом, программа .vbs может быть создана только один раз с более подходящим именем.

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
REM Obtain username of logged in user
SET loggedinuser=%USERNAME%

REM Create temporary vbscript to obtain user OU, if not exists
if not exist getUserOU.vbs (
   for /F "delims=:" %%a in ('findstr /N "^:VBS_Section" "%~F0"') do set n=%%a
   more +!n! < "%~F0" > getUserOU.vbs
)

REM Save backup of old printer list, just in case
echo Creating a backup list of current printers, please wait...
wmic printer list brief /format:csv > 

\\networkshare\userfiles\!loggedinuser!\oldprinterlist.txt
echo Backup list completed.

REM Set the OU variable by running the vbscript
echo Discovering your department...
FOR /F "delims=" %%a in ('cscript.exe //nologo getUserOU.vbs "%loggedinuser%"') do @set OU=%%a
echo Adding printers for %OU%

REM Perform new printer install based on OU
if %OU%==MIS (
set printer1=Printer_1_Yo
set printer2=Printer_2_Yo
set printer3=Printer_3_Yo
echo Adding %printer1%, please wait...
wmic printer call addprinterconnection \\newprintserver\%printer1%
echo %printer1% added. Adding %printer2%, please wait...
wmic printer call addprinterconnection \\newprintserver\%printer2%
echo %printer2% added. Adding %printer3%, please wait...
wmic printer call addprinterconnection \\newprintserver\%printer3%
echo %printer3% added. All printers are ready to use!
)

REM Delete printers that were on job
echo Deleting old printers from testserver, please wait...
wmic printer where servername=\\\\testserver delete
echo Deletion complete.
echo. If you would like to add more printers, please visit the Printers page on the intranet.
echo. Press any key to close this window.
pause>temp.txt
del temp.txt

goto :EOF

:VBS_Section

Const ADS_SCOPE_SUBTREE = 2

Set objConnection = CreateObject("ADODB.Connection")
Set objCommand =   CreateObject("ADODB.Command")
objConnection.Provider = "ADsDSOObject"
objConnection.Open "Active Directory Provider"
Set objCommand.ActiveConnection = objConnection

objCommand.Properties("Page Size") = 1000
objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE

objCommand.CommandText = _
   "SELECT distinguishedName FROM 'LDAP://dc=test,dc=com' " & _
       "WHERE objectCategory='user' " & _
           "AND sAMAccountName='" & WScript.Arguments(0) & "'"
Set objRecordSet = objCommand.Execute

objRecordSet.MoveFirst
Do Until objRecordSet.EOF
    strDN = objRecordSet.Fields("distinguishedName").Value
    arrPath = Split(strDN, ",")
   intLength = Len(arrPath(1))
   intNameLength = intLength - 3
   Wscript.Echo Right(arrPath(1), intNameLength)
   objRecordSet.MoveNext
Loop

Для вашей команды принтера wmic используйте:

wmic printer where 'servername="\\\\testserver"'

Если это не сработает, поменяйте местами одинарные и двойные кавычки. Я не за компьютерным банкоматом, поэтому пишу по памяти. Кроме того, вам не нужно проделывать весь процесс создания vbscript, чтобы получить файл ou. Wmic может запрашивать ldap.

 WMIC /NAMESPACE:\\root\directory\ldap PATH ds_user  GET ds_distinguishedname

Вот моя версия вашего скрипта.

@echo off
setlocal enabledelayedexpansion

set q=wmic /NAMESPACE:\\root\directory\ldap PATH ds_user Where "ds_samaccountname^='!username!'" get ds_distinguishedname

for /f "skip=1 tokens=3 delims==" %%a in ('%q%') do (
   for /f "tokens=1 delims=," %%b in ("%%a") do set ou=%%b
)

:: Save backup of old printer list, just in case
set share=\\networkshare\userfiles
if not exist "%share%\!username!" md "%share%\!username!"
set printlist="%share%\!username!\oldprinterlist.txt"
echo Creating a backup list of current printers, please wait...
wmic printer list brief /format:csv > %printlist%
echo Backup list completed.

::Perform new printer install based on OU
IF %ou%==MIS (
  call :addprinter Printer_1_Yo Testserver
  call :addprinter Printer_2_Yo Testserver
  call :addprinter Printer_3_Yo Testserver
)

::Delete printers that were on job
echo.
echo Deleting old printers from testserver, please wait...
wmic printer where "servername='\\\\testserver'" delete
echo Deletion complete.
echo.
echo. If you would like to add more printers, please visit the Printers page on the intranet.
echo. Press any key to close this window.
pause>nul  
goto :eof

:addprinter prn server
echo.
echo Adding %1, please wait...
wmic printer call addprinterconnection \\%2\%1