Как создать и написать файл XML?

Если вы просто хотите писать XML (а не создавать revXMLTree), вы можете написать свои собственные функции. Как насчет этого для начала:

local _tags
local _xml
local _level
local _tabs

function q pText
   return quote & pText & quote
end q

on startXML
   put "<?xml version=" & q("1.0") & "?>" & return into _xml
   put 0 into _level
   put empty into _tabs
   put empty into _tags
end startXML

on startTag pTag
   put _tabs & "<" & pTag & ">" & return after _xml
   add 1 to _level
   put pTag into _tags[_level]
   put tab after _tabs  
end startTag

on closeTag
   delete char 1 of _tabs
   put _tabs & "</" & _tags[_level] & ">" & return after _xml
   # Do a 'delete variable _tags[_level]' if you really want to clean the array as you go 
   subtract 1 from _level
end closeTag

on addAttribute pAttribute, pValue
   # This should go into the last tag, but as we have "proper XML" so far we can backtrace two chars (">" and newline)
   put space & pAttribute & "=" & q(pValue) before char -2 of _xml
end addAttribute

on writeContent pContent
   put _tabs & pContent & return after _xml
end writeContent

on writeNode pNode, pValue
   put _tabs & "<" & pNode & ">" & pValue & "</" & pNode & ">" & return after _xml
end writeNode

getProp xml
   return _xml
end xml

Поместите этот скрипт на карту или стек, после чего вы можете сделать:

startXML
startTag "employeetable"
startTag "employee"
addAttribute "IDNum", 1
startTag "firstName"
writeContent "Steve"
closeTag
writeNode "lastName", "Jobs"
writeNode "roomnum", "001"
writeNode "phoneExt", "345"
writeNode "parkingSlot", "100"
closeTag
closeTag
put the xml of this card into field 1

Это, конечно, не полное решение, так как оно не будет проверять ваш ввод, и формат может быть не совсем тем, что вы хотите, но я думаю, что это может помочь вам начать работу.

Библиотека управления версиями Марка Видера (общественное достояние) содержит некоторые процедуры записи XML, которые можно было бы рассмотреть.

http://revonline2.runrev.com/stack/686/libVersionControl

--> xml

/** ------------------------------
* XML.StartTag
*
* Return <tag>
* Convert embedded commas and spaces as part of the process.
* ------------------------------
*/
private function XML.StartTag pTag
    if comma is in pTag then
        replace comma with kMagicComma in pTag
    end if
    if "&" is in pTag then
        replace "&" with kAmpersand in pTag
    end if
    if space is in pTag and "=" is not in pTag then
        replace space with kMagicSpace in pTag
    end if
    return "<" & pTag & ">"
end XML.StartTag

/** ------------------------------
* XML.EndTag
*
* Return </tag>
* Convert embedded commas and spaces as part of the process.
*
* @pTag : the tag of interest
* ------------------------------
*/
private function XML.EndTag pTag
   if comma is in pTag then
      replace comma with kMagicComma in pTag
   end if
   if space is in pTag and "=" is not in pTag then
      replace space with kMagicSpace in pTag
   end if
   return "</" & pTag & ">" & cr
end XML.EndTag

/** ------------------------------
* XML.Element
*
* return <tag>value</tab>
* base64encode the value item if necessary
* ------------------------------
*/
private function XML.Element pTag, pValue
    local tIsBinary
    local tTest

    put false into tIsBinary
    if pTag is in "htmlText, script, imagedata" then
        put true into tIsBinary
    else
        repeat for each byte tByte in pValue
            put chartonum(tByte) into tTest
            -- see if the char is printable
            if tTest < 32 or tTest > 128 then
                put true into tIsBinary
                -- no need to look further
                exit repeat
            end if
        end repeat
    end if
    -- can't have binary data in xml
    if tIsBinary then
        put "base64decode(" && q(base64encode(pValue)) && ")" into pValue
    end if
    return XML.StartTag(pTag) & pValue & XML.EndTag(pTag)
end XML.Element

--> Utilities

function q pText
    return quote & pText & quote
end q

Документация LiveCode (словарь) содержит множество функций, связанных с XML. Этих функций достаточно для навигации по любому XML-дереву и управления им. Однако внешний XML не очень хорошо обрабатывает индексы, а это значит, что вам нужно следить за ними самостоятельно. Например. вы можете прокручивать XML-дерево, используя их порядковый номер, проверять идентификационный номер каждого узла дерева и использовать узел с правильным идентификационным номером. Дайте мне знать, если вам нужен пример.

Во всем остальном понять, как работает библиотека, так же сложно, как понять сами функции XML. Просто прочитайте встроенную документацию.

Похоже, он не будет работать с текстом UTF8 (символы с диакритическими знаками, такими как ąęćś) в качестве значений узлов.