Каков Perl-эквивалент MAX_INT?

В общем случае вы можете использовать undef для обозначения несуществующего значения; Скаляры perl не ограничиваются хранением только целых чисел. Было бы написано:

my $min; # undef by default
for my $value (@array) {
  $min = $value if !defined $min or $value < $min;
}

Но есть и более простые варианты. Например, инициализируйте $min первым значением в массиве, а затем сравните с остальными:

my $min = $array[0];
for my $i (1 .. $#array) {
  $min = $array[$i] if $array[$i] < $min;
}

Или просто используйте встроенную функцию:

use List::Util 'min';
my $min = min @array;

Чтобы ответить вам на вопрос, который вы на самом деле задали (хотя это на самом деле вам не нужно):

1. Наибольшее целочисленное значение, которое может быть сохранено как целое число со знаком.

   say ~0 >> 1;
   

2. Наибольшее целочисленное значение, которое может быть сохранено как целое число без знака.

   say ~0;
   

3. Все целые значения от 0 до этого числа могут быть сохранены без потерь как число с плавающей запятой.

   use Config qw( %Config );
   say eval($Config{nv_overflows_integers_at});
   

   Обратите внимание, что некоторые большие целые числа могут быть сохранены без потерь в числе с плавающей запятой, но не в том, что на 1 больше, чем это.

9**9**9 работает. То же самое делает 0+'inf' на многих версиях/платформах perl.

Perl — это не C; если вы попытаетесь вычислить слишком большое целое число, вместо этого вы получите результат с плавающей запятой (если вы не используете use bigint, что делает целые числа неограниченными). Кроме того, вы получаете inf.

Вы можете увидеть это с помощью Devel::Peek, который показывает вам внутреннее представление значения в Perl:

$ perl -E 'use Devel::Peek; Dump(1000); Dump(1000**100); Dump(1000**100 + 1)'
SV = IV(0xcdf290) at 0xcdf2a0
  REFCNT = 1
  FLAGS = (PADTMP,IOK,READONLY,pIOK)
  IV = 1000
SV = NV(0xd04f20) at 0xcdf258
  REFCNT = 1
  FLAGS = (PADTMP,NOK,READONLY,pNOK)
  NV = 1e+300
SV = NV(0xd04f18) at 0xcdf228
  REFCNT = 1
  FLAGS = (PADTMP,NOK,READONLY,pNOK)
  NV = 1e+300

IV указывает целочисленное значение; NV указывает значение с плавающей запятой (Число?).

Вам определенно следует использовать инструмент, подходящий для вашей цели, а не нечеткий хак; List::Util::min как уже упоминалось в другом ответе, отлично. Просто подумал, что вам может понравиться подтверждение вашего первоначального вопроса :)

Здесь: http://www.perlmonks.org/?node_id=718414

Я получил ответ, который я мог проверить на Linux 64.

18,446,744,073,709,551,615 = (2 ^64)-1

Наибольшее целочисленное значение, которое может хранить perl, равно 9 007 199 254 740 992.

Я не знаю, есть ли константа специально для этого.