Как я могу сделать целочисленное деление в Perl ИЛИ Как заставить работать мой двоичный поиск?

Вы должны использовать функцию int.

Кроме того, вам нужно use strict; и использовать my для определения области ваших переменных. Это позволит выявить ошибки, которые вы можете пропустить. Просто объявите их так:

my @array = (1..100);
chomp(my $number = <STDIN>);
my $low = 0;
my $high = $#array;

my $mid = int ($low + ($high - $low)/2);

Вы также можете рассмотреть возможность использования chomp, чтобы удалить символы новой строки из ввода.

my $int = int 5 / 2;
print $int;

Отпечатки 2.

Два эзотерических решения. На самом деле не используйте их, если вам действительно не скучно или что-то в этом роде.

1. use integer - прагма, которая заставляет Perl обрабатывать все ваши числовые значения как целые числа. Его можно ограничить локально, чтобы не испортить все данные в вашей программе.

   while($low < $high){
       print "Searcing $low ---- $high \n";
       {
           use integer;
           $mid = $low + ($high - $low)/2;
       }
       if($array[$mid] == $number){
           print "Found in index:" . $mid;
           last;
       }
       elsif($array[$mid] < $number){
           $low = $mid + 1;
       }
       else{
           $high = $mid - 1;
       }   
   }
   

2. Perl имеет несколько специальных переменных $=, _ 4_ и $%, которые будут содержать только целые значения, независимо от того, что вы им присваиваете. Используйте их напрямую

   $- = $low + ($high - $low) / 2;
   if ($array[$-] == $number) { ...
   

   или как промежуточные звенья

   my $mid = $- = $low + ($high - $low) / 2;
   if ($array[$mid] == $number) { ...
   

   Использование таких магических переменных удобно для кодового гольфа и раздражает ваших коллег, но не более того.

Используйте старый добрый >> 1 вместо /2.

Пример:

perl -e 'BEGIN { print 5/2, " : ", 5>>1}'

Вывод:

2.5 : 2

И используйте (оставьте вычитание):

my $mid = ($low + $high) >> 1;

С вашим кодом довольно много проблем.

• Вы отключили strict.

  Предположительно из-за очередной проблемы.

• Вы не объявили ни одну из своих переменных с помощью _1 _ или our или даже _ 3_.

  our @array = 1..100;
  use vars qw'$mid $low $high';
  my $number = <STDIN>
  

• Вы слишком беспокоитесь о переполнении. Это не C.

  Если ваше число будет переполнять целое число, оно просто превратится в число с плавающей запятой.

  my $mid = $low + ($high - $low)/2;
  

  Вероятно, просто должно быть:

  my $mid = ($high + $low)/2;
  

• Вы ожидали целого числа от деления.

  my $mid = ($high + $low)/2;
  

  Если вам действительно нужно целое число, просто используйте int.

  my $mid = int( ($high + $low)/2 );
  

• Вы не удалили новую строку с конца $number

  chomp($number);
  

• У вас вылет на одну ошибку.

  while($low < $high){
  

  Действительно должно быть

  while($low <= $high){
  

  Это действительно твоя главная проблема.

#! /usr/bin/env perl
use strict;
use warnings;

my @array = 1..100;
my $number = <STDIN>;
chomp $number;
my $low = 0;
my $high = $#array;

while($low <= $high){
    my $mid = int( ($high + $low)/2 );
    printf "Searching %2d .. (%2d) .. %2d\n", $low, $mid, $high;
    if($array[$mid] == $number){
        print "Found $number at index mid $mid\n";
        last;
    }elsif($array[$mid] < $number){
        $low = $mid + 1;
    }else{
        $high = $mid - 1;
    }
}

Хотя это не совсем Perlish.

#!/usr/bin/perl
use strict;
use warnings;
use List::MoreUtils qw'first_index';

my @array = 1..100;
my $number = <STDIN>;
chomp $number;

my $index = first_index { $_ == $number } @array;
print "Found $number at index ", $index if $index != -1;

Или более причудливо

#! /usr/bin/env perl
use strict;
use warnings;

my @array = 1..100;
my $number = <STDIN>;
chomp $number;

my $char = join '', map chr, @array;

my $index = index $char, chr $number;
print "Found $number at index $index\n" if $index != -1;

Это работает с числами вплоть до UV max или (2 ** 72) - 1.
Это 18 446 744 073 709 551 615 для 64-битных сборок и 4 294 967 295 для 32-битных сборок.

Прежде всего,

my $mid = $low + ($high - $low)/2

можно упростить до

my $mid = ($high + $low)/2;

Вы можете получить неотъемлемую часть, используя int

my $mid = int( ($high + $low)/2 );

Или вы можете воспользоваться тем фактом, что битовый сдвиг - это целочисленное деление на 2.

my $mid = ($high + $low) >> 1;

См. Также: Гибкая функция двоичного поиска