Как узнать количество записей, к которым обратилась программа в Progress-4GL?

Я пытаюсь узнать, к скольким записям работает запущенная программа. Я нашел VST _TableStat, но он не группирует количество записей по программе.

FOR  EACH _TableStat NO-LOCK
    WHERE _TableStat._TableStat-Create > 0
       OR _TableStat._TableStat-Delete > 0
       OR _TableStat._TableStat-Read   > 0
       OR _TableStat._TableStat-Update > 0,
    FIRST _File NO-LOCK
    WHERE _File._File-Number = _TableStat._TableStat-Id:

    DISPLAY
      /*_File._File-Name*/
        _TableStat-Create
        _TableStat._TableStat-Delete
        _TableStat._TableStat-Read  
        _TableStat._TableStat-Update
        WITH SIDE-LABELS 1 COLUMN 1 DOWN.
END.

Этот код показывает мне таблицы и количество доступных записей, но я хочу знать, какая программа обращается к таблице.

Есть ли способ узнать это? Или есть таблица типа _TableStat с PID или что-то в этом роде?

Ps .: Пользуюсь Progress 10.2B.

Заранее спасибо, Рубиньо Сантос


openedge progress-4gl progress-db
person rubinho.santos    schedule 28.03.2013    source источник
comment
Тот, кто проголосовал против этого, - идиот - этот вопрос жизненно важен при настройке производительности. У Тома Баскома есть инструмент, который отлично справляется с этой задачей, и я уверен, что он скоро отправит комментарий.   -  person Tim Kuehn    schedule 28.03.2013

Ответы (3)


arrow_upward
3
arrow_downward

Какая версия Прогресса?

Где-то около 10.1C был представлен _UserTableStat. Имеется таблица статистики по пользователям.

В _connect VST также есть поля "кеша клиентских операторов". Если для сеанса включены соответствующие биты, трассировка стека сохраняется, чтобы вы могли определить, какая строка выполняется в сеансе и как он туда попал.

Вместе они могут позволить вам получить то, что вам нужно.

Кстати: ProTop показывает большую часть этих данных - http://dbappraise.com/protop.html

Вы также можете захотеть взглянуть на некоторые функции «типов записей журнала», такие как 4gltrace и QryInfo, если вам нужна детализированная программа по статистике программы.

person Tom Bascom    schedule 28.03.2013

arrow_upward
1
arrow_downward

Он работает с таблицей _UserTableStat, как я и ожидал:

FOR EACH _UserTableStat NO-LOCK
   WHERE _UserTableStat._UserTableStat-Read   > 0
      OR _UserTableStat._UserTableStat-Create > 0
      OR _UserTableStat._UserTableStat-Update > 0
      OR _UserTableStat._UserTableStat-Delete > 0,
   FIRST _File NO-LOCK
   WHERE _File._File-Number = _UserTableStat._UserTableStat-Num,
   FIRST _Connect NO-LOCK
   WHERE _Connect._Connect-Id = _UserTableStat._UserTableStat-Conn:

    DISPLAY
        _Connect._Connect-IPAddress          
        _Connect._Connect-Name               
        _Connect._Connect-Pid                
        _File._File-Name                     
        _UserTableStat._UserTableStat-Read   
        _UserTableStat._UserTableStat-Create 
        _UserTableStat._UserTableStat-Update 
        _UserTableStat._UserTableStat-Delete 
    WITH SIDE-LABELS THREE-D 1 COLUMN 1 DOWN.

END.

Спасибо Тому Баскому за помощь!

person rubinho.santos    schedule 02.04.2013

arrow_upward
0
arrow_downward

В приведенном выше коде возникла проблема с этим соединением между _connect и _UserTableStat:

WHERE _Connect._Connect-Id = _UserTableStat._UserTableStat-Conn

Вместо этого вы должны использовать это:

WHERE _Connect._Connect-Usr = _UserTableStat._UserTableStat-Conn
  hint: _Connect-Usr = _Connect-Id + 1

Затем следующий фрагмент кода дает список, отсортированный по _UserTableStat-read по убыванию:

DEFAULT-WINDOW:WIDTH-CHARS = 240.

DEFINE VARIABLE dmon           AS DATETIME NO-UNDO.
DEFINE VARIABLE dstart         AS DATETIME NO-UNDO.
DEFINE VARIABLE iusertablestat AS INTEGER  NO-UNDO.
DEFINE VARIABLE lfirstview     AS LOGICAL  INITIAL TRUE NO-UNDO.

DEFINE TEMP-TABLE ttuts LIKE _UserTableStat
    FIELD _Connect-Type       AS CHARACTER INITIAL ?
    FIELD _Connect-Name       AS CHARACTER INITIAL ? FORMAT "X(15)"
    FIELD _Connect-Time       AS CHARACTER INITIAL ? FORMAT "X(25)"
    FIELD _Connect-ClientType AS CHARACTER INITIAL ?
    INDEX _UserTableStat-read   _UserTableStat-read
    INDEX _UserTableStat-update _UserTableStat-update
    INDEX _UserTableStat-create _UserTableStat-create
    INDEX _UserTableStat-delete _UserTableStat-delete.
    
dstart = NOW.
dmon = NOW.
DEFAULT-WINDOW:TITLE = SUBSTITUTE("starting scan of _UserTableStat at &1", dstart).
FOR EACH _UserTableStat NO-LOCK: 
    iusertablestat = iusertablestat + 1.

    IF     iusertablestat MODULO 10000 = 0 
        OR INTERVAL(NOW, dmon, "milliseconds") > 1000 THEN
    DO:
        dmon = NOW.
        IF lfirstview THEN
        DO:
            DISPLAY "scanning in process" WITH FRAME fviewit.
            lfirstview = FALSE.
        END.
        DEFAULT-WINDOW:TITLE = SUBSTITUTE("&1 - Scanning since &2 ms - &3 _UserTableStat records (started at &4)"
            , NOW, INTERVAL(NOW, dstart, "milliseconds"), iusertablestat, dstart).
         
        DEFAULT-WINDOW:TITLE = SUBSTITUTE("starting scan of _UserTableStat at &1  scanned &2 records", dstart, iusertablestat).
        PROCESS EVENTS.
    END.

    /* if you are interested in updates or delte, then adapath this next line */
    IF _UserTableStat._UserTableStat-read = 0 
        THEN NEXT.
    
    IF _UserTableStat._UserTableStat-Conn <> ?
        THEN FIND _Connect NO-LOCK WHERE _Connect._Connect-Usr = _UserTableStat._UserTableStat-Conn NO-ERROR. /* beware: you may use _UserTableStat-id + 1 too but do not miss the + 1*/
    ELSE RELEASE _Connect.
    
    CREATE ttuts.
    BUFFER-COPY _UserTableStat TO ttuts.
    IF AVAIL _Connect
        THEN BUFFER-COPY _Connect TO ttuts.
END.


DEFAULT-WINDOW:TITLE = SUBSTITUTE("&1 - Scan completed in &2 ms through &3 _UserTableStat records (started at &4)"
    , NOW, INTERVAL(NOW, dstart, "milliseconds"), iusertablestat, dstart).

FOR EACH ttuts 
    , FIRST _File NO-LOCK WHERE _File._File-Number = ttuts._UserTableStat-Num
    BY ttuts._UserTableStat-read DESCENDING: 
    DISPLAY 
        ttuts._UserTableStat-Num
        _File._File-Name
        ttuts._Connect-Name 
        ttuts._UserTableStat-Conn  /* = _Connect._Connect-Usr */
        ttuts._Connect-Type  
        ttuts._Connect-Time  
        ttuts._Connect-ClientType 
        ttuts._UserTableStat-read   FORMAT ">>>,>>>,>>>,>>>,>>9"
        ttuts._UserTableStat-update FORMAT ">>>,>>>,>>>,>>>,>>9"
        ttuts._UserTableStat-create FORMAT ">>>,>>>,>>>,>>>,>>9"
        ttuts._UserTableStat-delete FORMAT ">>>,>>>,>>>,>>>,>>9"
        WITH WIDTH 240 FRAME fttuts 17 DOWN.
END.
person Sébastien Lacroix    schedule 16.09.2020