AS3 Как добавить Класс на сцену из таймера?

Ваш код перевернут в нескольких местах. Это не очень приятно, и проблемы, которые у вас есть сейчас, будут десятикратно возрастать на каком-то этапе вашего проекта.

Во-первых, ваш класс MyTimer не должен расширять Sprite. Он не визуализируется и ничего не представляет графически.

Во-вторых, ваш класс таймера берет на себя больше, чем должен. Я бы пересмотрел его, чтобы управлять только вашими таймерами и событиями таймера. Создайте список в своем классе таймера, который будет содержать некоторые другие элементы, которые могут иметь триггеры метода для выполнения других действий, таких как создание и добавление Thief1_mc.

Упрощенная версия этого может выглядеть так:

public class Updater
{

    private var _timer:Timer;
    private var _toUpdate:Vector.<IUpdatable> = new Vector.<IUpdatable>();


    public function Updater()
    {
        _timer = new Timer(60);
        _timer.start();
        _timer.addEventListener(TimerEvent.TIMER, _notifyUpdatables);
    }


    private function _notifyUpdatables(e:TimerEvent):void
    {
        for each(var i:IUpdatable in _toUpdate)
        {
            i.update(this);
        }
    }


    public function addUpdatable(updatable:IUpdatable):void
    {
        _toUpdate.push(updatable);
    }


    public function removeUpdatable(updatable:IUpdatable):void
    {
        var index:int = _toUpdate.indexOf(updatable);
        if(index >= 0) _toUpdate.splice(index, 1);
    }

}

Отсюда нам нужно создать интерфейс, который мы реализуем для классов, которые мы хотим иметь возможность вызывать update() каждый раз, когда тикает таймер Updater:

public interface IUpdatable
{
    function update(updater:Updater):void;
}

Теперь, что я бы сделал в вашем случае, это класс, который расширяет Sprite и управляет графикой приложения/игры. Он будет реализовывать интерфейс IUpdatable, как я описал, а также может иметь дело с добавлением вашего Thief1_mc:

public class View extends Sprite implements IUpdatable
{

    public function update(updater:Updater):void
    {
        // Create a Thief.
        var thief:Thief = new Thief();

        updater.addUpdatable(thief);
        addChild(thief);
    }

}

Ваш Thief может использовать интерфейс IUpdatable, который у нас есть, и быть добавленным в очередь обновлений при его создании, как я сделал выше. Просто чтобы иметь полный пример, вот класс Thief:

public class Thief extends Sprite implements IUpdatable
{

    public function update(updater:Updater):void
    {
        // Make this Thief so some stuff.
        //
    }

}

И вот как вы можете связать все это вместе в своем классе документа:

public class App extends Sprite
{

    private var _updater:Updater;
    private var _view:View;


    public function App()
    {
        _updater = new Updater();
        _view = new View();

        _updater.addUpdatable(_view);

        stage.addChild(_view);
    }

}

Поначалу это может показаться немного ошеломляющим, и вам может показаться, что это большая работа, но теперь у вас есть хорошая чистая основа для легкого добавления дополнительных элементов.

Вместо того, чтобы ваш один класс пытался управлять таймерами и добавлять воров, как это было изначально, мы разделили обязанности и немного упростили процесс. Updater имеет дело исключительно с хранением IUpdatable экземпляров и вызовом их метода update() каждый раз, когда Timer в нем тикает. Класс View управляет графикой, а также добавляет Thief каждый раз, когда он обновляется через класс Updater. View был добавлен на сцену изначально, поэтому все, что вам нужно сделать, это добавить воров в себя, чтобы они появились.

Если вы возьмете это и реструктурируете работу таймеров в Updater, я думаю, вы окажетесь там, где хотели, но со значительно лучшим пониманием и структурой.